两列数据如何转化成矩阵

tainche

各位大神，如何将下面两列数据转化成矩阵呢
0553pv        Target
0190pt        823
0370pt        770
0543pt        769
0554nv        Target
0190pt        961
0023nt        942
0036nt        924
0555pv        Target
0029pt        901
0118pt        875
0434pt        842
如何转化成矩阵？ 我想把第一列以pv结尾的名字作为矩阵的第一列，然后以pt命名的作为第一行，首先按照pv分割，每两个pv之间的pt内容是表述上面一个pv性质的。假设0553pv下面有0190pt，值为823,，那么在第一行第一列就是823.
           0190pt        0370pt        0543pt        0023pt        0036pt        0029pt        0118pt        0434pt
0553pv        823        770        769        0        0        0        0        0
0554nv        961        0        0        942        924        0        0        0
0555pv        0        0        0        0        0        901        875        842

我是新手，对于这个复杂的情况就不会整了，请教各位大神

haooooaaa

1. awk '$1~/v$/{s=$1;next}{if(l!~$1)l=l?l"\t"$1:$1;h[s][$1]=$2}END{split(l,t);print "\t"l;for(i in h){s=i;for(j in t)s=h[i][t[j]]?s"\t"h[i][t[j]]:s"\t"0;print s}}' file
   
2.         0190pt  0370pt  0543pt  0023nt  0036nt  0029pt  0118pt  0434pt
   
3. 0554nv  961     0       0       942     924     0       0       0
   
4. 0555pv  0       0       0       0       0       901     875     842
   
5. 0553pv  823     770     769     0       0       0       0       0
   

复制代码

songyc_2015

1. $ awk '
   
2. /Target$/{
   
3.      s=$1
   
4.      a[++x]=$1
   
5.      next
   
6. }
   
7. {
   
8.     b[s,$1]=$2
   
9.     if(!d[$1]++)
   
10.         c[++y]=$1
    
11. }
    
12. END{
    
13.     for(i=1;i<=x;i++){
    
14.         if(i==1){
    
15.              for(k=1;k<=y;k++){
    
16.                  p="\t"c[k]
    
17.                  p=k==y?p"\n":p
    
18.                  printf p
    
19.              }
    
20.         }
    
21.         for(j=1;j<=y;j++){
    
22.             p=b[a[i],c[j]]?b[a[i],c[j]]:0
    
23.             p=j==1?a[i]"\t"p:p
    
24.             p=j==y?p"\n":p"\t"
    
25.             printf p
    
26.         }
    
27.     }
    
28. }' file
    
29.         0190pt  0370pt  0543pt  0023nt  0036nt  0029pt  0118pt  0434pt
    
30. 0553pv  823     770     769     0       0       0       0       0
    
31. 0554nv  961     0       0       942     924     0       0       0
    
32. 0555pv  0       0       0       0       0       901     875     842

复制代码

Herowinter

回复 1# tainche

1. 
   
2. awk '{if($1~/(pv|nv)$/){a[++n]=$1;m=$1}else if($1~/(pt|nt)$/){b[m,$1]=$2;if(!c[$1]++)head=length(head)?head"\t"$1:$1}} END{print "\t"head;l=split(head,d,"\t");for(i=1;i<=n;i++){s=a[i];for(j=1;j<=l;j++)s=length(b[a[i],d[j]])?s"\t"b[a[i],d[j]]:s"\t0";print s}}' urfile
   
3. 
   
4.         0190pt  0370pt  0543pt  0023nt  0036nt  0029pt  0118pt  0434pt
   
5. 0553pv 823     770     769     0       0       0       0       0
   
6. 0554nv  961     0       0       942     924     0       0       0
   
7. 0555pv  0       0       0       0       0       901     875     842
   

复制代码

tainche

回复 3# songyc_2015


    多谢大神，不过在服务器上运行报错，awk: $1~/v$/{s=$1;next}{l=l?l"\t"$11;h[$1]=$2}END{split(l,t);print "\t"l;for(i in h){printf i"\t";for(j in t)printf h[t[j]]?h[t[j]]"\t":0"\t";print ""}}
awk:                                       ^ syntax error

按照楼下大神的方法已搞定，多谢

tainche

回复 3# songyc_2015


    多谢大神帮忙，搞定了，膜拜中

sync_1521

1. awk '$1~/v$/{a[++m]=$1;next}{b[a[m],$1]=$2;if(!c[$1]++){head=head"\t"$1;d[++n]=$1}}END{print head;for(i=1;i<=m;i++){s=a[i];for(j=1;j<=n;j++){k=b[a[i],d[j]];k=k?k:0;s=s"\t"k}print s}}'

复制代码

tainche

回复 7# sync_1521

不好意思，信誉积分只剩2了，只能在此拜谢了