匹配中文字符串

zaiai2014

   我有这样的公式： 收入 = 门诊收入 + 住院收入， 还有一个哈希表，收入-> payin, 门诊收入 -> outp_payin, 住院收入 -> inp_payin。
  现在首先需要从公式中，将【收入】，【门诊收入】，【住院收入】这些中文字符串解析出来，然后替换为哈希表的相应值。

  1 。通过perl，首先的问题是字符集的问题， unicode, utf8，这些编码方式，从数据库提取出来，就需要进行decode等相应转化，这个就搞得不太清楚，希望有高手指点一二；
  2。然后就是如何解析出来中文字符串，英文的好像可以，有比较多的例子，中文字符的例子也很多\p{han}+，但是如何通过正则表达式解析中文字符串不太清楚。
  3。最后就是解析出来，进行替换。也会牵扯到字符串的替换，所以不能简单将收入都替换为payin，payin = 门诊payin + 住院payin。那就不是所想要的了。


  
  

jason680

回复 1# zaiai2014

Windows中文 - 编码！编码！！
http://bbs.chinaunix.net/thread-1857627-1-1.html

【分享】Perl读取和生成、显示UTF-8文本、UTF-16文本
http://bbs.chinaunix.net/forum.php?mod=viewthread&tid=4117501


simple example for your reference

$ cat pay.pl
#! /usr/bin/perl

use strict;
use warnings;

use utf8;
binmode(STDIN, ':encoding(utf8)');
binmode(STDOUT, ':encoding(utf8)');
binmode(STDERR, ':encoding(utf8)');

my %hTr = (
  收入 => "payin",
  门诊收入 => "outp_payin",
  住院收入 => "inp_payin",
);
while(<DATA>){
  print $_;
  my $cnt = 0;
  while(m/(\p{han}+)/g){
    print ++$cnt,"=$1\n";
  }
  s/(\p{han}+)/$hTr{$1}/g;
  print "En: $_";
}

__DATA__
收入 = 门诊收入 + 住院收入

$ ./pay.pl
收入 = 门诊收入 + 住院收入
1=收入
2=门诊收入
3=住院收入
En: payin = outp_payin + inp_payin

   

zaiai2014

先接受我的感谢！特别感谢。我试试看。

zaiai2014

也许是perl版本的问题，您的代码不能正确执行。
我使用的是Ubuntu 12.04 , perl 5.14.2
下面的正确执行：
----------------------------代码-----------------------------------------------
#!/usr/bin/perl

#解决了汉字匹配的问题，原因不太明白。20140320 绥德
use v5.14.2;


use utf8;
#use Encode qw(encode);
use open ":encoding( utf8 )", ":std";

my %hTr = (
  收入 => "payin",
  门诊收入 => "outp_payin",
  住院收入 => "inp_payin",
);

say %hTr;


while(<DATA>){
  print $_;
  my $cnt = 0;
  while(m/(\p{han}+)/g){
    say ++$cnt,"=$1\n";   
  }
  s/(\p{han}+)/$hTr{$1}/g;
  print "En: $_"
}

my $forum = "收入 = 门诊收入 + 住院收入";

#$forum = encode("UTF-8",$forum);

say $forum;

if ($forum =~ m/(\p{han}+)/g) {
    say "matched $1";
}


$forum =~ s/(\p{han}+)/$hTr{$1}/g;

say $forum;


__DATA__
收入 = 门诊收入 + 住院收入

----------------------------代码-----------------------------------------------


运行的结果，
hengaini@hengaini:~/temp/chinese$ perl chinese_replace.pl
住院收入inp_payin门诊收入outp_payin收入payin
收入 = 门诊收入 + 住院收入
1=收入
匹配了!
2=门诊收入
匹配了!
3=住院收入
匹配了!
En: payin = outp_payin + inp_payin
收入 = 门诊收入 + 住院收入
matched 收入
payin = outp_payin + inp_payin

zaiai2014

在windows 7 下面，还需要修改一下，如下代码：

#!/usr/bin/perl

#解决了汉字匹配的问题，原因不太明白。20140320 绥德
use v5.14.2;


use utf8;
#use Encode qw(encode);
use open ":encoding(gbk)", ":std";  #注意这里999999

my %hTr = (
  收入 => "payin",
  门诊收入 => "outp_payin",
  住院收入 => "inp_payin",
);

say %hTr;


while(<DATA>){
  print $_;
  my $cnt = 0;
  while(m/(\p{han}+)/g){
    say ++$cnt,"=$1\n";   
  }
  s/(\p{han}+)/$hTr{$1}/g;
  print "En: $_"
}

my $forum = "收入 = 门诊收入 + 住院收入";

#$forum = encode("UTF-8",$forum);

say $forum;

if ($forum =~ m/(\p{han}+)/g) {
    say "matched $1";
}


$forum =~ s/(\p{han}+)/$hTr{$1}/g;

say $forum;


__DATA__
收入 = 门诊收入 + 住院收入

运行的情况如下：
c:\temp\perl\programming>perl chinese_replace.pl
住院收入inp_payin门诊收入outp_payin收入payin
收入 = 门诊收入 + 住院收入
1=收入

2=门诊收入

3=住院收入

En: payin = outp_payin + inp_payin
收入 = 门诊收入 + 住院收入
matched 收入
payin = outp_payin + inp_payin

unix666

是Perl做的医院管理？

zaiai2014

说对了，就是这个业务范围。