免费注册 查看新帖 |

Chinaunix

  平台 论坛 博客 文库
› 论坛 › 操作系统 › AS400 › 请教一下JOBNUM的问题
12
最近访问板块 发新帖
楼主: JTM
打印 上一主题 下一主题

请教一下JOBNUM的问题 [复制链接]

IT_specs

论坛徽章:
0
11楼 [报告]
发表于 2006-07-29 19:28 |只看该作者
测试验证 ：其实我SBMJOB   CMD(DSPLIBL ) SBMFOR(123456/USER/TESTJOB) 这整个动作也是个JOB也有自己的JOBNUM/USER/JOBNMAE ;但是你提交的内容DSPLIBL 也是作为一个JOB 被提交了，（否则不就不叫提交作业了吗）这个JOB的JOBNUM/USER/JOBNAME才是你指定的那个，如果不指定他将和整个SBMJOB动作的是一样的，这个你可以看JOBLOG，
但是不是说每个JOB都是唯一的吗，这里是不是有点矛盾啊？
还要继续请教其他大侠。。。
实战分享：从技术角度谈机器学习入门| 【大话IT】RadonDB低门槛向MySQL集群下战书 | ChinaUnix打赏功能已上线！ | 新一代分布式关系型数据库RadonDB知多少？
xuguopeng

论坛徽章:
0
12楼 [报告]
发表于 2006-07-30 00:18 |只看该作者
这都什么时候的帖子了 又给翻出来了。。。。。。。。

LZ直接说出你的目的好了，饶来饶去都给我饶迷糊了
实战分享：从技术角度谈机器学习入门| 【大话IT】RadonDB低门槛向MySQL集群下战书 | ChinaUnix打赏功能已上线！ | 新一代分布式关系型数据库RadonDB知多少？
coolk

论坛徽章:
0
13楼 [报告]
发表于 2006-08-01 20:21 |只看该作者
有意思，还没试过！但是我想取JOBNUM应该是没有问题的！

[ 本帖最后由 coolk 于 2006-8-1 20:26 编辑 ]
实战分享：从技术角度谈机器学习入门| 【大话IT】RadonDB低门槛向MySQL集群下战书 | ChinaUnix打赏功能已上线！ | 新一代分布式关系型数据库RadonDB知多少？
blogliou

