Chinaunix

标题: 【求解】如何将2维数组转成多层哈希 [打印本页]

作者: yiten 时间: 2010-11-13 11:03
标题: 【求解】如何将2维数组转成多层哈希
通用的方法，传进任意的2维数组
如：把[ [1,2,3], ['a','b','c'], [ 1, 'b', '3']]转成
{ 1 => { 2 => 3, b => 3 }, a => { b => c } }

作者: zhlong8 时间: 2010-11-13 11:51

sub a2h {
my $array_ref = shift;
my $hash_ref;
for (@$array_ref) {
my($k1, $k2, $v) = @$_;
$hash_ref->{$k1}{$k2} = $v;
}
return $hash_ref;
}

复制代码

作者: flw 时间: 2010-11-13 11:55
$hash->{$_->[0]}{$_->[1]} = $_->[2] foreach @$array;

作者: yiten 时间: 2010-11-13 12:00
我说的是通用的
如果是[ [1,2,3,4], ['a','b','c',4], [ 1, 'b', '3',4]]呢

作者: yiten 时间: 2010-11-13 12:02
就是[$array_1,...,$array_n]
$array_n为相同长度的数组长度>=2，且至少有一个元素不同

作者: zhlong8 时间: 2010-11-13 12:11
本帖最后由 zhlong8 于 2010-11-13 12:31 编辑

用了递归。下次问题描述清楚点啊，通用什么的

use strict;
use warnings;
use Data::Dumper;
sub l2h;
sub a2h {
my $array_ref = shift;
my $hash_ref;
for (@$array_ref) {
my $k = shift @$_;
$hash_ref->{$k} = l2h @$_;
}
return $hash_ref;
}
sub l2h {
if (@_ == 1) {
return shift;
} else {
my $key = shift;
return {$key => &l2h(@_)};
}
}
print Dumper a2h [ [1,2,3,4], ['a','b','c',4], [ 1, 'b', '3',4]]

复制代码

因为你有重复的 key 1，所以输出为

$VAR1 = {
'1' => {
'b' => {
'3' => 4
}
},
'a' => {
'b' => {
'c' => 4
}
}
};

复制代码

作者: yiten 时间: 2010-11-13 13:15
多谢啊，果然是高手

作者: yiten 时间: 2010-11-13 13:20
好像不对
print Dumper a2h [ [1,2,3,4,5], ['a','b','c',4, 6], [ 'a', 'b', 2,3,4], [ 1, 2, 3,'b', 4] ]结果是
$VAR1 = {
      '1' => {
               '2' => {
                        '3' => {
                                 'b' => 4
                                 }
                        }
               },
      'a' => {
               'b' => {
                        '2' => {
                                 '3' => 4
                                 }
                        }
               }
      };

作者: yiten 时间: 2010-11-13 13:22
正确的结果应该是
$VAR1 = {
      '1' => {
               '2' => {
                        '3' => {
                                 'b' => 4
                                 '4' => 5
                                 }
                        }
               },
      ....
      ....
      };

作者: zhlong8 时间: 2010-11-13 13:34
本帖最后由 zhlong8 于 2010-11-13 13:38 编辑

回复 9# yiten

……没看上面我说你有重复key所以显示只有两个。原来你每一层key可以随意在后面添加的。我要哭了，说清楚嘛

作者: yiten 时间: 2010-11-13 13:50
恩，是的。
你的方法在第一层是分开了，但是第二层开始都是覆盖了

作者: zhlong8 时间: 2010-11-13 13:50
本帖最后由 zhlong8 于 2010-11-13 14:01 编辑

可以处理任意的里面元素长度超过2的二维数组，不需要等长，不过要注意不能有重复key

use strict;
use warnings;
use Data::Dumper;
sub l2h;
sub a2h {
my $array_ref = shift;
my %hash;
for (@$array_ref) {
l2h \%hash, $_;
}
return \%hash;
}
sub l2h {
my($hash_ref, $array_ref) = @_;
my $key = shift @$array_ref;
if (@$array_ref == 1) {
$hash_ref->{$key} = shift @$array_ref;
return;
}
elsif (exists $hash_ref->{$key} and ref($hash_ref->{$key}) eq 'HASH') {
&l2h($hash_ref->{$key}, $array_ref);
}
else {
$hash_ref->{$key} = {};
&l2h($hash_ref->{$key}, $array_ref);
}
}
print Dumper a2h [[1,2,3,4,5], ['a','b','c',4, 6], [ 'a', 'b', 2,3,4], [ 1, 2, 3,'b', 4]]

