去掉最大值和最小值然后求平均值

blackold

回复 19# yestreenstars


   

w630866139

awk 看到了就感觉蛋疼菊紧 不相信爱情了

seesea2517

@yjwan
@代号：军刀
@yestreenstars
@w630866139

我觉得要写成一行就不好理解，写成文件来，加点注释应该就好看一点了。

这是一个尝试：

1. BEGIN {
   
2.     OFS = FS
   
3. }
   
4. 
   
5. {
   
6.     ar_person_info[$1] = $1 OFS $2 OFS $3       # 看样本，每个人的前三列都是一样的吧，就记录一份人物信息数据
   
7.     ar_person_count[$1]++                       # 统计某人的出现次数
   
8. 
   
9.     refresh_max($1, $4, $5)                     # 更新某人列四的最大值的信息
   
10.     refresh_min($1, $4, $5)                     # 更新某人列四的最小值的信息
    
11. 
    
12.     ar_sum[$1,4] += $4                          # 求和某人列四的值
    
13.     ar_sum[$1,5] += $5                          # 求和某人列五的值
    
14. }
    
15. 
    
16. END {
    
17.     for (name in ar_person_count)
    
18.     {
    
19.         print ar_person_info[name] OFS calc_agv(name, 4) OFS calc_agv(name, 5)
    
20.     }
    
21. }
    
22. 
    
23. # 更新某人第四列的最大值的信息
    
24. # 参数：人名，第四列新值，第五列新值
    
25. function refresh_max(name, new_value_4, new_value_5)
    
26. {
    
27.     # 若第一次更新，则直接赋值，不需要比较
    
28.     if (ar_person_count[name] == 1)
    
29.     {
    
30.         ar_max[name,4] = new_value_4
    
31.         ar_max[name,5] = new_value_5
    
32.         return
    
33.     }
    
34. 
    
35.     # 若新值不大于现有值，则不操作
    
36.     if (new_value_4 <= ar_max[name,4])
    
37.         return
    
38. 
    
39.     # 更新最大值
    
40.     ar_max[name,4] = new_value_4
    
41.     ar_max[name,5] = new_value_5
    
42. }
    
43. 
    
44. # 更新某人第几列的最小值的信息
    
45. # 参数：人名，第四列新值，第五列新值
    
46. function refresh_min(name, new_value_4, new_value_5)
    
47. {
    
48.     # 若第一次更新，则直接赋值，不需要比较
    
49.     if (ar_person_count[name] == 1)
    
50.     {
    
51.         ar_min[name,4] = new_value_4
    
52.         ar_min[name,5] = new_value_5
    
53.         return
    
54.     }
    
55. 
    
56.     # 若新值不小于现有值，则不操作
    
57.     if (new_value_4 >= ar_min[name,4])
    
58.         return
    
59. 
    
60.     # 更新最小值
    
61.     ar_min[name,4] = new_value_4
    
62.     ar_min[name,5] = new_value_5
    
63. }
    
64. 
    
65. # 计算某个人第几列的平均值
    
66. # 对超过 3 个的人做去最大最小值后再求平均值，不超过的直接求平均值
    
67. # 参数：人名，列数
    
68. function calc_agv(name, col)
    
69. {
    
70.     # 三次以下的直接求平均值
    
71.     if (ar_person_count[name] < 3)
    
72.     {
    
73.         return ar_sum[name,col] / ar_person_count[name]
    
74.     }
    
75. 
    
76.     # 三次以上的扣除最大最小值再求平均值
    
77.     return (ar_sum[name,col] - ar_max[name,col] - ar_min[name,col]) / (ar_person_count[name] - 2)
    
78. }

复制代码

要说我觉得C/C++是比较好读的一种代码了，不过要是写成这样，那也是难懂啊（开个玩笑，这自然不是字面意义上的C/C++，当然要把好读的程序改成难懂的那不是相当容易嘛，而且还有现成的代码混淆器）：
@cjaizss

++++++++++[>++++++++++[>+<-]<-]>>-.+++++++.---------.++++++++.>>++++[<++++[<+>-]>-]<<+.-------..

yestreenstars

回复 23# seesea2517


    辛苦您了~

seesea2517

回复 24# yestreenstars


    这是寒掺我嘛……

yestreenstars

回复 25# seesea2517


    不是啦，我不是那个意思~写成多行脚本，再加上注释可以帮助新手更好地理解，这一点是极好的~

w630866139

seesea2517 发表于 2013-03-29 10:05
@yjwan
@代号：军刀
@yestreenstars

爱你~么么思密达~~~

seesea2517

回复 26# yestreenstars


@w630866139
嗯，对我这个新手很有帮助，我已经把 awk 当 C 来写了

w630866139

seesea2517 发表于 2013-03-29 11:09
回复 26# yestreenstars

c早就忘光了 T_T