如何让oracle定时执行一个存储过程呀，谢了

larzy

如何让oracle定时执行一个存储过程呀，谢了

muchen112

dbms_job.submit(jobno,what,next_date,interval)

用what描述要执行的procedure
next_date是指下一次执行的时间
interval 是指隔多长时间执行一次

z-fh

CREATE OR REPLACE PACKAGE SYS.dbms_job IS

  any_instance CONSTANT BINARY_INTEGER := 0;

  -- Parameters are:
  --
  -- JOB is the number of the job being executed.
  -- WHAT is the PL/SQL procedure to execute.
  --   The job must always be a single call to a procedure.  The
  --     routine may take any number of hardcoded parameters.  
  --     Special parameter values recognized are:
  --       job:       an in parameter, the number of the current job
  --       next_date: in/out, the date of the next refresh
  --       broken:    in/out, is the job broken.  The IN values is FALSE.
  --   Always remember the trailing semicolon.
  --   Some legal values of WHAT (assuming the routines exist) are
  --     'myproc( ''10-JAN-82'', next_date, broken);'
  --     'scott.emppackage.give_raise( ''JENKINS'', 30000.00);'
  --     'dbms_job.remove( job);'
  -- NEXT_DATE is the date at which the job will next be automatically run,
  --   assuming there are background processes attempting to run it.
  -- INTERVAL is a date function, evaluated immediately before the job starts
  --   executing.  If the job completes successfully, this new date is placed
  --   in NEXT_DATE.  INTERVAL is evaluated by plugging it into the statement
  --     select INTERVAL into next_date from dual;
  --   INTERVAL must evaluate to a time in the future.  Legal intervals include
  --     'sysdate + 7'                    -- execute once a week
  --     'NEXT_DAY(sysdate,''TUESDAY'')'  -- execute once every tuesday
  --     'null'                           -- only execute once
  --   If INTERVAL evaluates to null and a job completes successfully, then
  --   the job is automatically deleted from the queue.

  PROCEDURE isubmit    ( job       IN  BINARY_INTEGER,
                         what      IN  VARCHAR2,
                         next_date IN  DATE,
                         interval  IN  VARCHAR2 DEFAULT 'null',
                         no_parse  IN  BOOLEAN DEFAULT FALSE);
  -- Submit a new job with a given job number.

  PROCEDURE submit    ( job       OUT BINARY_INTEGER,
                        what      IN  VARCHAR2,
                        next_date IN  DATE DEFAULT sysdate,
                        interval  IN  VARCHAR2 DEFAULT 'null',
                        no_parse  IN  BOOLEAN DEFAULT FALSE,
                        instance  IN  BINARY_INTEGER DEFAULT any_instance,
                        force     IN  BOOLEAN DEFAULT FALSE );
  -- Submit a new job.  Chooses JOB from the sequence sys.jobseq.
  -- instance and force are added for jobq queue affinity
  -- If FORCE is TRUE, then any positive  integer is acceptable as the job
  -- instance. If FORCE is FALSE, then the specified instance must be running;
  -- otherwise the routine raises an exception.
  -- For example,
  --   variable x number;
  --   execute dbms_job.submit(,'pack.proc(''arg1'');',sysdate,'sysdate+1');

  PROCEDURE remove    ( job       IN  BINARY_INTEGER );
  -- Remove an existing job from the job queue.
  -- This currently does not stop a running job.
  --   execute dbms_job.remove(14144);

  PROCEDURE change    ( job       IN  BINARY_INTEGER,
                        what      IN  VARCHAR2,
                        next_date IN  DATE,
                        interval  IN  VARCHAR2,
                        instance  IN  BINARY_INTEGER DEFAULT NULL,
                        force     IN  BOOLEAN DEFAULT FALSE);
  -- Change any of the the user-settable fields in a job
  -- Parameter instance and force are added for job queue affinity
  -- If what, next_date,or interval is null, leave that value as-is.
  -- instance defaults to NULL indicates instance affinity is not changed.
  -- If FORCE is FALSE, the specified instance (to which the instance number
  -- change) must be running. Otherwise the routine raises an exception.
  -- If FORCE is TRUE, any positive  integer is acceptable as the job instance.
  --   execute dbms_job.change( 14144, null, null, 'sysdate+3');

  PROCEDURE what      ( job       IN  BINARY_INTEGER,
                        what      IN  VARCHAR2 );
  -- Change what an existing job does, and replace its environment

  PROCEDURE next_date ( job       IN  BINARY_INTEGER,
                        next_date IN  DATE     );
  -- Change when an existing job will next execute

  PROCEDURE instance ( job        IN BINARY_INTEGER,
                       instance   IN BINARY_INTEGER,
                       force      IN BOOLEAN DEFAULT FALSE);
  -- Change job instance affinity. FORCE parameter works same as in SUBMIT

  PROCEDURE interval  ( job       IN  BINARY_INTEGER,
                        interval  IN  VARCHAR2 );
  -- Change how often a job executes

  PROCEDURE broken    ( job       IN  BINARY_INTEGER,
                        broken    IN  BOOLEAN,
                        next_date IN  DATE DEFAULT SYSDATE );
  --  Set the broken flag.  Broken jobs are never run.

  PROCEDURE run       ( job       IN  BINARY_INTEGER,
                        force     IN  BOOLEAN DEFAULT FALSE);
  --  Run job JOB now.  Run it even if it is broken.
  --  Running the job will recompute next_date, see view user_jobs.
  --    execute dbms_job.run(14144);
  --  Warning: this will reinitialize the current session's packages
  --  FORCE is added for job queue affinity
  --  If FORCE is TRUE, instance affinity is irrelevant for running jobs in
  --  the foreground process. If FORCE is FALSE, the job can be run in the
  --  foreground only in the specified instance. dbms_job.run will raise an
  --  exception if FORCE is FALSE and the connected instance is the wrong one.

  PROCEDURE user_export ( job    IN     BINARY_INTEGER,
                          mycall IN OUT VARCHAR2);
  --  Produce the text of a call to recreate the given job

  PROCEDURE user_export ( job     IN     BINARY_INTEGER,
                         mycall   IN OUT VARCHAR2,
                         myinst   IN OUT VARCHAR2);
  -- Procedure is added for altering instance affinity (8.1+) and perserve the
  -- compatibility
  
  --------------------------------------------------------------
  -- Return boolean value indicating whether execution is in background
  -- process or foreground process
  -------------------------------------------------------------
  FUNCTION background_process RETURN BOOLEAN;


