免费注册 查看新帖 |

Chinaunix

  平台 论坛 博客 文库
1234下一页
最近访问板块 发新帖
查看: 24024 | 回复: 39

【Perl 文档中文化计划】Perl 特殊变量翻译完成。 [复制链接]

论坛徽章:
1
2015年辞旧岁徽章
日期:2015-03-03 16:54:15
发表于 2006-06-07 20:21 |显示全部楼层
本文由 chaoslawful 和鄙人共同翻译完成。
我原来翻译过一部分,不过没有翻完,后来幸亏 chaoslawful 的努力,所以才终于完成此文。
最新版本可以从这里获取(POD 格式):
http://svn.perlchina.org/trunk/POD2-CN/lib/POD2/CN/perlvar.pod
  1. NAME
  2.     perlvar - Perl 预定义变量

  3. DESCRIPTION
  4.   预定义名称
  5.     后面列出的名称对 Perl 来说具有特殊含义。
  6.     大多数标点名称都有合理的助记方法或类似于在 shell 中的用法。
  7.     然而,如果你就是想用长变量名,那只要在程序开头加上

  8.         use English;

  9.     即可。这样会为所有短名称在当前包中创建长名称别名。
  10.     其中一些甚至还有中间名,一般是从 awk 借用过来的。 一般来说,如果不需要
  11.     $PREMATCH,$MATCH 和 $POSTMATCH,那最好使用

  12.         use English '-no_match_vars';

  13.     调用方式,因为它能避免在用正则表达式时出现效率降低的情况。见 English。

  14.     依赖当前被选中文件句柄的变量可以通过在 IO::Handle
  15.     对象上调用合适的对象方法来设置,
  16.     但是这要比使用普通的内建变量效率低一些。(下面的概括行里包含的单词 HANDLE
  17.     即指 IO::Handle 对象。) 首先你要声明

  18.         use IO::Handle;

  19.     然后就可以用

  20.         method HANDLE EXPR

  21.     或者更安全的形式,

  22.         HANDLE->method(EXPR)

  23.     每个方法都返回 IO::Handle 属性的旧值,同时接受一个可选的 EXPR。
  24.     如果提供了该参数,则其指定了所涉及 IO::Handle
  25.     属性的新值。如果不提供该参数, 大多数方法不改变当前值--除了
  26.     autoflush(),它会假定给定了参数 1,稍有不同。

  27.     载入 IO::Handle
  28.     类是一项代价高昂的操作,因此你该知道如何使用常规的内建变量。

  29.     这些变量中的少数几个是“只读的”。这意味着如果直接或者通过引用间接向该变
  30.     量赋值, 就会引起一个运行时异常。

  31.     在修改本文档中描述的大部分特殊变量的缺省值时都需要特别小心。多数情况下应
  32.     该
  33.     在修改之前局部化这些变量,如果不这么做,就可能影响依赖于你所修改特殊变量
  34.     缺 省值的其他模块。下面是一次性读入整个文件的一种正确方法:

  35.         open my $fh, "foo" or die $!;
  36.         local $/; # enable localized slurp mode
  37.         my $content = <$fh>;
  38.         close $fh;

  39.     但下面的代码就很糟糕:

  40.         open my $fh, "foo" or die $!;
  41.         undef $/; # enable slurp mode
  42.         my $content = <$fh>;
  43.         close $fh;

  44.     因为一些模块可能想以默认的“行模式”从文件中读取数据,而一旦我们刚才
  45.     列出的代码得到执行,在同一个 Perl 解释器内运行的所有其他代码读到的 $/
  46.     全局值都会被改变。

  47.     通常,在局部化一个变量时总是想让影响限制在尽可能小的范围内,因此
  48.     应该自己建立一个 "{}" 块,除非你已经处于某些小的 "{}" 块内。例如:

  49.         my $content = '';
  50.         open my $fh, "foo" or die $!;
  51.         {
  52.             local $/;
  53.             $content = <$fh>;
  54.         }
  55.         close $fh;

  56.     下面是代码失控的一个例子:

  57.         for (1..5){
  58.             nasty_break();
  59.             print "$_ ";
  60.         }
  61.         sub nasty_break {
  62.             $_ = 5;
  63.             # do something with $_
  64.         }

  65.     你可能希望上述代码打印出:

  66.         1 2 3 4 5

  67.     但实际上得到的却是:

  68.         5 5 5 5 5

  69.     为什么?因为 nasty_break() 修改了 $_ 而没有事先将其局部化。
  70.     改正方法是增加 local():

  71.             local $_ = 5;

  72.     虽然在这样一个短小的例子里很容易发现问题,但在更复杂的代码中,如果不
  73.     对特殊变量进行局部化更改就是在自找麻烦。

  74.     下列内容按照先标量变量、后数组、最后散列的顺序排列。

  75.     $ARG
  76.     $_      默认的输入和模式搜索空间。下面的几对代码都是等同的:

  77.                 while (<>) {...}    # equivalent only in while!
  78.                 while (defined($_ = <>)) {...}

  79.                 /^Subject:/
  80.                 $_ =~ /^Subject:/

  81.                 tr/a-z/A-Z/
  82.                 $_ =~ tr/a-z/A-Z/

  83.                 chomp
  84.                 chomp($_)

  85.             以下是几处即使没有写明 Perl 也会假定使用 $_ 的地方:

  86.             *  各种单目函数,包括像 ord() 和 int() 这样的函数以及除 "-t"
  87.                以外所有的文件 测试操作 ("-f","-d"),"-t" 默认操作 STDIN。

  88.             *  各种列表函数,例如 print() 和 unlink()。

  89.             *  没有使用 "=~" 运算符时的模式匹配操作 "m//"、"s///" 和
  90.                "tr///"。

  91.             *  在没有给出其他变量时是 "foreach" 循环的默认迭代变量。

  92.             *  grep() 和 map() 函数的隐含迭代变量。

  93.             *  当 "while" 仅有唯一条件,且该条件是对 "<FH>"
  94.                操作的结果进行测试时,$_ 就是存放输入记录的默认位置。除了
  95.                "while" 测试条件之外不会发生这种情况。

  96.             (助记:下划线在特定操作中是可以省略的。)

  97.     $a
  98.     $b      是使用 sort() 时的特殊包变量,参见 "sort" in perlfunc。
  99.             由于这一特殊性,$a 和 $b 即使在用了 "strict 'vars'"
  100.             指示符以后也不需要声明(用 use vars 或者 our())。 如果想要在
  101.             sort() 的比较块或者函数中使用它们,就不要用 "my $a" 或 "my $b"
  102.             将其词法化。

  103.     $<*digits*>
  104.             含有上次模式匹配中捕获括号集合所对应的子模式,不包括已经退出的嵌
  105.             套 块中匹配的模式。(助记:类似 \digits。)
  106.             这些变量全都是只读的,对于 当前块来说具有动态作用域。

  107.     $MATCH
  108.     $&      含有上次成功的模式匹配所匹配到的字符串(不包括任何隐藏在块中的匹?
  109.             浠虻鼻?块所包围的 eval())。(助记:同一些编辑器中的 & 类似。)
  110.             该变量是只读的, 对于当前块来说具有动态作用域。

  111.             在程序中任何地方使用该变量都会使所有正则表达式匹配产生可观的效率
  112.             降低。 参见 "BUGS"。

  113.     $PREMATCH
  114.     $`      含有上次成功的模式匹配内容之前的字符串(不包括任何隐藏在块中的匹?
  115.             浠虻鼻?块所包围的 eval)。(助记:"`"
  116.             常常出现在引起的字符串之前。) 该变量是只读的。

  117.             在程序中任何地方使用该变量都会使所有正则表达式匹配产生可观的效率
  118.             降低。 参见 "BUGS"。

  119.     $POSTMATCH
  120.     $'      含有上次成功的模式匹配内容之后的字符串(不包括任何隐藏在块中的匹?
  121.             浠虻鼻?块所包围的 eval())。(助记:"'"
  122.             常常跟在引起的字符串之后。) 例如:

  123.                 local $_ = 'abcdefghi';
  124.                 /def/;
  125.                 print "$`:$&:$'\n";         # prints abc:def:ghi

  126.             该变量只读且对于当前块具有动态作用域。

  127.             在程序中任何地方使用该变量都会使所有正则表达式匹配产生可观的效率
  128.             降低。 参见 "BUGS"。

  129.     $LAST_PAREN_MATCH
  130.     $+      含有上次成功的搜索模式中最后一个括号匹配的文本。在无法知道可选模
  131.             式集中 到底哪一个匹配成功时,该变量是非常有用的。例如:

  132.                 /Version: (.*)|Revision: (.*)/ && ($rev = $+);

  133.             (助记:积极一点儿向前看。)(译注:“积极”与“正号”是同一个单词?
  134.             ? 该变量只读且相对于当前块具有动态作用域。

  135.     $^N     含有上一次成功搜索模式中最近闭合的组(即最右边的右括号构成的组)所
  136.             匹配 的文本。(助记:最近闭合的(可能)嵌套的括号。)
  137.             (译注:嵌套的单词为 Nest。)

  138.             该变量主要用在 "(?{...})"
  139.             块的内部,以便检查最近匹配到的文本。例如,
  140.             为了有效地用一个变量($1、$2 等等之外的变量)捕获文本,可以将
  141.             "(...)" 替换为

  142.                  (?:(...)(?{ $var = $^N }))

  143.             像这样设置并使用 $var 就能把你从计算括号个数的烦恼中解放出来了。

  144.             该变量对于当前块具有动态作用域。

  145.     @LAST_MATCH_END
  146.     @+      该数组保存了当前活动的动态作用域中最近成功的子匹配结束处的偏移量
  147.             。 $+[0]
  148.             为整个匹配在字符串中结束处的偏移量,这同用被匹配的变量调用 "pos"
  149.             函数得到的值一样。该数组的第 *n* 个元素保存了第 *n* 个子匹配
  150.             的偏移量,因此 $+[1] 就是紧接着 $1 结束处的偏移量,$+[2] 是
  151.             紧接着 $2 结束处的偏移量,以此类推。可以用 $#+
  152.             得知最近成功的匹配 中有多少个组。参见为 "@-" 变量给出的例子。

  153.     $*      将其设为非零整数值就可以进行字符串内的多行匹配,设为
  154.             0(或未定义值) 相当于告诉 Perl
  155.             可以假定字符串都是单行的,从而能进行模式匹配的优化。当 $* 为 0
  156.             或未定义值时,对含有多个换行符的字符串进行模式匹配会产生很难
  157.             理解的结果。它默认为未定义值。(助记:* 匹配很多东西。)
  158.             该变量只影响对 "^" 和 "$" 的解释。即使在 "$* == 0"
  159.             时也可以搜索一个字面的换行符。

  160.             在现在的 Perl 里不应使用 $*,在模式匹配中可以用 "/s" 和 "/m"
  161.             修饰符取代 它的功能。

  162.             对 $* 赋非数值量会触发一个警告(并使 $* 表现为 "$* == 0"),对 $*
  163.             赋数值量则会隐含对其应用 "int"。

  164.     HANDLE->input_line_number(EXPR)
  165.     $INPUT_LINE_NUMBER
  166.     $NR
  167.     $.      为最后访问的文件句柄对应的当前行号。

  168.             Perl 中每个文件句柄都记录从其中读出的行数。(Perl
  169.             中行的概念也许和你不一 样,要看 $/ 的值是什么。)
  170.             当从某个文件句柄中读出一行(通过 readline() 或 "<>")或对其调用
  171.             tell() 或 seek() 时,$. 即成为那个句柄的行 计数器的别名。

  172.             你可以通过向 $. 赋值来调整计数器,但这并不会实际移动文件指针。
  173.             *局部化 $. 不会使对应文件句柄的行计数器局部化*,而只会局部化 $.
  174.             和文件句柄的别名关系。

  175.             关闭文件句柄时会复位 $.,但在没有 close()
  176.             就重新打开一个已打开的文件句柄 时不会这样。更多细节参见 "I/O
  177.             Operators" in perlop。"<>" 从不显式关闭文件,因此行号会在 ARGV
  178.             文件之间持续增长(不过请看看 "eof" in perlfunc 中的例子)。

  179.             你还可以用 "HANDLE->input_line_number(EXPR)"
  180.             访问一个给定文件句柄的
  181.             行计数器,这样就无需担心最后访问的是哪个句柄了。

  182.             (助记:很多程序用“.”表示当前行号。)

  183.     IO::Handle->input_record_separator(EXPR)
  184.     $INPUT_RECORD_SEPARATOR
  185.     $RS
  186.     $/      为输入记录分隔符,默认为换行符。该变量会影响 Perl
  187.             对“行”这一概念 的理解。其功能类似于 awk 中的 RS
  188.             变量,在被设置为空字符串时同样
  189.             会将空白行作为终止标志。(空白行不能含有任何空格或制表符。)
  190.             你可以将其
  191.             设置为含有多个字符的字符串,以匹配多字符的终止标志;也可以设为
  192.             "undef" 以便一直读到文件结束。当文件含有连续的空白行时,把它设为
  193.             "\n\n" 和设为 "" 有少许不同:设为 ""
  194.             会把两个或更多连续的空白行视为单个 空白行;而设为 "\n\n"
  195.             则只是盲目地假定其后输入的字符属于下一段,即使
  196.             这些字符是换行符也一样。(助记:在引用诗句时会用 /
  197.             作为行间的分隔。)

  198.                 local $/;           # enable "slurp" mode
  199.                 local $_ = <FH>;    # whole file now here
  200.                 s/\n[ \t]+/ /g;

  201.             切记:$/ 的内容是一个字符串,而不是正则表达式。awk
  202.             得在某些方面改进 一下了。:-)

  203.             将 $/
  204.             设为整数、存有整数的标量或可转换成整数的标量这些值的引用时,Perl
  205.             会尝试读入记录而不是行,最大记录长度就是引用的那个整数。因此这段
  206.             代码:

  207.                 local $/ = \32768; # or \"32768", or \$var_containing_32768
  208.                 open my $fh, $myfile or die $!;
  209.                 local $_ = <$fh>;

  210.             会从 FILE 读取一条不长于 32768
  211.             字节的记录。如果你不是在读取一个面向记录 的文件(或者所用的 OS
  212.             没有面向记录的文件类型),那很可能每次读取都得到一
  213.             整块的数据。若某条记录比你所设置的记录长度还大,就会把该记录拆成
  214.             若干片 返回。

  215.             在 VMS 上,记录读取是用 "sysread"
  216.             的等价物完成的,因此最好不要在同一个
  217.             文件上混合使用记录和非记录读。(这不太可能成为问题,因为任何你想?
  218.             约锹寄J?读取的文件也许都不能在行模式下用。) 非 VMS 系统用普通
  219.             I/O 进行读取,因此 在一个文件中混合记录和非记录读是安全的。

  220.             参见 "Newlines" in perlport 以及 $.。

  221.     HANDLE->autoflush(EXPR)
  222.     $OUTPUT_AUTOFLUSH
  223.     $|      若将该变量设为非零值,就会立刻强制进行刷新,并且当前选中的输出通
  224.             道在每次 打印或写之后都会进行刷新。默认值为 0
  225.             (不管选中的通道实际上是否被系统所缓冲, $| 只是告诉你 Perl
  226.             是否在每次写完之后显式刷新)。典型情况下,若 STDOUT
  227.             的输出是终端则是行缓冲的,否则就是块缓冲。设置该变量在向管道或套
  228.             接字输出 时很有用,比如你正在 rsh 下运行一个 Perl
  229.             程序并且想在输出时马上就能看到
  230.             输出内容。该变量不影响输入缓冲。关于输入缓冲请参见 "getc" in
  231.             perlfunc。 (助记:when you want your pipes to be piping hot.)

  232.     IO::Handle->output_field_separator EXPR
  233.     $OUTPUT_FIELD_SEPARATOR
  234.     $OFS
  235.     $,      为 print 的输出域分隔符。通常 print
  236.             不经任何修饰就输出它的参数,要 得到更像 awk
  237.             的行为,可以将该变量设置成和 awk 的 OFS 变量一样
  238.             ,以指定域之间打印什么。(助记:当 print
  239.             语句里有“,”时会打印的东西。)

  240.     IO::Handle->output_record_separator EXPR
  241.     $OUTPUT_RECORD_SEPARATOR
  242.     $ORS
  243.     $\      为 print 的输出记录分隔符。通常 print
  244.             简单地原样输出它的参数,不增加
  245.             任何结尾的换行符或其他表征记录结束的字符串。要得到更像 awk
  246.             的行为, 可以将该变量设为同 awk 的 ORS 变量一样,以指定在 print
  247.             的结尾输出 什么。(助记:设置 $\ 而不是在 print
  248.             结尾加“\n”。另外,它长得和 $/ 很像,但却是你从 Perl
  249.             那里拿“回”的东西。) (译注:“回”原文为
  250.             单词“back”,还指代反斜杠“backslash”,起一语双关作用。)

  251.     $LIST_SEPARATOR
  252.     $"      该变量同 $,
  253.             类似,但应用于向双引号引起的字符串(或类似的内插字符串)
  254.             中内插数组和切片值的场合。默认为一个空格。(助记:我觉得显而易见?
  255.             ?

  256.     $SUBSCRIPT_SEPARATOR
  257.     $SUBSEP
  258.     $;      为模拟多维数组时的下标分隔符。如果你这样引用一个散列元素

  259.                 $foo{$a,$b,$c}

  260.             实际上意思就是

  261.                 $foo{join($;, $a, $b, $c)}

  262.             但是别这么写

  263.                 @foo{$a,$b,$c}      # a slice--note the @

  264.             它的意思是

  265.                 ($foo{$a},$foo{$b},$foo{$c})

  266.             默认为“\034”,同 awk 的 SUBSEP
  267.             一样。如果你的散列键包含二进制数据, 可能 $;
  268.             就没法包含任何可靠的值了。
  269.             (助记:逗号(语法上的下标分隔符)是半个分号。是啊,我知道这完全没?
  270.             兴捣??,但 $, 已经被用做更重要的用途了。)

  271.             请考虑像 perllol 里说明的那样使用“真正的”多维数组。

  272.     $#      为打印数值时的输出格式。该变量是 awk 中 OFMT
  273.             变量一个粗糙的模仿尝试。 不过确实有段时间 awk 和 Perl
  274.             在什么可以看成数值的概念上有所分歧。它的 初始值是“%.*n*g”,*n*
  275.             是你所用系统上 float.h 中 DBL_DIG 宏的值。 这同 awk 的默认 OFMT
  276.             设置“%.6g”不一样,因此你需要显式设定 $# 以便 得到和 awk
  277.             一样的结果。(助记:# 是数值标志。)

  278.             不建议使用 $# 变量。

  279.     HANDLE->format_page_number(EXPR)
  280.     $FORMAT_PAGE_NUMBER
  281.     $%      为当前选中的输出通道的当前页码。同格式配合使用。 (助记:% 是
  282.             nroff 中的页码。)

  283.     HANDLE->format_lines_per_page(EXPR)
  284.     $FORMAT_LINES_PER_PAGE
  285.     $=      为当前选中的输出通道的当前页长度(可打印的行数)。默认为 60。
  286.             同格式配合使用。 (助记:符号 = 由两个水平行组成。)

  287.     HANDLE->format_lines_left(EXPR)
  288.     $FORMAT_LINES_LEFT
  289.     $-      为当前选中的输出通道的页面残留行数。同格式配合使用。
  290.             (助记:页面行数 - 已打印行数。)

  291.     @LAST_MATCH_START
  292.     @-      $-[0] 是最近一次成功匹配的起始偏移量。 "$-["*n*"]" 是由第 *n*
  293.             个子模式所匹配的子字符串的起始偏移量,
  294.             若对应的子模式没有匹配则取为 undef。

  295.             因此对 $_ 进行匹配之后,$& 和 "substr $_, $-[0], $+[0] - $-[0]"
  296.             是一样的。类似地,若 $-[n] 已定义,则 $*n* 同 "substr $_, $-[n],
  297.             $+[n] - $-[n]" 是一样的,$+ 也和 "substr $_, $-[$#-], $+[$#-] -
  298.             $-[$#-]" 相同。可以用 $#- 找出最近一次成功匹配
  299.             中最后一个匹配的子组。与之相对的 $#+ 是那次匹配所用正则表达式中
  300.             子组的数目,对应的是 "@+"。

  301.             该数组存放当前活动的动态作用域中最近成功的子匹配开始处的偏移量。
  302.             $-[0] 是整个匹配在字符串中开始处的偏移量,数组中第 *n* 个元素
  303.             存有第 *n* 个子匹配的偏移量,因此 $-[1] 是 $1 开始处的位移,
  304.             $-[2] 是 $2 开始处的位移,以此类推。

  305.             在对某个变量 $var 进行匹配后:

  306.             $` 和 "substr($var, 0, $-[0])" 相同
  307.             $& 和 "substr($var, $-[0], $+[0] - $-[0])" 相同
  308.             $' 和 "substr($var, $+[0])" 相同
  309.             $1 和 "substr($var, $-[1], $+[1] - $-[1])" 相同
  310.             $2 和 "substr($var, $-[2], $+[2] - $-[2])" 相同
  311.             $3 和 "substr $var, $-[3], $+[3] - $-[3])" 相同

  312.     HANDLE->format_name(EXPR)
  313.     $FORMAT_NAME
  314.     $~      为当前被选中输出通道的当前报表格式名称。默认为文件句柄名。(助记?
  315.             ?^ 的兄弟。)

  316.     HANDLE->format_top_name(EXPR)
  317.     $FORMAT_TOP_NAME
  318.     $^      为当前被选中输出通道的当前页眉格式名称。默认为文件句柄名后加
  319.             _TOP。 (助记:指向页眉。)

  320.     IO::Handle->format_line_break_characters EXPR
  321.     $FORMAT_LINE_BREAK_CHARACTERS
  322.     $:      是一组字符,字符串可以在这些字符后断行以填充格式中的连续域(以 ^
  323.             开始)。 默认为 " \n-",使字符串能在空白或连字符处断开。
  324.             (助记:诗中的“冒号”是一行的一部分。)

  325.     IO::Handle->format_formfeed EXPR
  326.     $FORMAT_FORMFEED
  327.     $^L     退纸时格式应输出的内容。默认为 \f。

  328.     $ACCUMULATOR
  329.     $^A     write() 对 format() 行的累加器的当前值。格式会调用 formline()
  330.             并将其结果放入 $^A。在调用对应的格式之后,write() 将 $^A
  331.             的内容打印出来并清空之。 因此你永远不可能看到 $^A
  332.             的内容,除非自己直接调用 formline() 并查看该变量 。参见 perlform
  333.             和 "formline()" in perlfunc。

  334.     $CHILD_ERROR
  335.     $?      由最近的管道关闭、反引号(``)命令、成功调用 wait() 和 waitpid()
  336.             或者 system() 操作符返回的状态信息。它就是由 wait()
  337.             系统调用返回的 16 位状态字
  338.             (或是由其他信息组合而成的类似值)。因此,子进程的退出值实际上是
  339.             ("$? >> 8"),"$? & 127" 给出了导致进程结束的信号代码(如果存在),
  340.             而 "$? & 128" 会报告是否产生了内核转储。(助记:同 sh 和 ksh
  341.             类似。)

  342.             另外如果 C 中支持 "h_errno" 变量,在任意 "gethost*()"
  343.             函数失败时,该变量 的值将会通过 $? 返回。

  344.             如果已经为 "SIGCHLD" 安装了一个信号处理器,那么在处理器之外 $?
  345.             的值通常 是有问题的。

  346.             在 "END" 子程序里,$? 含有即将交给 "exit()" 的值。可以在 "END"
  347.             子程序 中修改 $? 以达到改变程序退出状态的效果。例如:

  348.                 END {
  349.                     $? = 1 if $? == 255;  # die would make it 255
  350.                 }

  351.             在 VMS 系统下,指示符 "use vmsish 'status'" 使得 $? 反映实际的
  352.             VMS 退出 状态,而不是默认的对 POSIX 状态的模拟;细节见 "$?" in
  353.             perlvms。

  354.             另见 错误指示器。

  355.     ${^ENCODING}
  356.             为 Encode
  357.             对象的*对象引用*,用来将源代码转换成统一码。多亏有了该变量,
  358.             你的 Perl 脚本才不会被强制为 UTF-8 编码。默认为
  359.             *undef*。绝对不建议对 该变量进行直接操作。细节见 encoding。

  360.     $OS_ERROR
  361.     $ERRNO
  362.     $!      如果按数值使用该变量,就会得到 "errno"
  363.             变量的当前值;换句话说,如果
  364.             某个系统或者库函数调用失败了,就会设置该变量。这意味着 $!
  365.             的值仅当 *紧接*在一个失败之后时才有意义:

  366.                 if (open(FH, $filename)) {
  367.                     # Here $! is meaningless.
  368.                     ...
  369.                 } else {
  370.                     # ONLY here is $! meaningful.
  371.                     ...
  372.                     # Already here $! might be meaningless.
  373.                 }
  374.                 # Since here we might have either success or failure,
  375.                 # here $! is meaningless.

  376.             上述的*无意义*代表任何东西:零、非零、"undef"。成功的系统或库函?
  377.             ?调用不会将该变量重置为零。

  378.             If used as a string, yields the corresponding system error
  379.             string. You can assign a number to $! to set *errno* if, for
  380.             instance, you want "$!" to return the string for error *n*, or
  381.             you want to set the exit value for the die() operator.
  382.             (Mnemonic: What just went bang?)
  383.             若作为字符串使用,则会产生对应的系统错误字符串。可以对 $!
  384.             赋一个数 来设置 *errno*,这样就能用 "$!" 得到错误 *n*
  385.             对应的字符串了,也可以 用来设置 die()
  386.             运算符所用的退出值。(助记:刚刚什么东西炸了?)

  387.             另见 错误指示器。

  388.     %!      当 $! 设置为某个值时 "%!" 的对应元素即为真值。例如,$!{ENOENT}
  389.             为真当且仅当 $! 的当前值为 "ENOENT";也就是说,若最后的错误是
  390.             "No such file or
  391.             directory"(或其他等价的东西:并不是所有操作系统都给出
  392.             完全一致的错误,当然也不可能都是同一种语言)。要检查某个特定的键?
  393.             谀愕南低?上是否有意义,可以用 "exists
  394.             $!{the_key}";要取得合法键的列表,可以用 "keys %!"。更多信息见
  395.             Errno,另外从前面的描述也可以得出 $! 的有效 范围。

  396.     $EXTENDED_OS_ERROR
  397.     $^E     同当前操作系统相关的错误信息。目前该变量仅在 VMS、OS/2 和 Win32
  398.             (以及 MacPerl)下同 $! 有所不同。在所有其他平台上,$^E 总是和 $!
  399.             一样。

  400.             在 VMS 系统下,$^E 是最近一次系统错误的 VMS 状态值。这比 $!
  401.             提供的关于系统错误的信息更为详尽。当 $! 被设置成 EVMSERR 时
  402.             该变量尤为重要。

  403.             在 OS/2 系统下,$^E 被设置为最近一次通过 CRT 或直接通过 Perl
  404.             进行的 OS/2 API 调用所返回的错误代码。

  405.             在 Win32 下,$^E 总是返回由 Win32 调用 "GetLastError()" 所报告
  406.             的错误信息,它描述的是发生在 Win32 API 内部的最近一次错误。多数
  407.             特定于 Win32 的程序代码会通过 $^E 报告错误,而 ANSI C 及类 Unix
  408.             调用则会设置 "errno",因此大部分可移植的 Perl 代码都通过 $!
  409.             报告错误。

  410.             在 $! 的描述中提到的警告一般也适用于
  411.             $^E。(助记:额外的错误解释。)
  412.             (译注:英文中“额外”的单词为“Extra”。)

  413.             另见 错误指示器。

  414.     $EVAL_ERROR
  415.     $@      最近一个 eval() 运算符返回的 Perl 语法错误消息。 若 $@
  416.             是空字符串,则最近一次 eval() 进行了正确的解析和执行(
  417.             但是你所进行的操作可能已经按照通常的形式失败了)。
  418.             (助记:语法错误发生“在”哪里?)
  419.             (译注:符号“@”为英文单词“at”简写,意为“在……”)

  420.             警告消息不会被收集在该变量中。但你可以像后面描述的那样,通过设置
  421.             $SIG{__WARN__} 自己建立一个例程来处理警告。

  422.             另见 错误指示器。

  423.     $PROCESS_ID
  424.     $PID
  425.     $$      运行本脚本的 Perl 的进程号。该变量应视为只读的,不过在 fork()
  426.             调用 时会被改变。(助记:和 shell 一样。)

  427.             Linux 用户注意:在 Linux 下, C 函数 "getpid()" 和 "getppid()"
  428.             对 不同的线程返回不同的值。为了可移植,该行为没有反映在 $$
  429.             里,该变量 的值在线程间保持不变。如果你想调用底层的
  430.             "getpid()",可以使用 CPAN 模块 "Linux::Pid"。

  431.     $REAL_USER_ID
  432.     $UID
  433.     $<      本进程的实际 uid。(助记:如果你用了 setuid,那么这是你原来的
  434.             uid。) 可以用 POSIX::setuid() 同时改变实际 uid 和有效
  435.             uid。由于改变 $< 需要 进行系统调用,在更改之后应检查 $!
  436.             以发现可能产生的错误。

  437.     $EFFECTIVE_USER_ID
  438.     $EUID
  439.     $>      本进程的有效 uid。例:

  440.                 $< = $>;            # set real to effective uid
  441.                 ($<,$>) = ($>,$<);  # swap real and effective uid

  442.             可以用 POSIX::setuid() 同时改变有效 uid 和实际 uid。更改 $>
  443.             后需要 检查 $! 以发现可能产生的错误。

  444.             (助记:如果你用了 setuid,那么这是你要变成的 uid。) $< 和 $>
  445.             仅在支持 setreuid() 的机器上才能互换。

  446.     $REAL_GROUP_ID
  447.     $GID
  448.     $(      本进程的实际
  449.             gid。如果你使用的机器支持同时属于多个组,则该变量给出的是
  450.             被空格隔开的所在组列表。第一个数值是由 getgid()
  451.             返回的结果,后续的内容 是 getgroups()
  452.             返回的结果,其中可能有和第一个值相同的项。

  453.             然而为了设置实际 gid,赋给 $( 的必须是单个数值。因此从 $( 得到的
  454.             值在没有强制为数值(例如同零相加)的情况下*不应*再赋给 $(。

  455.             可以用 POSIX::setgid() 同时改变实际 gid 和有效 gid。更改 $(
  456.             后需要检查 $! 以便发现可能出现的错误。

  457.             (助记:圆括号用来将事物*分组*。当使用 setgid 时,实际 gid
  458.             是你*离开*的那个
  459.             组。)(译注:英文“离开”和“左”都是单词“left”。)

  460.     $EFFECTIVE_GROUP_ID
  461.     $EGID
  462.     $)      本进程的有效
  463.             gid。如果你使用的机器支持同时属于多个组,则该变量给出的是被
  464.             空格隔开的所在组列表。第一个数值为 getegid()
  465.             的返回值,后续的值是 getgroups()
  466.             的返回值,其中可能有和第一个值相同的项。

  467.             类似地,赋给 $)
  468.             的值也必须是一个空格隔开的数值列表。第一个数设置有效
  469.             gid,其余部分(若存在)则传给 setgroups()。要达到向 setgroups()
  470.             传递空列表 的效果,只需重复一遍新设置的有效 gid;例如,要将有效
  471.             gid 强制为 5 并向 setgroups() 传入空列表,就要这么写:" $) = "5
  472.             5" "。

  473.             可以用 POSIX::setgid() 同时改变有效 gid 和实际 gid
  474.             (只用单个数值参数)。 更改 $) 后需要对 $!
  475.             进行检查以便发现可能出现的错误。

  476.             (助记:圆括号用来*分组*事物。当使用 setgid 时,有效 gid
  477.             就是你需要的那个 组)(译注:原文为“that's *right* for
  478.             you”,难以表达“right”的含义。)

  479.             $<、$>、$( 和 $) 只能在支持对应的 *set[re][ug]id()*
  480.             例程的机器上进行设置。$( 和 $) 只能在支持 setregid()
  481.             的机器上互换。

  482.     $PROGRAM_NAME
  483.     $0      包含当前运行程序名。

  484.             在一些(注意:不是全部)操作系统下,向 $0 赋值可以改变 "ps"
  485.             程序所看到 的参数域。某些平台上你可能需要用特殊的 "ps"
  486.             选项或其他的 "ps" 才能看到 这个改变。修改 $0
  487.             作为指示当前程序状态的一种方法,要比用来隐藏你在运行的
  488.             程序更有用。(助记:同 sh 和 ksh 一样。)

  489.             注意 $0
  490.             的最大长度受相关平台的限制。多数极端情况下可能被限制在原始的 $0
  491.             所占据的空间之内。

  492.             在某些平台上可能会附加一些填充字符(例如空格)在 "ps"
  493.             显示出的修改名称
  494.             之后。有些平台上这种填充会充满原参数域,并且不受你的控制(例如
  495.             Linux 2.2)。

  496.             BSD 用户注意:设置 $0 不会完全把“perl”从 ps(1)
  497.             的输出中抹去。例如, 将 $0 设置为 "foobar" 可能产生 "perl:
  498.             foobar (perl)"("perl: " 前缀和 "
  499.             (perl)"后缀是否显示出来依赖于确切的 BSD
  500.             种类及版本)。这是操作系统 的一个特性,Perl 没法改变它。

  501.             在多线程脚本中 Perl
  502.             对所有线程等同视之,因此任何线程都能更改自己的 $0
  503.             副本,并且这一更改对 ps(1)
  504.             也是可见的(假设操作系统肯合作)。注意其他线程 所看到的 $0
  505.             不会被改变,因为它们有自己的副本。

  506.     $[      数组第一个元素以及字符串中首个字符的索引号。默认为
  507.             0,但理论上你可以将其 设为 1 ,以使 Perl 在处理下标或对 index()
  508.             和 substr() 函数求值时表现得更 像 awk(或 Fortran)。(助记:[
  509.             代表下标开始。)

  510.             Perl 5 出现后,向 $[
  511.             赋值被当作一个编译器指示符,因此不会影响任何其他文件
  512.             的行为。(这就是为什么你只能赋给它编译期常量的原因。)
  513.             强烈建议不要使用该变量。

  514.             注意,不像其他编译期指示符(例如 strict),对 $[
  515.             的赋值对于同一文件的外层词法
  516.             作用域来说是可见的。然而你可以对其使用
  517.             local(),从而将它的值严格限定在单个词法 块之内。

  518.     $]      Perl 解释器的版本 + 补丁级别 /
  519.             1000。该变量可用来判定一个脚本是否运行在恰当版本 范围的 Perl
  520.             解释器上。(助记:该版本的 Perl 是否是正确的类别?)(译注:英文
  521.             “right bracket”可以表示正确的类别,字面意思则是右方括号。)
  522.             例:

  523.                 warn "No checksumming!\n" if $] < 3.019;

  524.             在运行的 Perl 解释器太老时导致失败的一种简便方法可参见 "use
  525.             VERSION" 和 "require VERSION" 的文档

  526.             为了避免浮点数的不精确性,在测试该变量时你可能更希望用不等测试
  527.             "<" 和 ">",而不是包含有相等的测试:"<="、"==" 和 ">="。

  528.             浮点数表示法有时会导致不精确的数值比较结果。另一种允许对 Perl
  529.             版本进行精确的字符串 比较的现代化表示法请见 $^V。

  530.     $COMPILING
  531.     $^C     同开关 -c 相关联的标志的当前值。主要用于
  532.             -MO=...,以允许代码在编译时改变自身 行为,例如在编译期处理
  533.             AUTOLOAD 而不是像平时那样延迟载入。见 perlcc。设置 "$^C = 1"
  534.             同调用 "B::minus_c" 类似。

  535.     $DEBUGGING
  536.     $^D     调试标志的当前值。(助记:-D
  537.             开关的值。)可以读取或设置。同它的命令行等价物类似,你
  538.             可以使用数值或符号值,例如 "$^D = 10" 和 "$^D = "st""。

  539.     $SYSTEM_FD_MAX
  540.     $^F     系统文件描述符最大数量,通常为 2。系统文件描述符会被传递到
  541.             exec() 出来的 进程里去,而数值高于它的文件描述符则不会。另外在
  542.             open() 时,若 open() 调用
  543.             失败系统文件描述符会保持不变。(普通文件描述符在尝试 open()
  544.             之前会被关闭。) 文件描述符的 exec
  545.             时关闭状态是根据对应的文件、管道或套接字打开时的 $^F
  546.             值来决定的,而不是 exec() 时的 $^F 值。

  547.     $^H     警告:该变量应严格限制在内部使用。其存在性、行为以及内容可能不经
  548.             提醒就被改 变。

  549.             该变量包含 Perl
  550.             解释器的编译期提示。在一个块编译结束时该变量会恢复到解释器开始
  551.             编译那个块时的值。

  552.             当 perl 开始解析任何提供了词法作用域的块构造时(例如 eval
  553.             体、require 的文件 、子程序体、循环体或条件块),$^H
  554.             的已有值会被保存下来,但不会发生变化。当 该块的编译完成时,$^H
  555.             恢复到保存的值。在保存和恢复其值的两点之间,BEGIN 块中
  556.             执行的代码可以任意改变 $^H 的值。

  557.             该行为提供了词法作用域语义,并被应用在像 "use strict"
  558.             指示符这样的地方。

  559.             其值应为一个整数;不同的位代表不同的指示标志。例如:

  560.                 sub add_100 { $^H |= 0x100 }

  561.                 sub foo {
  562.                     BEGIN { add_100() }
  563.                     bar->baz($boon);
  564.                 }

  565.             考虑在 BEGIN 块执行过程中发生了什么。此时 BEGIN
  566.             块已经通过编译,而 foo() 函数体尚未完成编译。因此 $^H 的新值仅在
  567.             foo() 函数体编译时可见。

  568.             将上面的 BEGIN 块替换为:

  569.                 BEGIN { require strict; strict->import('vars') }

  570.             即演示了 "use strict 'vars'"
  571.             是如何实现的。下面是同一词法指示符的一个条件化 版本:

  572.                 BEGIN { require strict; strict->import('vars') if $condition }

  573.     %^H     警告:该变量应严格限定在内部使用。其存在性、行为以及内容可能不经
  574.             提醒就被改变。

  575.             %^H 散列表提供与 $^H
  576.             相同的作用域语法。这使其在实现词法作用域内的指示符时非常 有用。

  577.     $INPLACE_EDIT
  578.     $^I     原地编辑扩展的当前值。设置为 "undef" 时关闭原地编辑。(助记:-i
  579.             开关的值。)

  580.     $^M     默认情况下,内存耗尽是一个不可捕捉的致命错误。然而在适当编译的版
  581.             本中, Perl 可以将 $^M 的内容用作 die() 后的紧急内存池。假设你的
  582.             Perl 编译时使用 了 -DPERL_EMERGENCY_SBRK 选项以及 Perl 自己的
  583.             malloc。那么

  584.                 $^M = 'a' x (1 << 16);

  585.             将会分配一个 64K
  586.             的缓冲区以备紧急情况时使用。如何打开该选项的相关信息请参见 Perl
  587.             发行版中的 INSTALL
  588.             文件。为了防止无意中使用这一高级特性,该变量没有 对应的 English
  589.             长名。

  590.     $OSNAME
  591.     $^O     为当前 Perl
  592.             副本编译时所处的操作系统名称,在配置过程中即确定。其值同
  593.             $Config{'osname'} 相同。另见 Config 及 perlrun 中说明的 -V
  594.             命令行开关。

  595.             在 Windows 平台下,$^O 并不十分有用:因为它总是
  596.             "MSWin32",而无法表示出 95/98/ME/NT/2000/XP/CE/.NET
  597.             之间的区别。请用 Win32::GetOSName() 或 Win32::GetOSVersion() (见
  598.             Win32 及 perlport) 区分这些变种。

  599.     ${^OPEN}
  600.             由 PerlIO 使用的一个内部变量。是由 "\0"
  601.             字节分开的两部分组成的一个字符串,
  602.             前一部分描述输入层,后一部分描述输出层。

  603.     $PERLDB
  604.     $^P     供调试支持用的内部变量。其不同位所代表的意义很可能改变,但目前表
  605.             示的是:

  606.             0x01  进入/退出调试子程序。

  607.             0x02  逐行调试。

  608.             0x04  关闭优化。

  609.             0x08  为后续的交互检查预留更多数据。

  610.             0x10  保留子程序定义时所处源代码行的信息。

  611.             0x20  启动时打开单步调试。

  612.             0x40  报告时用子程序地址而不是名称。

  613.             0x80  还要报告 "goto &subroutine"。

  614.             0x100 根据编译的位置为 eval 提供表现内容较多的“文件”名。

  615.             0x200 根据编译的位置为匿名子程序提供表现内容较多的名称。

  616.             0x400 进入/退出调试断言子程序。

  617.             某些位仅同编译期相关,还有一些是运行期相关的。这是一种新机制,以
  618.             后可能 会修改其细节。

  619.     $LAST_REGEXP_CODE_RESULT
  620.     $^R     上一次成功的 "(?{ code })" 正则表达式断言(见 perlre)的求值结果。
  621.             可以被改写。

  622.     $EXCEPTIONS_BEING_CAUGHT
  623.     $^S     解释器当前状态。

  624.                 $^S         状态
  625.                 ---------   -------------------
  626.                 undef       解析模块/eval
  627.                 true (1)    正在执行一个 eval
  628.                 false (0)   其他

  629.             第一个状态也可能在 $SIG{__DIE__} 和 $SIG{__WARN__}
  630.             处理程序内产生。

  631.     $BASETIME
  632.     $^T     程序开始运行的时间,是从格林威治标准时刻(1970
  633.             年初)开始的秒数。由 -M 、-A 和 -C
  634.             文件测试所返回的结果是基于该值的。

  635.     ${^TAINT}
  636.             反映污染模式是否打开。1 表示打开(程序用 -T 运行),0 表示关闭,-1
  637.             表示仅 打开了污染警告(即使用了 -t 或 -TU)。

  638.     ${^UNICODE}
  639.             反映了 Perl 的确切 Unicode 设置。关于其可能值的更多信息请见
  640.             perlrun 文档 中对 "-C" 开关的描述。该变量在 Perl
  641.             启动时被设置,然后就是只读的了。

  642.     $PERL_VERSION
  643.     $^V     Perl
  644.             解释器的修订号、版本号以及子版本号,由具有这些序数的字符组成的字
  645.             符串表示 。因此 Perl v5.6.0 中该变量等于 "chr(5) . chr(6) .
  646.             chr(0)" 且 "$^V eq v5.6.0"
  647.             会返回真值。注意该字符串值中的字符可能处于 Unicode 范围内。

  648.             该变量可用来确定某个脚本是否在正确版本范围内的 Perl
  649.             解释器上运行。(助记:用 ^V 进行版本控制。) 例如:

  650.                 warn "No \"our\" declarations!\n" if $^V and $^V lt v5.6.0;

  651.             可以用 sprintf() 的 "%vd" 转换将 $^V 变成等价的字符串表达形式:

  652.                 printf "version is v%vd\n", $^V;  # Perl's version

  653.             关于在运行的 Perl 解释器过于古老时产生失败的方便方法,请参见
  654.             "use VERSION" 和 "require VERSION" 的文档。

  655.             较老的 Perl 版本表示法请见 $]。

  656.     $WARNING
  657.     $^W     警告开关的当前值,当使用 -w
  658.             时初始化为真,否则为假,不过可以直接修改。 (助记:同 -w
  659.             开关相关。) 另见 warnings。

  660.     ${^WARNING_BITS}
  661.             当前由 "use warnings" 指示符打开的警告检查集合。更多细节参见
  662.             "warnings" 的 文档。

  663.     $EXECUTABLE_NAME
  664.     $^X     是用于执行当前 Perl 副本的名称,来自 C 的 "argv[0]"。

  665.             根据主机操作系统,$^X 的值可能是 perl
  666.             程序文件的一个相对或绝对路径名、 或者是用于调用 perl 而不是 perl
  667.             程序文件路径名的字符串。另外,多数 操作系统允许调用不在 PATH
  668.             环境变量中的程序,因此并不保证 $^X 的值一定 在 PATH 中。对 VMS
  669.             来说,该值可能包含一个版本号。

  670.             通常可以用 $^X 的值再次产生和当前运行的 perl
  671.             相同的一个独立副本,例如,

  672.               @first_run = `$^X -le "print int rand 100 for 1..100"`;

  673.             但考虑到并不是所有的操作系统都支持分叉或捕获命令的输出,这条复杂
  674.             的语句 也许不可移植。

  675.             将 $^X
  676.             的值用作一个文件的路径名并不安全,因为某些为可执行文件使用强制后
  677.             缀 的操作系统在调用一个命令时并不需要使用该后缀。要将 $^X
  678.             的值还原为路径名, 可以用如下语句:

  679.               # Build up a set of file names (not command names).
  680.               use Config;
  681.               $this_perl = $^X;
  682.               if ($^O ne 'VMS')
  683.                  {$this_perl .= $Config{_exe}
  684.                       unless $this_perl =~ m/$Config{_exe}$/i;}

  685.             由于许多操作系统允许任何对 Perl
  686.             程序文件具有读权限的用户复制该文件、对其打
  687.             补丁并执行之,对安全敏感的 Perl 程序员应注意调用 perl
  688.             的安装副本而不是 $^X
  689.             引用的副本。下面的语句可以完成该目的,产生一个可以作为命令或当作
  690.             文件引用的 路径名。

  691.               use Config;
  692.               $secure_perl_path = $Config{perlpath};
  693.               if ($^O ne 'VMS')
  694.                  {$secure_perl_path .= $Config{_exe}
  695.                       unless $secure_perl_path =~ m/$Config{_exe}$/i;}

  696.     ARGV    对 @ARGV
  697.             里的命令行文件名进行迭代的特殊文件句柄。通常写为角操作符 "<>"
  698.             中的空文件句柄。注意目前 "ARGV" 仅在 "<>" 操作符内具有这一
  699.             特殊效果;在其他位置上它只是一个对应于 "<>"
  700.             打开的最后一个文件的普通 文件句柄。特别地,将 "\*ARGV"
  701.             作为参数传递给期望一个文件句柄的函数时, 函数不一定能自动读取
  702.             @ARGV 中所有文件的内容。

  703.     $ARGV   当读取 <> 时包含当前文件名。

  704.     @ARGV   数组 @ARGV 含有脚本的命令行参数。$#ARGV 通常是参数数量减 1,因为
  705.             $ARGV[0] 是第一个参数,而*不是*程序本身的命令名称。命令名称请见
  706.             $0。

  707.     ARGVOUT 用 -i
  708.             进行原地编辑处理时,这是指向当前打开的输出文件的特殊文件句柄。当
  709.             你需要进行 大量插入操作而不想一直修改 $_
  710.             时,该句柄相当有用。关于 -i 开关请参考 perlrun。

  711.     @F      当打开自动分割模式时,数组 @F 包含读入的一行所产生的域内容。关于
  712.             -a 开关请参考 perlrun。该数组是包内的特殊变量,当运行在 "strict
  713.             'vars'" 模式下且不处于 main 包
  714.             内时,必须对其进行声明或给出完整的包名。

  715.     @INC    数组 @INC 包含一个路径列表,"do EXPR"、"require" 和 "use"
  716.             结构都会在该列表中查找自己 所需的库文件。它的初始值由所有 -I
  717.             命令行开关的参数、默认 Perl 库目录(如 /usr/local/lib/perl)
  718.             和代表当前目录的“.”依次组合而成。(当使用 "-T" 或 "-t" 开启
  719.             污染检查开启时则不会把“.”附加在后面。)
  720.             若需要在运行时修改该变量,你应该使用 "use lib"
  721.             指示符,以便能正确载入平台相关的库:

  722.                 use lib '/mypath/libdir/';
  723.                 use SomeMod;

  724.             你还可以直接在 @INC 中放入 Perl
  725.             代码,以达到在文件包含系统中插入拦截点的目的。这些拦截点
  726.             可以是函数引用、数组引用或 bless 过的对象。细节请参考 "require"
  727.             in perlfunc

  728.     @_      在某个函数内,数组 @_ 包含传递给该函数的所有参数。参见 perlsub。

  729.     %INC    散列表 %INC 含有若干项,每一项都代表由 "do"、"require" 和 "use"
  730.             运算符包含进来的一个
  731.             文件。散列键是包含处给定的文件名(模块名已转换为路径名),散列值为
  732.             找到该文件的位置。 "require"
  733.             运算符用这个散列表判断某个特定文件是否已经被包含过。

  734.             若某个文件是由拦截点(例如一个函数引用,这些拦截点的说明参见
  735.             "require" in perlfunc)载入的, 那么默认插入 %INC
  736.             的是这个拦截点而不是文件名。但要注意的是,拦截点可能已经自行修改
  737.             了 %INC 中的对应项以提供某些特别信息。

  738.     %ENV
  739.     $ENV{expr}
  740.             散列表 %ENV 含有当前的环境。对 "ENV" 设置值会改变后续 fork()
  741.             出来的所有子进程的环境。

  742.     %SIG
  743.     $SIG{expr}
  744.             散列表 %SIG 包含信号对应的处理器。例如:

  745.                 sub handler {       # 第一个参数是信号名称
  746.                     my($sig) = @_;
  747.                     print "Caught a SIG$sig--shutting down\n";
  748.                     close(LOG);
  749.                     exit(0);
  750.                 }

  751.                 $SIG{'INT'}  = \&handler;
  752.                 $SIG{'QUIT'} = \&handler;
  753.                 ...
  754.                 $SIG{'INT'}  = 'DEFAULT';   # 恢复默认行为
  755.                 $SIG{'QUIT'} = 'IGNORE';    # 忽略 SIGQUIT

  756.             设置为 'IGNORE' 值通常具有忽略该信号的效果,除了 "CHLD"
  757.             信号以外。对于这一特殊情况 的详细说明请见 perlipc。

  758.             下面是其他一些例子:

  759.                 $SIG{"PIPE"} = "Plumber";   # 假定为 main::Plumber (不推荐)
  760.                 $SIG{"PIPE"} = \&Plumber;   # 挺好;假定为当前的 Plumber
  761.                 $SIG{"PIPE"} = *Plumber;    # 有点儿深奥
  762.                 $SIG{"PIPE"} = Plumber();   # 啊!Plumber() 返回的是什么?

  763.             请确保没有使用裸字作为一个信号处理器的名字,免得产生无意中的调用
  764.             。

  765.             如果系统有 sigaction()
  766.             函数,就用它来安装信号处理器。这意味着你能得到可靠的信号处理方式
  767.             。

  768.             默认的信号投递策略在 Perl 5.8.0
  769.             中从立即发送(也即“不安全”)改为了延迟发送,即“安全信号”
  770.             。更多信息请见 perlipc。

  771.             用 %SIG
  772.             散列表也可以设置特定的内部拦截点。在即将打印一条警告信息时,由
  773.             $SIG{__WARN__}
  774.             指定的例程会被调用。警告信息作为第一个参数被传递给该例程。__WARN
  775.             __ 拦截点的存在会消除通常 要打印到 STDERR
  776.             上的警告。你可以利用这一点将警告保存到变量里,或者像这样将警告转
  777.             变为致命错误:

  778.                 local $SIG{__WARN__} = sub { die $_[0] };
  779.                 eval $proggie;

  780.             当即将抛出一个致命异常时,由 $SIG{__DIE__}
  781.             指定的例程会被调用。错误信息作为第一个参数被 传递给该例程。当
  782.             __DIE__
  783.             拦截例程返回后,异常处理会像拦截点不存在一样继续进行,除非拦截例
  784.             程 本身通过 "goto"、循环退出或 die() 的方式结束。"__DIE__"
  785.             处理器在调用过程中被显式关闭,因此 你可以在 "__DIE__"
  786.             处理器中继续 die。"__WARN__" 也具有类似行为。

  787.             由于一个实现的小问题,$SIG{__DIE__} 拦截点即使在 eval()
  788.             内也会被调用。请不要利用这一点复盖 $@
  789.             中挂起的异常或莫名其妙地重载
  790.             CORE::GLOBAL::die()。这一奇特行为在将来应该会被修正为只在
  791.             程序即将退出时调用
  792.             $SIG{__DIE__},这也是最初的目的。不应采用任何其他形式的用法。

  793.             "__DIE__"/"__WARN__" 处理器在一种情况下是很特殊的:
  794.             它们可能会在汇报解析器发现的(可能)错误时被调用。在这种情况下解析
  795.             器可能处于不一致的状态,任何从 这类处理器中 eval Perl
  796.             代码的尝试都可能导致段错误。这意味着处理解析 Perl
  797.             时产生的警告或错误时应 极度小心,像这样:

  798.                 require Carp if defined $^S;
  799.                 Carp::confess("Something wrong") if defined &Carp::confess;
  800.                 die "Something wrong, but could not load Carp to give backtrace...
  801.                      To see backtrace try starting Perl with -MCarp switch";

  802.             这里的第一行只有在调用处理器的对象*不是*解析器时才会执行载入操作
  803.             。第二行只有在 Carp 可用时才打印
  804.             出回溯信息并退出程序。第三行则仅在 Carp 不可用时才会运行。

  805.             额外信息请见 "die" in perlfunc、"warn" in perlfunc、"eval" in
  806.             perlfunc 和 warnings。

  807.   错误指示器
  808.     变量 $@、$!、$^E 和 $?
  809.     含有关于不同类型错误条件的信息,这些错误可能在执行一个 Perl
  810.     程序时产生。这些变量按照到 Perl
  811.     进程和错误报告子系统的“距离”远近排列顺序,它们分别对应由 Perl
  812.     解释器、C 库、操作系统和外部程序检测到的错误。

  813.     为了展示这些变量之间的区别,请考虑以下这个使用了单引号引起字符串的 Perl
  814.     表达式:

  815.         eval q{
  816.             open my $pipe, "/cdrom/install |" or die $!;
  817.             my @res = <$pipe>;
  818.             close $pipe or die "bad pipe: $?, $!";
  819.         };

  820.     当这条语句执行之后,4 个变量都有可能被设置。

  821.     在需要 "eval" 的字符串没有通过编译(若 "open" 或 "close"
  822.     导入的原型错误则可能发生)或者 Perl 代码在执行过程中 die() 掉,则 $@
  823.     变量会被设置。这些情况下 $@ 的值是编译错误信息或 "die" 的
  824.     参数(其中会内插 $! 和 $?)。(另见 Fatal。)

  825.     上面的 eval() 表达式执行后,open()、"<PIPE>" 和 "close" 被翻译成对 C
  826.     运行库的调用,继而 进入操作系统内核。若其中某个调用失败,则 $! 会设置为
  827.     C 库的 "errno" 值。

  828.     在少数操作系统下,$^E 可能含有更详细的错误指示,例如“CDROM
  829.     仓门没有关闭”。不支持扩展错误 信息的系统只是将 $^E 设置为和 $!
  830.     一样的值。

  831.     最后,$? 在外部程序 /cdrom/install 失败时设置为非 0 值。高 8
  832.     位反映出该程序遇到的特定错误 条件(程序的 exit() 值),低 8
  833.     位反映失败方式,例如信号致死或核心转储,细节参见 wait(2)。对比
  834.     仅在检测到错误条件时才设置的 $! 和 $^E,变量 $? 在每个 "wait" 或管道
  835.     "close" 时都会 设置并冲掉旧值。这一行为更接近 $@,后者在每次 eval()
  836.     后总是在失败时设置并在成功时清除。

  837.     更多细节请分别参见 $@、$!、$^E 和 $? 各自的说明。

  838.   关于变量名语法的技术事项
  839.     Perl
  840.     中的变量名可以有多种格式。通常,它们要以下划线或字母开头,这种情况下变量
  841.     名可以任意长(但有 251
  842.     个字符的内部限制)且可包含字母、数字、下划线或特殊序列 "::" 和
  843.     "'"。最后一个 "::" 或 "'" 之前的 部分被当作*包限定符*;参见 perlmod。

  844.     Perl 变量名也可以是一串数字、单个标点或控制符。这些名字都被 Perl
  845.     保留用作特殊用途;例如,全数字的
  846.     名字用来在正则表达式匹配之后保存反向引用捕获的数据。Perl
  847.     对单个控制符的名字具有一套特殊语法:它将 "^X" (脱字符后跟 "X") 理解为
  848.     Ctrl-"X" 字符。例如,记法 $^W (美元符 脱字符 "W") 是一个名字 为单个字符
  849.     Ctrl-"W" 的标量变量。这要比在程序里键入一个字面上的 Ctrl-"W" 好一些。

  850.     最后,在 Perl 5.6 中引入了一个新特性,Perl
  851.     变量名可以是以控制符(更进一步,也可以是脱字符)开头的字母
  852.     数字字符串。这些变量必须写成 "${^Foo}" 的形式;大括号是必需的。"${^Foo}"
  853.     代表了一个名字是 Ctrl-"F" 后跟两个 "o" 的标量。这些变量被 Perl
  854.     保留作将来的特殊用途,但以 "^_" (Ctrl-下划线或
  855.     脱字符-下划线)开头的那些除外。以 "^_" 开头的名字将不会在 Perl
  856.     的未来版本中产生任何特殊含义;因而 可以在程序中安全使用这类名字。但 $^_
  857.     本身*是*保留的。

  858.     以数字、控制符或标点字符开头的 Perl 标识符不受 "package"
  859.     声明的影响,它们始终被强制在 "main" 包里; 另外它们也不受 "strict
  860.     'vars'" 错误的约束。其他一小部分名字也具有同样的豁免权:

  861.             ENV             STDIN
  862.             INC             STDOUT
  863.             ARGV            STDERR
  864.             ARGVOUT         _
  865.             SIG

  866.     特别地,不管当前作用域中的 "package" 声明如何,新形式的特殊变量
  867.     "${^_XYZ}" 总是被放置在 "main" 包里。

  868. BUGS
  869.     由于 Perl 实现时一个不幸的事故,"use English"
  870.     会使程序中所有正则表达式匹配产生显著的效率降低,不管它们 是否出现在 "use
  871.     English" 的作用域里。因此,强烈不推荐在库里使用 "use
  872.     English"。更多信息请参见 CPAN 上的 Devel::SawAmpersand 模块文档 (
  873.     http://www.cpan.org/modules/by-module/Devel/ )。

  874.     在异常处理器中不应该考虑 $^S。$SIG{__DIE__}
  875.     的当前实现令人伤心,很难用它跟踪错误。请避免使用它并 用 "END{}" 或
  876.     CORE::GLOBAL::die 重载来代替之。

  877. TRANSLATORS
  878.     ChaosLawful


复制代码

[ 本帖最后由 flw 于 2006-6-9 15:29 编辑 ]

论坛徽章:
0
发表于 2006-06-07 20:24 |显示全部楼层
继续嫉妒ing。。。。

论坛徽章:
0
发表于 2006-06-07 21:47 |显示全部楼层
up一下,仰慕诸位大侠的无私奉献!

论坛徽章:
0
发表于 2006-06-07 22:45 |显示全部楼层
昨天刚刚打印一份英文版的当字典,感谢!

论坛徽章:
1
2015年辞旧岁徽章
日期:2015-03-03 16:54:15
发表于 2006-06-08 08:02 |显示全部楼层
呵呵,昨天没仔细推敲,今天查看了一下 wiki 的版本记录,
发现开头部分仍然还是我翻译的,起先我还一直以为没有我的功劳呢!
赶紧加上!呵呵。

论坛徽章:
0
发表于 2006-06-08 13:35 |显示全部楼层
感谢 chaoslawful  flw
收藏仔细拜读

论坛徽章:
0
发表于 2006-06-08 16:25 |显示全部楼层
好东东,收藏先!谢谢LZ啊。真是好银

论坛徽章:
0
发表于 2006-06-09 08:40 |显示全部楼层
浏览

论坛徽章:
0
发表于 2006-06-12 17:18 |显示全部楼层
收藏,谢谢了

论坛徽章:
0
发表于 2006-06-13 11:28 |显示全部楼层
flw,怎么有空开始发力了???

做的不错.
您需要登录后才可以回帖 登录 | 注册

本版积分规则 发表回复

  

北京盛拓优讯信息技术有限公司. 版权所有 京ICP备16024965号-6 北京市公安局海淀分局网监中心备案编号:11010802020122 niuxiaotong@pcpop.com 17352615567
未成年举报专区
中国互联网协会会员  联系我们:huangweiwei@itpub.net
感谢所有关心和支持过ChinaUnix的朋友们 转载本站内容请注明原作者名及出处

清除 Cookies - ChinaUnix - Archiver - WAP - TOP