awk 中的 $1=$1

splendid12

echo '1 2 3 4' | awk '{OFS="\n"; printf $0}'
1 2 3 4


echo '1 2 3 4' | awk '{OFS="\n"; $1=$1; printf $0}'
1
2
3
4

y?

ziyunfei

8.$1=$1 是用来激活$0的重新赋值,也就是说 字段$1...和字段数NF的改变会促使awk重新计算$0的值,通常是在改变OFS后而需要输出$0时这样做

    echo "A B C D" | awk '{OFS="|";print $0;$1=$1;print $0;}'
    A B C D
    A|B|C|D
   
    即使OFS放在BEGIN里,也没有用
    echo "A B C D" | awk 'BEGIN{OFS="|"}{print $0;$1=$1;print $0;}'
    A B C D
    A|B|C|D

   $0=$0 刚好相反, 修改$0的值可以促使awk重新计算字段$1...和字段数NF的的值,通常是在改变FS后而需要输出$1...或者NF时这样做

    echo "A|B|C|D" | awk '{FS="|";print $1,NF;$0=$0;print $1,NF}'
    A|B|C|D 1
    A 4
   
    不过把修改FS放在BEGIN里,就没必要$0=$0了
    echo "A|B|C|D" | awk 'BEGIN{FS="|"}{print $1,NF;$0=$0;print $1,NF}'
    A 4
    A 4
   
其实,在awk源码中.重新计算$0的值的函数名叫rebuild_record,重构记录的意思.默认情况下.这个函数是不可能执行的.因为$0是直接读入的.$1=$1等修改字段的行为会触发awk执行这个函数
重新计算$1...的值的函数名叫reset_record,重新分割记录到字段的意思.默认情况下.这个函数只在处理完当前行,读入下一行之前执行.中途是不会执行的.$0=$0等修改记录的行为会触发awk执行这个函数
通过在源码中添加一行标记重新编译awk.可以查看awk到底什么时候运行了这两个函数.

rebuild_record

• echo "A B C D" | awk '{print $0;OFS="|";print "OFS=\"|\"";print $0;print "$1=$1";$1=$1;print $0;}'
• -----------reset_record-----------             #读入行之前,执行reset_record,把$0拆分开赋值给$1...
• A B C D                                         #$0为读入的值
• OFS="|"                                        #改变OFS
• A B C D                                         #没有触发rebuild_record重构$0,$0仍为读入的值.
• $1=$1                                           #执行$1=$1,
• ----------rebuild_record------------            #awk不管$1是否真的改变,执行rebuild_record.
• A|B|C|D                                         #$0的值成为各个字段和ORS计算出的值
  

复制代码
reset_record

• echo "A|B|C|D" | awk '{print $1,NF;print "FS=\"|\"";FS="|";print $1,NF;print "$0=$0";$0=$0;print $1,NF}'
• -----------reset_record-----------              #读入行之前,执行reset_record,把$0拆分开赋值给$1...
• A|B|C|D 1                                        #$1为刚才计算的值
• FS="|"                                             #改变FS
• A|B|C|D 1                                        #没有触发reset_record重构$1和NF,仍为第一次计算的值.
• $0=$0                                             #执行$0=$0
• -----------reset_record-----------              #awk不管$0是否真的改变,执行reset_record.
• A 4                                                   #$1和NF的值成为重新计算出的值
  

复制代码

mpstat

顶2楼

waker

1. 
   
2. Advanced Notes: Changing FS Does Not Affect the Fields
   
3. 
   
4. According to the POSIX standard, awk is supposed to behave as if each record is split into fields at the time it is read. In particular, this means that if you change the value of FS after a record is read, the value of the fields (i.e., how they were split) should reflect the old value of FS, not the new one.
   
5. 
   
6. However, many older implementations of awk do not work this way. Instead, they defer splitting the fields until a field is actually referenced. The fields are split using the current value of FS! (d.c.) This behavior can be difficult to diagnose. The following example illustrates the difference between the two methods. (The sed21 command prints just the first line of /etc/passwd.)
   
7. 
   
8.      sed 1q /etc/passwd | awk '{ FS = ":" ; print $1 }'
   
9. 
   
10. which usually prints:
    
11. 
    
12.      root
    
13. 
    
14. on an incorrect implementation of awk, while gawk prints something like:
    
15. 
    
16.      root:nSijPlPhZZwgE:0:0:Root:/:
    

复制代码

这种作法算是对标准的一种补偿吧

winway1988

回复 2# ziyunfei


    顶，求资料出处。

Shell_HAT

回复 5# winway1988


http://www.gnu.org/software/gawk/manual/gawk.html

xiaopan3322

SS兄(@yinyuemi)写过一篇文章：
http://bbs.chinaunix.net/thread-2309494-1-1.html
请看第四点！

ziyunfei

winway1988 发表于 2012-03-17 08:43
回复 2# ziyunfei

http://bbs.chinaunix.net/thread-2319120-1-1.html

11年shell大赛第八题