END;

z-fh

包含以下子过程：

Broken()过程。
change()过程。
Interval()过程。
Isubmit()过程。
Next_Date()过程。
Remove()过程。
Run()过程。
Submit()过程。
User_Export()过程。
What()过程。

1、
Broken()过程更新一个已提交的工作的状态，典型地是用来把一个已破工作标记为未破工作。
这个过程有三个参数：job 、broken与next_date。

PROCEDURE Broken (job       IN binary_integer,
                  Broken    IN boolean,
                  next_date IN date :=SYSDATE)

job参数是工作号，它在问题中唯一标识工作。
broken参数指示此工作是否将标记为破——TRUE说明此工作将标记为破，而FLASE说明此工作将标记为未破。
next_date参数指示在什么时候此工作将再次运行。此参数缺省值为当前日期和时间。
2、
Change()过程用来改变指定工作的设置。
这个过程有四个参数：job、what 、next_date与interval。

PROCEDURE Change (job        IN binary_integer,
                  What       IN varchar2,
                  next_date  IN date,
                  interval   IN varchar2)

此job参数是一个整数值，它唯一标识此工作。
What参数是由此工作运行的一块PL/SQL代码块。
next_date参数指示何时此工作将被执行。
interval参数指示一个工作重执行的频度。
3、
Interval()过程用来显式地设置重执行一个工作之间的时间间隔数。
这个过程有两个参数：job与interval。

PROCEDURE Interval (job      IN binary_integer,
                    Interval IN varchar2)

job参数标识一个特定的工作。interval参数指示一个工作重执行的频度。
4、
ISubmit()过程用来用特定的工作号提交一个工作。
这个过程有五个参数：job、what、next_date、interval与no_parse。

PROCEDURE ISubmit (job       IN binary_ineger,
                   What      IN varchar2,
                   next_date IN date,
                   interval  IN varchar2,
                   no_parse  IN booean:=FALSE)

