sed匹配的字符能否数学计算

REFRESHMM

a文本里所以数字+3怎么写

cjaizss

vim下十分容易
:%s/[0-9]\+/\=submatch(0)+3/g
sed不直接支持数学运算，但是可以用e，不过我不喜欢，
既然不包含e也是图灵完备，当然可以，写一个吧
以下只针对非负整数

1. #!/bin/sed -nrf
   
2. :a
   
3. s/(^|\n)([^0-9\n]+)([0-9][^\n]*)$/\1\2\n\3/
   
4. s/(^|\n)([0-9]+)([^0-9\n][^\n]*)$/\1\2\n\3/
   
5. ta
   
6. 
   
7. s/^/\n\n/
   
8. :b
   
9. s/\n\n([^0-9\n]+)/\1\n/
   
10. tb
    
11. /\n\n[0-9]/ {
    
12.         s/(\n\n[0-9]*)0($|\n)/\13\2/
    
13.         td
    
14.         s/(\n\n[0-9]*)1($|\n)/\14\2/
    
15.         td
    
16.         s/(\n\n[0-9]*)2($|\n)/\15\2/
    
17.         td
    
18.         s/(\n\n[0-9]*)3($|\n)/\16\2/
    
19.         td
    
20.         s/(\n\n[0-9]*)4($|\n)/\17\2/
    
21.         td
    
22.         s/(\n\n[0-9]*)5($|\n)/\18\2/
    
23.         td
    
24.         s/(\n\n[0-9]*)6($|\n)/\19\2/
    
25.         td
    
26.         s/(\n\n[0-9]*)7($|\n)/\1x0\2/
    
27.         s/(\n\n[0-9]*)8($|\n)/\1x1\2/
    
28.         s/(\n\n[0-9]*)9($|\n)/\1x2\2/
    
29.         tc
    
30.         :c
    
31.         s/(\n\n)x/\11/
    
32.         s/(\n\n[0-9]*)0x/\11/
    
33.         s/(\n\n[0-9]*)1x/\12/
    
34.         s/(\n\n[0-9]*)2x/\13/
    
35.         s/(\n\n[0-9]*)3x/\14/
    
36.         s/(\n\n[0-9]*)4x/\15/
    
37.         s/(\n\n[0-9]*)5x/\16/
    
38.         s/(\n\n[0-9]*)6x/\17/
    
39.         s/(\n\n[0-9]*)7x/\18/
    
40.         s/(\n\n[0-9]*)8x/\19/
    
41.         td
    
42.         s/(\n\n[0-9]*)9x/\1x0/
    
43.         tc
    
44.         :d
    
45.         s/\n\n([0-9]+)/\1\n/
    
46. }
    
47. tb
    
48. 
    
49. s/\n//g
    
50. p
    

复制代码

REFRESHMM

这么麻烦 最喜欢sed可以读写源文件 awk和perl也好

REFRESHMM

js:fileStr.replace(/\d+/g,r=>r-0+3)

cjaizss

如果用e，以上代码会简单很多

1. #!/bin/sed -nrf
   
2. :a
   
3. s/(^|\n)([^0-9\n]+)([^\n]*)$/\1echo '\2'\n\3/
   
4. s/(^|\n)([0-9]+)([^\n]*)$/\1expr 3 + \2\n\3/
   
5. ta
   
6. e
   
7. s/\n//g
   
8. p

复制代码

baby_神

回复 2# cjaizss

大佬能解释下不，看的一脸懵逼

legs

perl -pe's#\d+#$&+3#ge'