文件行合并问题，求助

lrz

有一文件内容如下：
582.7X497.3
文件1 285.6X464.9
文件2 285.8X464.9
.......
02/21/12 16:09:06
%
803.7X350.9
文件1 160.6X350.9
文件2 159.4X350.1
文件3 160.6X350.9
........
02/21/12 17:03:18
%
每段内容用%分隔，现要将每段内容的第一行和最后一行合并，格式变为：
总尺寸：582.7X497.3     时间：2012-02-21    16:09
文件1 285.6X464.9
文件2 285.8X464.9
.......
%
总尺寸：803.7X350.9   时间：2012-02-21  17:03
文件1 160.6X350.9
文件2 159.4X350.1
文件3 160.6X350.9
........
%

请求帮忙一下，谢谢！

sync_1521

1. awk '/%/{if(s){"date -d \""m"\" \"+%F %H:%M\""|getline n;sub("^[^\n]*","总尺寸：& 时间："n,s);print s"\n"$0;s=m=""};next}{s=s?s"\n"m:m;m=$0}'  1
   
2. 总尺寸：582.7X497.3 时间：2012-02-21 16:09
   
3. 文件1 285.6X464.9
   
4. 文件2 285.8X464.9
   
5. .......
   
6. %
   
7. 总尺寸：803.7X350.9 时间：2012-02-21 17:03
   
8. 文件1 160.6X350.9
   
9. 文件2 159.4X350.1
   
10. 文件3 160.6X350.9
    
11. ........
    
12. %

复制代码

jason680

回复 1# lrz

$ awk 'BEGIN{RS="% *\n*";FS=OFS="\n"}NF>2{N=NF-1;sub(/:..$/,"",$N);$1="总尺寸："$1"\t时间："$N;--NF;$NF=RT;printf $0}' FILE
总尺寸：582.7X497.3        时间：02/21/12 16:09
文件1 285.6X464.9
文件2 285.8X464.9
.......
%
总尺寸：803.7X350.9        时间：02/21/12 17:03
文件1 160.6X350.9
文件2 159.4X350.1
文件3 160.6X350.9
........
%

   

lrz

sync_1521 发表于 2016-01-21 22:26

0lrz@01:05 Tmpfs $awk '/%/{if(s){"date -d \""m"\" \"+%F %H:%M\""|getline n;sub("^[^\n]*","总尺寸：& 时间："n,s);print s"\n"$0;s=m=""};next}{s=s?s"\n"m:m;m=$0}'  output_file1.tmp

awk: cmd. line:1: (FILENAME=output_file1.tmp FNR=6092) fatal: cannot open pipe `date -d "03/12/06 10:51:53" "+%F %H:%M"' (打开的文件过多)

0lrz@01:05 Tmpfs $wc -l output_file1.tmp
33092 output_file1.tmp

晕！

lrz

回复 3# jason680


    时间格式不对，帮忙改一下好吗？对awk不熟悉。

jason680

回复 5# lrz

Here you are

$ awk 'BEGIN{RS="% *\n*";FS=OFS="\n"}NF>2{--NF;split($NF,a,"[/ :]");$1="总尺寸："$1"\t时间：20"a[3]"-"a[1]"-"a[2]"\t"a[4]":"a[5];$NF=RT;printf $0}' FILE
总尺寸：582.7X497.3        时间：2012-02-21        16:09
文件1 285.6X464.9
文件2 285.8X464.9
.......
%
总尺寸：803.7X350.9        时间：2012-02-21        17:03
文件1 160.6X350.9
文件2 159.4X350.1
文件3 160.6X350.9
........
%

   

sync_1521

回复 4# lrz
改成这样试试

1. awk '/%/{if(s){"date -d \""m"\" \"+%F %H:%M\""|getline n;close("date -d \""m"\" \"+%F %H:%M\"");sub("^[^\n]*","总尺寸：& 时间："n,s);print s"\n"$0;s=m=""};next}{s=s?s"\n"m:m;m=$0}'

复制代码

jason680

回复 7# sync_1521

cmd=...; cmd | getline n; close(cmd);
   

sync_1521

回复 8# jason680

学习了

1. awk '/%/{if(s){cmd="date -d \""m"\" \"+%F %H:%M\"";cmd|getline n;close(cmd);sub("^[^\n]*","总尺寸：& 时间："n,s);print s"\n"$0;s=m=""};next}{s=s?s"\n"m:m;m=$0}'

复制代码

lrz

谢谢各位，解决了。
经测试，
awk 'BEGIN{RS="% *\n*";FS=OFS="\n"}NF>2{--NF;split($NF,a,"[/ :]");$1="总尺寸："$1"\t时间：20"a[3]"-"a[1]"-"a[2]"\t"a[4]":"a[5];$NF=RT;printf $0}' FILE
高效点。