另类平均值求法

秋天的絮儿

Dear:
第7行连续相同的话，求该连续行第三列的平均值并写在列的最后。



------------------------------------------------------------------
源文件：

1. a       b       3       q       e       w       aaa
   
2. a       b       4       q       e       w       bbb
   
3. a       b       5       q       e       w       bbb
   
4. a       b       5       q       e       w       ccc
   
5. a       b       5       q       e       w       ccc
   
6. a       b       4       q       e       w       aaa
   
7. a       b       8       q       e       w       aaa
   
8. a       b       2       q       e       w       ccc
   
9. a       b       5       q       e       w       ccc
   

复制代码

目标文件：

1. a        b        3        q        e        w        aaa        3
   
2. a        b        4        q        e        w        bbb        4.5
   
3. a        b        5        q        e        w        bbb        4.5
   
4. a        b        5        q        e        w        ccc        5
   
5. a        b        5        q        e        w        ccc        5
   
6. a        b        4        q        e        w        aaa        6
   
7. a        b        8        q        e        w        aaa        6
   
8. a        b        2        q        e        w        ccc        3.5
   
9. a        b        5        q        e        w        ccc        3.5
   

复制代码

yestreenstars

1. #!/usr/bin/awk -f
   
2. {
   
3.         a[NR]=$0
   
4.         b[NR]=$3
   
5.         c[NR]=$7
   
6. }
   
7. END{
   
8.         for(i=0;i++<NR;){
   
9.                 if(c[i+1]==c[i]){
   
10.                         j=i
    
11.                         sum=b[j]
    
12.                         while(c[j+1]==c[j]){
    
13.                                 sum+=b[j+1]
    
14.                                 j++
    
15.                         }
    
16.                         avg=sum/(j-i+1)
    
17.                         while(i<=j){
    
18.                                 print a[i]"\t"avg
    
19.                                 i++
    
20.                         }
    
21.                         i=j
    
22.                 }else{
    
23.                         print a[i]"\t"b[i]
    
24.                 }
    
25.         }
    
26. }

复制代码

blackold

1. $ awk 'NR==FNR{if($7!=p){if(NR!=1)a[np]=s/c;np=NR;s=$3;c=1}else {s+=$3;c++};p=$7;next}FNR==1{a[np]=s/c}{if(a[FNR]) p=a[FNR];print $0,p}' urfile urfile

复制代码

秋天的絮儿

回复 3# blackold


    膜拜黑哥。

秋天的絮儿

回复 2# yestreenstars


    谢谢，可以使用

ly5066113

1. awk '$NF!=v{i++}FNR==1{i=1}{k=$NF""i}NR==FNR{c[k]++;s[k]+=$3}NR>FNR{print $0,s[k]/c[k]}{v=$NF}' file file

复制代码

hujysh

都很牛，答案都出来了，我承认题目都没有看懂

rulebook

1. awk 'NR>1&&$7!=c{for(i=1;i<=x;i++)print d[i]"\t"a/b;a=0;b=0;x=0}{a=a+$3;b++;c=$7;x++;d[x]=$0}END{for(i=1;i<=x;i++)print d[i]"\t"a/b}' a.txt

复制代码

cao627

1. $ echo | awk 'NR>1&&$7!=c||NR!=FNR{for(i=1;i<=x;i++)print d[i]"\t"a/b;a=0;b=0;x=0}{a=a+$3;b++;c=$7;x++;d[x]=$0}'  a.txt  -

复制代码

jason680

回复 1# 秋天的絮儿

How about this way with read FILE one times only

$ awk 'function out(){for(n=1;n<=c;n++)print a[n]"\t"s/c;s=c=0}{if(S7!=$7)out();s+=$3;a[++c]=$0;S7=$7}END{out()}' FILE
a       b       3       q       e       w       aaa        3
a       b       4       q       e       w       bbb        4.5
a       b       5       q       e       w       bbb        4.5
a       b       5       q       e       w       ccc        5
a       b       5       q       e       w       ccc        5
a       b       4       q       e       w       aaa        6
a       b       8       q       e       w       aaa        6
a       b       2       q       e       w       ccc        3.5
a       b       5       q       e       w       ccc        3.5