复制代码

输出为

$VAR1 = {
'1' => {
'2' => {
'3' => {
'4' => 5,
'b' => 4
}
}
},
'a' => {
'b' => {
'c' => {
'4' => 6
},
'2' => {
'3' => 4
}
}
}
};

复制代码

作者: yiten 时间: 2010-11-13 13:56
这个是对的了，厉害，呵呵{:3_193:}

作者: yiten 时间: 2010-11-13 14:01
我的思路是到了，要把外面的哈希引用传到递归里去填充。
但是就是出不来正确结果，看了这个果然觉悟了，哈哈

作者: zhlong8 时间: 2010-11-13 14:11
本帖最后由 zhlong8 于 2010-11-13 14:14 编辑

回复 14# yiten

写了个循环版的，FP用多习惯递归了

use strict;
use warnings;
use Data::Dumper;
sub a2h {
my $array_ref = shift;
my %hash;
for my $item (@$array_ref) {
my $hash_ref = \%hash;
while (@$item > 2) {
my $key = shift @$item;
if (exists $hash_ref->{$key} and ref($hash_ref->{$key}) eq 'HASH') {
$hash_ref = $hash_ref->{$key};
}
else {
$hash_ref->{$key} = {};
$hash_ref = $hash_ref->{$key};
}
}
my($key, $val) = @$item;
$hash_ref->{$key} = $val;
}
\%hash;
}
print Dumper a2h [[1,2,3,4,5], ['a','b','c',4, 6], ['a', 'b', 2,3,4], [ 1, 2, 3,'b', 4],[1,'kk','afkd'],[1,'kk', 'afkd',2]]

复制代码

输出为

$VAR1 = {
'1' => {
'kk' => {
'afkd' => 2
},
'2' => {
'3' => {
'4' => 5,
'b' => 4
}
}
},
'a' => {
'b' => {
'c' => {
'4' => 6
},
'2' => {
'3' => 4
}
}
}
};

复制代码

作者: yiten 时间: 2010-11-13 15:04
向zhlong8致敬

自己感觉这个问题还是比较有深度的和技巧的，有人会发现这个转化还是比较有用的，哈哈

作者: yiten 时间: 2010-11-13 15:14
这2个算法已经很不错了，$hash_ref有类似游标的作用
但是里头有对数组的shift操作，而且相当于shift了mxn次，我觉得在数据量比较大的情况下，还不是很轻快。

作者: zhlong8 时间: 2010-11-13 15:20
本帖最后由 zhlong8 于 2010-11-13 15:25 编辑

回复 17# yiten

shift 很快的不用担心(内部用偏移量实现，时间复杂度为 O(1))，需要历遍所有元素这个复杂度必须的吧？

作者: yiten 时间: 2010-11-13 15:32
回复 18# zhlong8

恩，我的思路也只有这个，但是能不能也借鉴用类似游标来做，尽量不要修改原数组，不知道能不能行的通。有空再研究吧，呵呵

作者: zhlong8 时间: 2010-11-13 19:28
回复 19# yiten

用下标索引速度反而慢了。数组结构也不复杂，可以用 Clone 复制份来操作

作者: yiten 时间: 2010-12-24 10:10
这几天有空，把zhlong8的第二个算法改写了下，改写后不会修改原数组，也快了一些。
如果有人发现这个功能有用，可以参考下，我是个好人

sub array2hash {
my $array = shift;
my $result_hash = {};
my $temp_hash;
for my $item (@$array) {
$temp_hash = $result_hash;
for my $i ( 0..$#$item - 2 ) {
my $key = $item->[$i];
$temp_hash->{$key} = {} unless ref $temp_hash->{$key};
$temp_hash = $temp_hash->{$key};
}
$temp_hash->{$item->[-2]} = $item->[-1] if exists $item->[-2];
}
return $result_hash;
}

复制代码

作者: yiten 时间: 2010-12-24 10:11
本帖最后由 yiten 于 2010-12-24 10:12 编辑

欢迎光临 Chinaunix (http://bbs.chinaunix.net/)