这个过程与Submit()过程的唯一区别在于此job参数作为IN型参数传递且包括一个
由开发者提供的工作号。如果提供的工作号已被使用，将产生一个错误。
5、
Next_Date()过程用来显式地设定一个工作的执行时间。这个过程接收两个参数：job与next_date。
PROCEDURE Next_Date(job         IN binary_ineger,
                    next_date   IN date)
job标识一个已存在的工作。next_date参数指示了此工作应被执行的日期与时间。
6、
Remove()过程来删除一个已计划运行的工作。这个过程接收一个参数：
PROCEDURE Remove(job IN  binary_ineger);
job参数唯一地标识一个工作。这个参数的值是由为此工作调用Submit()过程返回的job参数的值。
已正在运行的工作不能由调用过程序删除。
7、
Run()过程用来立即执行一个指定的工作。这个过程只接收一个参数：
PROCEDURE Run(job IN binary_ineger)
job参数标识将被立即执行的工作。
8、
使用Submit()过程，工作被正常地计划好。
这个过程有五个参数：job、what、next_date、interval与no_parse。

PROCEDURE Submit ( job       OUT binary_ineger,
                   What      IN  varchar2,
                   next_date IN  date,
                   interval  IN  varchar2,
                   no_parse  IN  booean:=FALSE)

job参数是由Submit()过程返回的binary_ineger。这个值用来唯一标识一个工作。
what参数是将被执行的PL/SQL代码块。
next_date参数指识何时将运行这个工作。
interval参数何时这个工作将被重执行。
no_parse参数指示此工作在提交时或执行时是否应进行语法分析——TRUE
指示此PL/SQL代码在它第一次执行时应进行语法分析，
而FALSE指示本PL/SQL代码应立即进行语法分析。
9、
User_Export()过程返回一个命令，此命令用来安排一个存在的工作以便此工作能重新提交。
此程序有两个参数：job与my_call。

PROCEDURE User_Export(job        IN binary_ineger,
                      my_call    IN OUT varchar2)

job参数标识一个安排了的工作。my_call参数包含在它的当前状态重新提交此工作所需要
的正文。
10、
What()过程应许在工作执行时重新设置此正在运行的命令。这个过程接收两个参数：job与what。

PROCEDURE What (job  IN binary_ineger,
                What IN OUT varchar2)

job参数标识一个存在的工作。what参数指示将被执行的新的PL/SQL代码。

一个简单例子：

创建测试表
SQL>; create table a(a date);

表已创建。

创建一个自定义过程
SQL>; create or replace procedure test as
  2  begin
  3  insert into a values(sysdate);
  4  end;
  5  /

过程已创建。

创建JOB
SQL>; variable job1 number;
SQL>;
SQL>; begin
  2  
dbms_job.submit(:job1,'test;',sysdate,'sysdate+1/1440');　　--每天1440分钟，即一分钟运行test过程一次
  3  end;
  4  /

PL/SQL 过程已成功完成。

运行JOB
SQL>; begin
  2  dbms_job.run(:job1);
  3  end;
  4  /

PL/SQL 过程已成功完成。

SQL>; select to_char(a,'yyyy/mm/dd hh24:mi:ss') 时间 from a;

时间
-------------------
2001/01/07 23:51:21
2001/01/07 23:52:22
2001/01/07 23:53:24

删除JOB
SQL>; begin
  2  dbms_job.remove(:job1);
  3  end;
  4  /

PL/SQL 过程已成功完成。

please

好，值得收藏。

larzy

太棒了.....,谢谢了.

muchen112

我创建了一个procedure,目的为了在屏幕上显示出查询结果：
create or replace procedure p_query is
begin
  dbms_output.put_line('job_id    '||'job_title');
  dbms_output.put_line('-----------------------------');
  for jobs_record in (select * from jobs)
  loop
    dbms_output.put_line(jobs_record.job_id||'     '||jobs_record.job_title);
  end loop;
end p_query;

然后定义个一个dbms_job:
var g_jobno number
begin
  dbms_jobs(:g_jobno,'p_query;',sysdate,'sysdate+1/1440');
  dbms_jobs.run(:g_jobno);
end;

我希望的是每隔1分钟在屏幕上显示一次查询结果，但结果只显示了一次，没有定时显示，请教原因，如何解决？谢谢！