救命用的！匹配两个文件的某列，然后替换

cosoo

有两个文件：
a.txt

ASDFAS|AF|12341234
TRYERYE|HL|457564
ZXVCZXVC|CD|45745
XCVBCXVB|HC|657457656
ASFJYJYYJJY|OP|34634644

b.txt

AF|AF
HL|HK
CD|CP
HC|HK

如何匹配a的第三列跟b的第一列，如果匹配就用b的第二列替换a 的第三列，如果不匹配则保持不变，也就是变成下面：

ASDFAS|AF|12341234
TRYERYE|HC|457564
ZXVCZXVC|CP|45745
XCVBCXVB|HK|657457656
ASFJYJYYJJY|OP|34634644

springwind426

1. 
   
2. awk -F'|' -v OFS='|' 'NR==FNR{a[FNR]=$1;b[FNR]=$2}NR!=FNR{if(a[FNR]==$2)$2=b[FNR];print}' b.txt a.txt
   

复制代码

ywlscpl

虽然你问的问题错误百出，不过我想这是你要的

1. awk 'BEGIN{FS=OFS="|"}NR==FNR{a[$1]=$2}NR>FNR{if (a[$2]) sub($2,a[$2],$2);print}' b.txt a.txt

复制代码

cosoo

我试了下， 这样好像可以。。。

awk 'BEGIN{OFS=FS="|"}NR==FNR{a[$1]=$2}NR>FNR{$2=a[$2];print}' b.txt a.txt > c.txt

ywlscpl

你觉得if (a[$2])这个条件不需要吗？

如果不匹配则保持不变

springwind426

如果是行对行的匹配，那么

1. 
   
2. awk -F'|' -v OFS='|' 'NR==FNR{a[FNR]=$1;b[FNR]=$2}NR!=FNR{if(a[FNR]==$2)$2=b[FNR];print}' b.txt a.txt
   

复制代码

如果不考虑行对应，只要关键字对应

1. 
   
2. awk 'BEGIN{FS=OFS="|"}NR==FNR{a[$1]=$2}NR>FNR{if (a[$2]) $2=a[$2];print}' b.txt a.txt
   

复制代码

springwind426

原帖由 cosoo 于 2009-4-25 22:25 发表
我试了下， 这样好像可以。。。

awk 'BEGIN{OFS=FS="|"}NR==FNR{a[$1]=$2}NR>FNR{$2=a[$2];print}' b.txt a.txt > c.txt

这个有问题，当没有对应的关键字的时候，a.txt的第二个字段会是空的

ly5066113

判断key值的存在，还是用if ($2 in a)最好
if (a[$2]) 会有2个问题：
1、a[$2]=0或a[$2]=""时，条件为假
2、$2不在a中时，会增加数组a的元素个数，使得数组越来越大

ywlscpl

受教了
以后得注意了