字符串翻转，使用sed

szjrabbit

在看以前的老帖子：http://bbs.chinaunix.net/viewthr ... 6&highlight=sed
其中有个字符串翻转的例子如下，不太明白，各位能不能给解释一下阿，谢谢了。
sed '/\n/!G;s/\(.\)\(.*\n\)/&\2\1/;//D;s/.//'

举例
echo 1234567890|sed '/\n/!G;s/\(.\)\(.*\n\)/&\2\1/;//D;s/.//'
0987654321

oldoger

推荐你看这一篇
http://bbs.chinaunix.net/viewthread.php?tid=336126

oldoger

原帖由 "waker" 发表：
#反转一行中每个字符的顺序(类似"rev")
sed '/\n/!G;s/\(.\)\(.*\n\)/&\2\1/;//D;s/.//'
###假设一行文字是 123
###那么执行后模式空间中的内容应该按下边的顺序变化
执行/\n/!G;得
123\n
然后s/\(.\)\(.*\n\)/&\2\1/;
得
123\n23\n1
执行//D
23\n1
因为是D命令所以从头循环
模式空间有\n
所以/\n/!G;中G不执行
再来s...
23\n3\n21
再D
3\n21
循环,G不执行
再来s...
3\n\n321
再D
\n321
循环
G和s和D都不执行
执行最后的s/.//
321

哈哈，版版的解释

linuxboy823

原帖由 oldoger 于 2009-3-11 11:49 发表

哈哈，版版的解释

又要被我学习了！！

ywlscpl

来个awk的

1. awk -F "" '{for (i=1;i<=NF;i++) a[i]=$i;for (i=NF;i>0;i--)  printf $i;print ""}' file

复制代码

cjaizss

sed -r ':a s/(^|\n)([^\n])([^\n]*)([^\n])(\n|$)/\1\4\n\3\n\2\5/;ta;s/\n//g'
比那个复杂一些

dream3401

echo "1234567"|sed -r ':a s/(^|#)([^#])([^#]*)([^#])($|#)/\1\4#\3#\2\5/;p;ta;s/#//g'
用\n不是太好理解，换一个#,加一个p

[ 本帖最后由 dream3401 于 2009-3-11 13:26 编辑 ]

cjaizss

原帖由 dream3401 于 2009-3-11 13:23 发表
echo "1234567"|sed -r ':a s/(^|#)([^#])([^#]*)([^#])($|#)/\1\4#\3#\2\5/;p;ta;s/#//g'
用\n不是太好理解，换一个#,加一个p

用\n的原因在于\n这个字符在一行中是不会出现的。
而用#
#123是无法翻转的

dream3401

原帖由 cjaizss 于 2009-3-11 13:35 发表

用\n的原因在于\n这个字符在一行中是不会出现的。
而用#
#123是无法翻转的

嗯，是的，我只是刚开始看到你的\n以后理解了好一会儿，为了便于不理解的人看懂，我用#换了一下，真正在应用中\n还是正解，谢谢你分享!

ly5066113

写个好理解的：

sed -r 'G;:a;s/(.)(\n.*)/\2\1/;ta;s/.//'