sed程序实现乘法

ly5066113

1. ly5066113@ubuntu:~$ sed --version
   
2. GNU sed version 4.1.5
   
3. Copyright (C) 2003 Free Software Foundation, Inc.
   
4. This is free software; see the source for copying conditions.  There is NO
   
5. warranty; not even for MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE,
   
6. to the extent permitted by law.
   
7. ly5066113@ubuntu:~$ echo '123456789 * 123456789' | sed -f mult.sed
   
8. 15241578750190521
   
9. ly5066113@ubuntu:~$ expr 123456789 \* 123456789
   
10. 15241578750190521
    
11. ly5066113@ubuntu:~$ echo '123456789123456789 * 123456789' | sed -f mult.sed
    
12. 15241578765432099750190521
    
13. ly5066113@ubuntu:~$ expr 123456789123456789 \* 123456789
    
14. expr: *: Numerical result out of range
    
15. ly5066113@ubuntu:~$ echo '123456789123456789 * 123456789' | bc
    
16. 15241578765432099750190521

复制代码

数字越大，计算时间越长，但位数是没有上限的。
没有使用GNU拓展，UNIX下也可以使用。

1. #! /usr/bin/sed -f
   
2. 
   
3. s/ *//g
   
4. s/\*/;/
   
5. s/\([0-9]\)\([0-9]\);/\1a\2;/
   
6. s/\([0-9]\)\([0-9]\)$/\1a\2/
   
7. : a
   
8.         s/\([0-9]\)\([0-9]\)\(aa*\)/\1a\3\2\3/
   
9. t a
   
10. h
    
11. : b
    
12. /;$/!{
    
13.         s/\(.*\)\([0-9]\)\(a*\);\(.*\)\([0-9]\)\(a*\)$/\2*\5\3\6,\1;\4\5\6/
    
14.         t b
    
15.         s/;.*//
    
16.         x
    
17.         s/[0-9]a*$//
    
18.         x
    
19.         G
    
20.         b b
    
21. }
    
22. s/,\n.*//
    
23. s/$/;0*0=0;0*1=0;0*2=0;0*3=0;0*4=0;0*5=0;0*6=0;0*7=0;0*8=0;0*9=0;1*1=1;1*2=2;1*3=3;1*4=4;1*5=5;1*6=6;1*7=7;1*8=8;1*9=9;2*2=4;2*3=6;2*4=8;2*5=10;2*6=12;2*7=14;2*8=16;2*9=18;3*3=9;3*4=12;3*5=15;3*6=18;3*7=21;3*8=24;3*9=27;4*4=16;4*5=20;4*6=24;4*7=28;4*8=32;4*9=36;5*5=25;5*6=30;5*7=35;5*8=40;5*9=45;6*6=36;6*7=42;6*8=48;6*9=54;7*7=49;7*8=56;7*9=63;8*8=64;8*9=72;9*9=81;/
    
24. : c
    
25.         s/\([0-9]\*[0-9]\)\(.*\)\(;\1=\)\([0-9][0-9]*\)/\4\2\3\4/
    
26. t c
    
27. /^[^;]*\*/{
    
28.         s/\([0-9]\)\*\([0-9]\)/\2*\1/
    
29.         b c
    
30. }
    
31. s/;.*//
    
32. s/a/0/g
    
33. h
    
34. : d
    
35. /^[0-9]*$/!{
    
36.         s/,/-/
    
37.         s/,.*//
    
38.         s/$/-;9aaaaaaaaa98aaaaaaaa87aaaaaaa76aaaaaa65aaaaa54aaaa43aaa32aa21a100/
    
39.         : e
    
40.         /^--[^a]/!{
    
41.                 s/^\([0-9a]*\)\([0-9]\)-\([^-]*\)-\(.*;.*\2\(a*\)\2.*\)/\1-\3-\5\4/
    
42.                 s/^\([^-]*\)-\([0-9a]*\)\([0-9]\)-\(.*;.*\3\(a*\)\3.*\)/\1-\2-\5\4/
    
43.                 s/-\(aaaaaaaaa\(a\)\)\{0,1\}\(a*\)\([0-9]*;.*\([0-9]\)\3\5\)/-\2\5\4/
    
44.                 b e
    
45.         }
    
46.         s/^--\([^;]*\);.*/\1/
    
47.         G
    
48.         s/\n[0-9]*,[0-9]*//
    
49.         h
    
50.         b d
    
51. }

复制代码

ywlscpl

tim佳作不断

justlooks

这个看的我头皮发麻

bbgg1983

sed原来也可以如此虚幻！

网中淫

德艺双馨，一代宗师！

iori809

一定要收藏

bbgg1983

up

Shell_HAT

向Tim哥学习

rdcwayx

版主应该给TIM个置顶贴，让他可以随时放些更新的东西。

expert1

膜拜之，但学习不了，还是expr,bc适合我。