论坛徽章:
0
14楼 [报告]
发表于 2006-08-02 09:31 |只看该作者
使用QUSLJOB  API可获取JOB NUMBER, 转一个sample:



  3. /*-------------------------------------------------------------------*/
  4. /*                                                                   */
  5. /*  CL PROGRAM DESCRIPTION...                                        */
  6. /*                                                                   */
  7. /*                                                                   */
  8. /*   PROGRAM ID: CHKJOBSTS                                           */
  9. /*                                                                   */
  10. /*  DESCRIPTION: This program uses the List Job API to check the     */
  11. /*               status of any given Job based solely on the Job     */
  12. /*               Name.  This program will only return information    */
  13. /*               for a Job if it is Active or on the Job Queue.      */
  14. /*                                                                   */
  15. /*-------------------------------------------------------------------*/
  16. /*                                                                   */
  17. /*  PARAMETER USAGE                                                  */
  18. /*  ===============                                                  */
  19. /*                                                                   */
  20. /*   PARM  USAGE  TYPE  LENGTH  DESCRIPTION                          */
  21. /*   -------------------------------------------------------------   */
  22. /*    #1     I    *CHAR   10    Job Name                             */
  23. /*    #2    I/O   *CHAR   10    User Name                            */
  24. /*                                 Values: '          ' (blank)      */
  25. /*                                         Valid User Id             */
  26. /*    #3    I/O   *CHAR    6    Job Number                           */
  27. /*                                 Values: '      '     (blank)      */
  28. /*                                         Valid Job Number          */
  29. /*    #4     O    *CHAR   10    Job Status                           */
  30. /*                                 Values: '          ' (blank)      */
  31. /*                                         '*ACTIVE   '              */
  32. /*                                         '*JOBQ     '              */
  33. /*                                                                   */
  34. /*-------------------------------------------------------------------*/
  35. /*                                                                   */
  36. /*  INDICATOR USAGE                                                  */
  37. /*  ===============                                                  */
  38. /*                                                                   */
  39. /*                                                                   */
  40. /*                                                                   */
  41. /*                                                                   */
  42. /*-------------------------------------------------------------------*/
  43. /*                                                                   */
  44. /*  MODIFICATION HISTORY                                             */
  45. /*  ====================                                             */
  46. /*                                                                   */
  47. /*                                                                   */
  48. /*  MODIFICATION ID: n/a                                             */
  49. /*             DATE: 9 June 1995                                     */
  50. /*       PROGRAMMER: Kevin J. McDaniel                               */
  51. /*                   Computer Associates International, Inc.         */
  52. /*                   Global Professional Services                    */
  53. /*                   6650 W. Snowville Road                          */
  54. /*                   Brecksville, Ohio  44141                        */
  55. /*                   Tel: 216-838-8200                               */
  56. /*                   Fax: 216-838-4144                               */
  57. /*      DESCRIPTION: Created.                                        */
  58. /*                                                                   */
  59. /*                                                                   */
  60. /*-------------------------------------------------------------------*/
  61. /*                                                                   */
  62. /*  PROGRAM NOTES                                                    */
  63. /*  =============                                                    */
  64. /*                                                                   */
  65. /*  The format used here with API QUSLJOB, will be JOBL0100.         */
  66. /*                                                                   */
  67. /*  Format JOBL0100 contains:                                        */
  68. /*     1 - 10  Job Name                                              */
  69. /*    11 - 20  User Name Used                                        */
  70. /*    21 - 26  Job Number Used                                       */
  71. /*    27 - 42  Internal Job Identifier                               */
  72. /*    43 - 52  Job Status (*** This is what we want)                 */
  73. /*    53 - 53  Job Type                                              */
  74. /*    54 - 54  Job Subtype                                           */
  75. /*    55 - 56  Reserved                                              */
  76. /*                                                                   */
  77. /*-------------------------------------------------------------------*/


  80. CHKJOBSTS:  PGM        PARM(&JOBNAM &JOBUSR &JOBNBR &JOBSTAT)


  83. /*********************************************************************/
  84. /*         D E C L A R E   P R O G R A M   V A R I A B L E S         */
  85. /*********************************************************************/

  87.   /*------------------------------------*/
  88. /*  PARAMETER VARIABLES.              */
  89. /*------------------------------------*/

  91.              DCL        VAR(&JOBNAM) TYPE(*CHAR) LEN(10)
  92.              DCL        VAR(&JOBUSR) TYPE(*CHAR) LEN(10)
  93.              DCL        VAR(&JOBNBR) TYPE(*CHAR) LEN(6)
  94.              DCL        VAR(&JOBSTAT) TYPE(*CHAR) LEN(10)

  96.   /*------------------------------------*/
  97. /*  GENERIC VARIABLES.                */
  98. /*------------------------------------*/

  100.              DCL        VAR(&JOBID) TYPE(*CHAR) LEN(26)
  101.              DCL        VAR(&BIN4) TYPE(*CHAR) LEN(4)
  102.              DCL        VAR(&DEC8) TYPE(*DEC) LEN(8 0)
  103.              DCL        VAR(&LEN) TYPE(*DEC) LEN(8 0)
  104.              DCL        VAR(&LENBIN) TYPE(*CHAR) LEN(4)
  105.              DCL        VAR(&LJENTRY) TYPE(*CHAR) LEN(57)
  106.              DCL        VAR(&LOOP) TYPE(*DEC) LEN(8 0)
  107.              DCL        VAR(&NBR) TYPE(*CHAR) LEN(6)
  108.              DCL        VAR(&STATUS) TYPE(*CHAR) LEN(10)

  110.   /*------------------------------------*/
  111. /*  USER SPACE VARIABLES.             */
  112. /*------------------------------------*/

  114.              DCL        VAR(&USRSPC) TYPE(*CHAR) LEN(20) +
  115.                           VALUE('LJ        QTEMP     ')
  116.              DCL        VAR(&WRKSPC) TYPE(*CHAR) LEN(10) +

  118.   /*------------------------------------*/
  119. /*  ERROR HANDLING VARIABLES.         */
  120. /*------------------------------------*/

  122.              DCL        VAR(&MSGID) TYPE(*CHAR) LEN(7)
  123.              DCL        VAR(&MSG) TYPE(*CHAR) LEN(512)
  124.              DCL        VAR(&MSGDTA) TYPE(*CHAR) LEN(512)
  125.              DCL        VAR(&MSGF) TYPE(*CHAR) LEN(10)
  126.              DCL        VAR(&MSGFLIB) TYPE(*CHAR) LEN(10)
  127.              DCL        VAR(&KEYVAR) TYPE(*CHAR) LEN(4)
  128.              DCL        VAR(&KEYVAR2) TYPE(*CHAR) LEN(4)
  129.              DCL        VAR(&RTNTYPE) TYPE(*CHAR) LEN(2)


  132. /*********************************************************************/
  133. /*      G L O B A L   E R R O R   M E S S A G E   M O N I T O R      */
  134. /*********************************************************************/

  136.              MONMSG     MSGID(CPF0000) EXEC(GOTO CMDLBL(STDERR1))


  139. /*********************************************************************/
  140. /*                          M A I N L I N E                          */
  141. /*********************************************************************/

  143. START:

  145.    /*------------------------------------*/
  146.   /* CREATE A TEMPORARY USER SPACE TO   */
  147. /*  LIST JOBS IN.                     */
  148. /*------------------------------------*/

  150.              RTVJOBA    NBR(&NBR)
  151.              CHGVAR     VAR(%SST(&USRSPC 3 6)) VALUE(&NBR)
  152.              CHGVAR     VAR(&WRKSPC) VALUE(%SST(&USRSPC 1 10))

  154.          /* TRY TO DELETE USER SPACE BEFORE CREATING IT. */
  155.              DLTUSRSPC  USRSPC(QTEMP/&WRKSPC)
  156.                MONMSG     MSGID(CPF0000)

  158.          /* CREAT THE USER SPACE. */
  159.              CALL       PGM(QUSCRTUS) PARM(&USRSPC 'LJSPACE   ' +
  160.                           X'00000100' ' ' '*ALL      ' 'LJ +
  161.                           Temporary User Space')
  162.                  /*----------------------------------------*/
  163.                  /* CREATE USER SPACE PARMS:               */
  164.                  /*----------------------------------------*/
  165.                  /* USER SPACE NAME AND LIBRARY            */
  166.                  /* EXTENDED ATTRIBUTE (LIKE PF, LF, DSPF) */
  167.                  /* INITIAL SIZE                           */
  168.                  /* INITIAL VALUE                          */
  169.                  /* AUTHORITY                              */
  170.                  /* TEXT                                   */
  171.                  /*----------------------------------------*/

  173.   /*------------------------------------*/
  174. /*  GET INFO ABOUT A SPECIFIC JOB.    */
  175. /*------------------------------------*/

  177.              IF         COND(&JOBUSR *EQ ' ') THEN(CHGVAR +
  178.                           VAR(&JOBUSR) VALUE('*ALL      '))
  179.              IF         COND(&JOBNBR *EQ ' ') THEN(CHGVAR +
  180.                           VAR(&JOBNBR) VALUE('*ALL  '))

  182.              CHGVAR     VAR(&JOBID) VALUE(&JOBNAM *CAT &JOBUSR +
  183.                           *CAT &JOBNBR)

  185.          /* USE LIST JOB API. */
  186.              CALL       PGM(QUSLJOB) PARM(&USRSPC 'JOBL0100  ' +
  187.                           &JOBID '*ALL      ')
  188.                  /*----------------------------------------*/
  189.                  /* LIST JOB PARMS:                        */
  190.                  /*----------------------------------------*/
  191.                  /* RECEIVING USER SPACE NAME AND LIBRARY  */
  192.                  /* FORMAT NAME OF INFORMATION TO RECEIVE  */
  193.                  /* QUALIFIED JOB NAME                     */
  194.                  /* JOB STATUS                             */
  195.                  /*----------------------------------------*/

  197.   /*------------------------------------*/
  198. /*  SEE IF ANY JOB INFO WAS FOUND.    */
  199. /*------------------------------------*/

  201.          /* LOOK AT HEADER PORTION TO SEEI IF ANY JOB INFO WAS FOUND. */
  202.              CALL       PGM(QUSRTVUS) PARM(&USRSPC X'00000085' +
  203.                           X'00000004' &BIN4)
  204.                  /*----------------------------------------*/
  205.                  /* RETREIVE USER SPACE PARMS:             */
  206.                  /*----------------------------------------*/
  207.                  /* USER SPACE NAME AND LIBRARY            */
  208.                  /* OFFSET TO # OF ENTRIES - 133 IN HEADER */
  209.                  /* LENGTH OF DATA TO RECEIVE              */
  210.                  /* VAR TO RECEIVE VALUE OF # OF ENTRIES   */
  211.                  /*----------------------------------------*/

  213.    /*------------------------------------*/
  214.   /*  IF NO ENTRIES WERE FOUND, THEN    */
  215. /*   SET THE RETURN CODE AND EXIT.    */
  216. /*------------------------------------*/

  218.              CHGVAR     VAR(&LOOP) VALUE(%BINARY(&BIN4))

  220.              IF         COND(&LOOP *EQ 0) THEN(DO)
  221.                CHGVAR     VAR(&JOBSTAT) VALUE('          ')
  222.                GOTO       CMDLBL(ALLDONE)
  223.                ENDDO

  225.        /*------------------------------------*/
  226.       /* OK, JOBS WERE FOUND, BUT ARE THEY  */
  227.      /* ACTIVE OR ON THE JOBQ?  WE COULD   */
  228.     /* HAVE LOOKED JUST FOR ACTIVE JOBS   */
  229.    /* WITH THE LIST JOB API BUT THIS     */
  230.   /* WOULD HAVE MISSED ANYTHING WAITING */
  231. /* ON THE JOBQ.                       */
  232. /*------------------------------------*/

  234.          /* RETREIVE THE LIST ENTRY LENGTH FROM HEADER OF USER SPACE. */
  235.              CALL       PGM(QUSRTVUS) PARM(&USRSPC X'00000089' +
  236.                           X'00000004' &LENBIN)
  237.                  /*----------------------------------------*/
  238.                  /* RETREIVE USER SPACE PARMS:             */
  239.                  /*----------------------------------------*/
  240.                  /* USER SPACE NAME AND LIBRARY            */
  241.                  /* OFFSET TO SIZE OF ENTRIES - 137 IN HDR */
  242.                  /* LENGTH OF DATA TO RECEIVE              */
  243.                  /* VAR TO RECEIVE VALUE OF ENTRY SIZE     */
  244.                  /*----------------------------------------*/

  246.              CHGVAR     VAR(&LEN) VALUE(%BINARY(&LENBIN))

  248.          /* RETREIVE THE OFFSET TO THE LIST PORTION OF THE USER SPACE. */
  249.              CALL       PGM(QUSRTVUS) PARM(&USRSPC X'0000007D' +
  250.                           X'00000004' &BIN4)
  251.                  /*----------------------------------------*/
  252.                  /* RETREIVE USER SPACE PARMS:             */
  253.                  /*----------------------------------------*/
  254.                  /* USER SPACE NAME AND LIBRARY            */
  255.                  /* OFFSET TO LIST ENTRY - 125 IN HEADER   */
  256.                  /* LENGTH OF DATA TO RECEIVE              */
  257.                  /* VAR TO RECEIVE VALUE OF LIST OFFSET    */
  258.                  /*----------------------------------------*/

  260.              CHGVAR     VAR(&DEC8) VALUE(%BINARY(&BIN4))
  261.              CHGVAR     VAR(&DEC8) VALUE(&DEC8 + 1)

  263.   /*------------------------------------*/
  264. /*  RETREIVE LIST INFORMATION.        */
  265. /*------------------------------------*/

  267. STARTLOOP:  CHGVAR     VAR(%BINARY(&BIN4)) VALUE(&DEC8)

  269.          /* RETREIVE THE ACTUAL LIST ENTRY FROM THE USER SPACE. */
  270.              CALL       PGM(QUSRTVUS) PARM(&USRSPC &BIN4 +
  271.                           &LENBIN &LJENTRY)
  272.                  /*----------------------------------------*/
  273.                  /* RETREIVE USER SPACE PARMS:             */
  274.                  /*----------------------------------------*/
  275.                  /* USER SPACE NAME AND LIBRARY            */
  276.                  /* OFFSET TO LIST ENTRY                   */
  277.                  /* LENGTH OF DATA TO RECEIVE              */
  278.                  /* VAR TO RECEIVE VALUE OF LIST ENTRY     */
  279.                  /*----------------------------------------*/

  281.              CHGVAR     VAR(&STATUS) VALUE(%SST(&LJENTRY 43 10))

  283.              IF         COND((&STATUS *EQ '*ACTIVE   ') *OR +
  284.                              (&STATUS *EQ '*JOBQ     ')) THEN(DO)
  285.                CHGVAR     VAR(&JOBUSR) VALUE(%SST(&LJENTRY 11 10))
  286.                CHGVAR     VAR(&JOBNBR) VALUE(%SST(&LJENTRY 21 6))
  287.                CHGVAR     VAR(&JOBSTAT) VALUE(&STATUS)
  288.                GOTO       CMDLBL(ALLDONE)
  289.                ENDDO

  291. ENDLOOP:    CHGVAR     VAR(&DEC8) VALUE(&DEC8 + &LEN)
  292.              CHGVAR     VAR(&LOOP) VALUE(&LOOP - 1)

  294.              IF         COND(&LOOP *EQ 0) THEN(DO)
  295.                CHGVAR     VAR(&JOBSTAT) VALUE('          ')
  296.                GOTO       CMDLBL(ALLDONE)
  297.                ENDDO

  299.              GOTO       CMDLBL(STARTLOOP)

  301.   /*------------------------------------*/
  302. /*  CLEAN UP AFTER OURSELVES.         */
  303. /*------------------------------------*/

  305. ALLDONE:    DLTUSRSPC  USRSPC(QTEMP/&WRKSPC)
  306.                MONMSG     MSGID(CPF0000)

  308.              GOTO       CMDLBL(ENDPGM)


  311. /*********************************************************************/
  312. /*                E R R O R   H A N D L I N G                        */
  313. /*********************************************************************/

  315. STDERR1:    DMPCLPGM

  317. STDERR2:    RCVMSG     PGMQ(*PRV) MSGKEY(&KEYVAR) RMV(*NO) +
  318.                           KEYVAR(&KEYVAR2) MSG(&MSG) +
  319.                           MSGDTA(&MSGDTA) MSGID(&MSGID) +
  320.                           RTNTYPE(&RTNTYPE) MSGF(&MSGF) +
  321.                           SNDMSGFLIB(&MSGFLIB)

  323.              IF         COND(&RTNTYPE *NE '02') THEN(GOTO +
  324.                           CMDLBL(STDERR3))

  326.              IF         COND(&MSGID *NE ' ') THEN(SNDPGMMSG +
  327.                           MSGID(&MSGID) MSGF(&MSGFLIB/&MSGF) +
  328.                           MSGDTA(&MSGDTA) MSGTYPE(*DIAG))

  330.              IF         COND(&MSGID *EQ ' ') THEN(SNDPGMMSG +
  331.                           MSG(&MSG) MSGTYPE(*DIAG))

  333.              RMVMSG     MSGKEY(&KEYVAR2)

  335. STDERR3:    RCVMSG     MSGKEY(&KEYVAR) MSGDTA(&MSGDTA) +
  336.                           MSGID(&MSGID) MSGF(&MSGF) +
  337.                           SNDMSGFLIB(&MSGFLIB)
  338.              SNDPGMMSG  MSGID(&MSGID) MSGF(&MSGFLIB/&MSGF) +
  339.                           MSGDTA(&MSGDTA) MSGTYPE(*ESCAPE)


  342. /*********************************************************************/
  343. /*                  P R O G R A M   E N D                            */
  344. /*********************************************************************/

  346. ENDPGM:     ENDPGM
复制代码
实战分享：从技术角度谈机器学习入门| 【大话IT】RadonDB低门槛向MySQL集群下战书 | ChinaUnix打赏功能已上线！ | 新一代分布式关系型数据库RadonDB知多少？
blogliou

论坛徽章:
0
15楼 [报告]
发表于 2006-08-02 09:35 |只看该作者
自由格式的user space和QUSLJOB使用(可获取job number)


  2.       *
  3.       * CrtUsrSpc: Create User Space for OS/400 API's
  4.       *
  5.      d QUSCRTUS        pr                  extpgm('QUSCRTUS')
  6.      d   UsrSpc                      20A   const
  7.      d   ExtAttr                     10A   const
  8.      d   InitialSize                 10I 0 const
  9.      d   InitialVal                   1A   const
  10.      d   PublicAuth                  10A   const
  11.      d   Text                        50A   const
  12.      d   Replace                     10A   const
  13.      d   ErrorCode                32766A   options(*nopass: *varsize)
  14.       *
  15.       * --- Prototype for API Retrive User Space
  16.       *
  17.      d QUSRTVUS        pr                  extpgm( 'QUSRTVUS' )
  18.      d   QRtvUserSpace...
  19.      d                               20
  20.      d   QRtvStartingPosition...
  21.      d                                8B 0
  22.      d   QRtvLengthOfData...
  23.      d                                8B 0
  24.      d   QRtvReceiverVariable...
  25.      d                            32048
  26.      d   QRtvError...
  27.      d                              256

  29.       * --- Prototype for API Retrive List Job
  30.       *
  31.      d QUSLJOB         pr                  extpgm( 'QUSLJOB' )
  32.      d   QJobUserSpace...
  33.      d                               20
  34.      d   QJobFormatName...
  35.      d                                8
  36.      d   QJobJobName...
  37.      d                               26
  38.      d   QFldStatus...
  39.      d                               10
  40.      d   QFldError...
  41.      d                              256
  42.      d   QJobType...
  43.      d                                1
  44.      d   QNbrFldRtn...
  45.      d                                8B 0
  46.      d   QKeyFldRtn...
  47.      d                                8B 0 dim( 100 )
  48.       *
  49.      d qcmdexc         pr                  extpgm( 'QCMDEXC' )
  50.      d   os400_cmd                 2000A   options( *varsize ) const
  51.      d   cmdlength                   15P 5                     const
  52.       *
  53.       * Defined variables
  54.       *
  55.      d emailaddress    s             24    inz('abc@xyz.com')
  56.      d size            s             10I 0
  57.      d UsrSpcName      s             20    inz( 'DSPJOB    QTEMP     ' )

  59.       *
  60.       ******************************************************************

  62.      dQUSA0100         DS
  63.      d QUsrSpcOffset...
  64.      d                         1      4B 0
  65.      d QUsrSpcEntries...
  66.      d                         9     12B 0
  67.      d QUsrSpcEntrieSize...
  68.      d                        13     16B 0

  70.      dLJOBINPUT        ds                           qualified
  71.      d  JobName...
  72.      d                         1     10
  73.      d  UserName...
  74.      d                        11     20
  75.      d  JobNumber...
  76.      d                        21     26
  77.      d  Status...
  78.      d                        27     36
  79.      d  UserSpace...
  80.      d                        37     46
  81.      d  UserSpaceLibrary...
  82.      d                        47     56
  83.      d  Format...
  84.      d                        57     64
  85.      d  JobType...
  86.      d                        65     65
  87.      d  Reserved01...
  88.      d                        66     68
  89.      d  Reserved02...
  90.      d                        69     72B 0
  91.       *
  92.      dLJOB100          ds                           qualified
  93.      d  JobName...
  94.      d                         1     10
  95.      d  UserName...
  96.      d                        11     20
  97.      d  JobNumber...
  98.      d                        21     26
  99.      d  InternalJobId...
  100.      d                        27     42
  101.      d  Status...
  102.      d                        43     52
  103.      d  JobType...
  104.      d                        53     53
  105.      d  JobSubType...
  106.      d                        54     54
  107.      d  Reserved01...
  108.      d                        55     56
  109.       *
  110.      dLJOB200          ds                           qualified
  111.      d  JobName...
  112.      d                         1     10
  113.      d  UserName...
  114.      d                        11     20
  115.      d  JobNumber...
  116.      d                        21     26
  117.      d  InternalJobId...
  118.      d                        27     42
  119.      d  Status...
  120.      d                        43     52
  121.      d  JobType...
  122.      d                        53     53
  123.      d  JobSubType...
  124.      d                        54     54
  125.      d  Reserved01...
  126.      d                        55     56
  127.      d  JobInfoStatus...
  128.      d                        57     57
  129.      d  Reserved02...
  130.      d                        58     60
  131.      d  NumberOfFieldsReturned...
  132.      d                        61     64B 0
  133.      d  ReturnedData...
  134.      d                        65   1064
  135.       *
  136.      dLJOB200KEY       ds                           qualified
  137.      d  KeyNumber01...
  138.      d                         1      4B 0
  139.      d  NumberOfKeys...
  140.      d                         5      8B 0
  141.       *
  142.      dLJOBKEYINFO      ds                           qualified
  143.      d  LengthOfInformation...
  144.      d                         1      4B 0
  145.      d  KeyField...
  146.      d                         5      8B 0
  147.      d  TypeOfData...
  148.      d                         9      9
  149.      d  Reserved01...
  150.      d                        10     12
  151.      d  LengthOfData...
  152.      d                        13     16B 0
  153.      d  KeyData...
  154.      d                        17   1016
  155.       *
  156.       *  APIErrDef     Standard API error handling structure.                  *
  157.       *
  158.      dQUSEC            DS
  159.      d  ErrorBytesProvided...
  160.      d                         1      4B 0
  161.      d  ErrorBytesAvailble...
  162.      d                         5      8B 0
  163.      d  ErrorExceptionId...
  164.      d                         9     15
  165.      d  ErrorReserved...
  166.      d                        16     16
  167.       *
  168.      dAPIError         DS
  169.      d APIErrorProvied...
  170.      d                                     LIKE( ErrorBytesProvided )
  171.      d                                     INZ( %LEN( APIError ) )
  172.      d APIErrorAvailble...
  173.      d                                     LIKE( ErrorBytesAvailble )
  174.      d APIErrorMessageID...
  175.      d                                     LIKE( ErrorExceptionId )
  176.      d APIErrorReserved...
  177.      d                                     LIKE( ErrorReserved )
  178.      d APIErrorInformation...
  179.      d                              240A
  180.       *-----------------------------------------------------------------
  181.       * program status dataarea
  182.       *-----------------------------------------------------------------
  183.      d PgmSts         SDS
  184.      d   P1User              254    263
  185.      d   W1Program       *PROC
  186.       *--------------------------------------------------------------*
  187.       * work fields                                                  *
  188.       *--------------------------------------------------------------*
  189.      d Variables       ds
  190.      d   Snipp                        1    inz( '''' )
  191.      d   Count                       15  0 inz(  0   )
  192.      d   KeyCount                    15  0 inz(  0   )
  193.      d   EndPos                      15  0 inz(  0   )
  194.      d   JobbStatus                   4    inz( ' '  )
  195.      d   Subsystem                   20    inz( ' '  )
  196.      d   ReturnCode                   1    inz( ' '  )
  197.      d   FormatName                   8    inz( ' ' )
  198.      d   QualifedJobName...
  199.      d                               26    inz( ' ' )
  200.      d   JobStatus                   10    inz( ' ' )
  201.      d   JobType                      1    inz( ' ' )
  202.      d   NbrOfFldRtn                  8B 0 inz(  0  )
  203.      d   KeyFldRtn                    8B 0 inz(  0  ) dim( 100 )
  204.      d   StartingPosition...
  205.      d                                8B 0 inz(  0  )
  206.      d   LengthOfData...
  207.      d                                8B 0 inz(  0  )
  208.      d   KeyStartingPosition...
  209.      d                                8B 0 inz(  0  )
  210.      d   KeyLengthOfData...
  211.      d                                8B 0 inz(  0  )
  212.      d   ReceiverVariable...
  213.      d                            32048
  214.      d   OS400_Cmd                 2000    inz( ' '  )
  215.      d   CmdLength                   15P 5 inz( %size( OS400_Cmd ) )
  216.      d   True                         1    inz( *on  )
  217.      d   False                        1    inz( *off )
  218.       *
  219.       /free

  221.        //
  222.        // Create a user space
  223.        //
  224.           size = 10000;

  226.          // Create a user space
  227.          QUSCRTUS(UsrSpcName: 'USRSPC': size: x'00': '*ALL':
  228.           'Temp User Space for  QUSLJOB API':  '*YES': APIError);


  231.        exsr CheckStatusOfJob;

  233.        *inlr = *on;
  234.        // *************************************************************
  235.        // check status of an job
  236.        // -------------------------------------------------------------
  237.        begsr CheckStatusOfJob;

  239.        // run API to fill user space with information about all iSeries job

  241.        FormatName = 'JOBL0200';
  242.        QualifedJobName = '*ALL      ' + '*ALL      ' + '*ALL  ';
  243.        JobStatus = '*ACTIVE';
  244.        JobType = '*';
  245.        NbrOfFldRtn = 2;
  246.        KeyFldRtn( 1 ) = 0101;
  247.        KeyFldRtn( 2 ) = 1906;
  248.        callp QUSLJOB( UsrSpcName : FormatName  : QualifedJobName :
  249.                       JobStatus  : APIError    :
  250.                       JobType    : NbrOfFldRtn : KeyFldRtn         );

  252.         // if error message from the retrieve job API then dump program

  254.        if APIErrorMessageID <> ' ';
  255.          dump;
  256.          ReturnCode = True;
  257.          leavesr;
  258.        endif;

  260.        // run API to get user space attribute

  262.        StartingPosition = 125;
  263.        LengthOfData = 16;
  264.        callp QUSRTVUS( UsrSpcName   : StartingPosition  :
  265.                        LengthOfData : ReceiverVariable  :
  266.                        APIError                           );
  267.        QUSA0100 = ReceiverVariable;

  269.         // if error message from the retrieve user space API then dump program

  271.        if APIErrorMessageID <> ' ';
  272.          dump;
  273.          ReturnCode = True;
  274.          leavesr;
  275.        endif;

  277.        // preperation to read from user space

  279.        StartingPosition = QUsrSpcOffset + 1;
  280.        LengthOfData = QUsrSpcEntrieSize;

  282.        // read from user space

  284.        for count = 1 to QUsrSpcEntries;
  285.          callp QUSRTVUS( UsrSpcName   : StartingPosition  :
  286.                          LengthOfData : ReceiverVariable  :
  287.                          APIError                           );
  288.          LJOB200 = ReceiverVariable;
  289.          if APIErrorMessageID <> ' ';
  290.            dump;
  291.            ReturnCode = True;
  292.            leavesr;
  293.          endif;

  295.          // check status of job
  296.          JobbStatus = ' ';
  297.          Subsystem = ' ';
  298.          LJobKeyInfo = LJob200.ReturnedData;
  299.          KeyStartingPosition = 1;
  300.          KeyLengthOfData = LJobKeyInfo.LengthOfInformation;
  301.          for keycount = 1 to LJob200.NumberOfFieldsReturned;
  302.            LJobKeyInfo = %subst( LJob200.ReturnedData :
  303.                                  KeyStartingPosition :
  304.                                  KeyLengthOfData );
  305.            KeyLengthOfData = LJobKeyInfo.LengthOfInformation;
  306.            LJobKeyInfo = %subst( LJob200.ReturnedData :
  307.                                  KeyStartingPosition :
  308.                                  KeyLengthOfData );
  309.            Endpos = LJobKeyInfo.LengthOfData;
  310.            if     LJobKeyInfo.KeyField = 0101;
  311.               JobbStatus = %subst( LJobKeyInfo.KeyData : 1 :  Endpos );
  312.            elseif LJobKeyInfo.KeyField = 1906;
  313.               Subsystem = %subst( LJobKeyInfo.KeyData : 1 : Endpos );
  314.            endif;
  315.            KeyStartingPosition = KeyStartingPosition + KeyLengthOfData;
  316.          endfor;

  318.          // if job in message wait then email message to address in
  319.          // variable email address

  321.          if Jobbstatus = 'MSGW';
  322.             Subsystem = %trim( %subst( Subsystem : 11 : 10 ) ) + '/' +
  323.                         %trim( %subst( Subsystem :  1 : 10 ) );
  324.             os400_cmd = 'snddst type(*lmsg) ' +
  325.                         'tointnet((' + snipp + %trim(EmailAddress) +
  326.                         snipp + ')) dstd(' + snipp +
  327.                         'Job  is in  *MSGW' +
  328.                         snipp + ') longmsg(' + snipp +
  329.                         'Job (' +
  330.                         %trim( LJob200.JobName ) + '/' +
  331.                         %trim( LJob200.UserName ) + '/' +
  332.                         %trim( LJob200.JobNumber ) +
  333.                         ') subsystem ' + %trim( Subsystem ) +
  334.                         ' in status *MSGW' +
  335.                         snipp + ')';
  336.              monitor;
  337.                qcmdexc ( os400_cmd : %size ( os400_cmd ) );
  338.                on-error;
  339.                  dump;
  340.             endmon;
  341.          endif;

  343.          StartingPosition = StartingPosition + LengthOfData;

  345.        endfor;

  347.        endsr;

复制代码

[ 本帖最后由 blogliou 于 2006-8-2 11:35 编辑 ]
实战分享：从技术角度谈机器学习入门| 【大话IT】RadonDB低门槛向MySQL集群下战书 | ChinaUnix打赏功能已上线！ | 新一代分布式关系型数据库RadonDB知多少？
coolk

论坛徽章:
0
16楼 [报告]
发表于 2006-08-02 19:46 |只看该作者
牛！！！
实战分享：从技术角度谈机器学习入门| 【大话IT】RadonDB低门槛向MySQL集群下战书 | ChinaUnix打赏功能已上线！ | 新一代分布式关系型数据库RadonDB知多少？
12
返回列表 发新帖
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 注册

本版积分规则 发表回复

  

北京盛拓优讯信息技术有限公司. 版权所有 京ICP备16024965号-6 北京市公安局海淀分局网监中心备案编号：11010802020122 niuxiaotong@pcpop.com 17352615567
未成年举报专区
中国互联网协会会员  联系我们：huangweiwei@itpub.net
感谢所有关心和支持过ChinaUnix的朋友们 转载本站内容请注明原作者名及出处

清除 Cookies - ChinaUnix - Archiver - WAP - TOP