在DSPF中双子文件的问题，向兄弟们请教！在线等待 ... ...

winner_530

我怎样在一个 DSPF中的一个 SFLCTL中添加第二个 SFL，我现在有一个 DSPF且里面有一个 SFLCTL和一个 SFL，我想再给这个SFLCTL加一个SFL，最终效果就像在SEU里用F15后显示出来的一个样（屏幕中有上下两个子文件而且都可以使用PAGEUP/PAGEDOWN）。

或者要实现在SEU里的F15功能键确定后那样的效果该如何做呢？！

请高手赐教！尽量能给个源代码或怎样在SDA（或DDS）里面添加/设置第二个“子文件”。

兄弟在线等待... ...

xuguopeng

的写2个SUBFILE吧（2个SFL 2个SFLCTL）

以前MICHAEL9406发过一个这样的例程序的

1. The DDS for the two-subfile program.
   
2.      A                                      DSPSIZ(24 80 *DS3)                     
   
3.      A                                      CHGINPDFT(HI UL)                        
   
4.      A                                      ERRSFL                                 
   
5.      A                                      CA03(03 'Exit')                        
   
6.      A                                      CA12(12 'Exit')                        
   
7.      A                                      MOUBTN(*ULD ENTER)                     
   
8.      A          R HEADER                                                            
   
9.      A                                  1 69DATE                                    
   
10.      A                                      EDTCDE(Y)                              
    
11.      A                                  2 69TIME                                    
    
12.      A*                                 3 69SYSNAME                                 
    
13.      A                                  3 69'SYSTEM X'                              
    
14.      A                                  4 69USER                                    
    
15.      A                                  2  7'   __                            _-   
    
16.      A                                      _    ___ _  __          '               
    
17.      A                                  3  7'  / /_ _    __ ___    ___ __ __ / -   
    
18.      A                                      /   / _/(_)/ /___  ___  '               
    
19.      A                                  4  7' / __/| |/|/ // _ \  (_- / // // _-   
    
20.      A                                       \ / _// // // -_)(_-   '               
    
21.      A                                  5  7' \__/ |__,__/ \___/ /___/\_,_//_._-   
    
22.      A                                      _//_/ /_//_/ \__//___/  '               
    
23.      A                                  6  7'                                  -  
    
24.      A                                                              '            
    
25.      A          R SFLA                      SFL                                   
    
26.      A            STATES        10A  O  2  1                                      
    
27.      A          R FMT01                     SFLCTL(SFLA)                          
    
28.      A                                      TEXT('States subfile')               
    
29.      A                                      OVERLAY                              
    
30.      A                                      WINDOW(9 5 8 27 *NOMSGLIN)            
    
31.      A                                      WDWTITLE((*TEXT ' States '))         
    
32.      A  *DS3                                SFLLIN(2)                             
    
33.      A                                      SFLPAG(0012)                          
    
34.      A                                      SFLSIZ(&NBRREC)                       
    
35.      A* (can not use this with SFLLIN)      SFLSNGCHC                             
    
36.      A                                      RTNCSRLOC(&REC &FLD)                  
    
37.      A                                      SFLCSRRRN(&RELRCD)                    
    
38.      A  90                                  SFLDSP                                
    
39.      A  90                                  SFLDSPCTL                             
    
40.      A N90                                  SFLCLR                                
    
41.      A  91                                  SFLEND(*SCRBAR *MORE)                 
    
42.       * Use TopRecIn or RelRcd to set TopRec, which sets the position of SFLA:
    
43.      A            TOPREC         4S 0H      SFLRCDNBR(*TOP)
    
44.      A            TOPRECIN       5S 0H      SFLSCROLL                           
    
45.      A            RELRCD         5S 0H                                            
    
46.      A            NBRREC         5S 0P                                            
    
47.      A            REC           10A  H                                            
    
48.      A            FLD           10A  H                                   
    
49.      A          R SFLB                      SFL                          
    
50.      A            CITIES        20A  O  2  2                             
    
51.      A          R FMT02                     SFLCTL(SFLB)                 
    
52.      A                                      TEXT('Cities subfile')      
    
53.      A                                      RTNCSRLOC(&RECB &FLDB)      
    
54.      A                                      OVERLAY                     
    
55.      A                                      SFLCSRRRN(&RELRCDB)         
    
56.      A  80                                  SFLDSP                       
    
57.      A  80                                  SFLDSPCTL                    
    
58.      A N80                                  SFLCLR                       
    
59.      A  81                                  SFLEND(*SCRBAR *MORE)        
    
60.      A                                      SFLSIZ(&NBRRECB)            
    
61.      A                                      SFLPAG(0006)                 
    
62.      A                                      WINDOW(9 45 8 26 *NOMSGLIN)  
    
63.      A                                      WDWTITLE((*TEXT &TITLE))     
    
64.      A                                      SFLMLTCHC                    
    
65.      A            RELRCDB        5S 0H                                   
    
66.      A            NBRRECB        5S 0P                                   
    
67.      A            RECB          10A  H                                   
    
68.      A            FLDB          10A  H                                   
    
69.      A            TITLE         12A  P                                   
    
70.      A          R FOOTER                                                      
    
71.      A                                      OVERLAY                              
    
72.      A                                 23  3'F3=Exit  F12=Return'                 
    
73.      A                                      COLOR(BLU)                           
    
74.      A                                 20 46'Select as many cities as you like.'  
    
75.      A                                      COLOR(BLU)                           
    
76.      A                                 21 46'Use the space bar or mouse click'   
    
77.      A                                      COLOR(BLU)                           
    
78.      A                                 22 46'to make your selections.'            
    
79.      A                                      COLOR(BLU)                           
    
80.      A          R DUMMY                                                           
    
81.      A                                      TEXT('PREVENTS PREVIOUS SCREEN FROM-  
    
82.      A                                       BEING CLEARED')                     
    
83.      A                                      ASSUME                                
    
84.      A                                  5  9' '                                   
    
85. 
    
86. --------------------------------------------------------------------------------
    
87. 
    
88. 
    
89. 
    
90. 
    
91. This is the RPGIV for the two subfile program
    
92. 
    
93. 
    
94.       *************************************************************
    
95.       * A program to select from 2 different subfiles             *
    
96.       *   11/03  Booth Martin                                     *
    
97.       *                                                           *
    
98.       *                                                           *
    
99.       *************************************************************        
    
100.      H option(*nodebugio)                                          
     
101.      FTEST00D   CF   E             WORKSTN                          
     
102.      F                                     SFILE(SFLA:RRN)         
     
103.      F                                     SFILE(SFLB:RRNB)         
     
104.      FTEST01P   IF   E           K DISK                             
     
105.      FTEST02P   IF   E           K DISK                             
     
106.                                                                     
     
107.      D RRN             S              4S 0                          
     
108.      D RRNB            S              4S 0                          
     
109.      D TopRec          S              4s 0                          
     
110.      D SavedStates     S                   Like(States)            
     
111.       *  ..................................................         
     
112.      C                   EXSR      FillSubfileASR                  
     
113.      C                   EXSR      FillSubfileBSR                  
     
114.                                                                     
     
115.      C                   DoW       *INLR = *Off                     
     
116.      C                   write (e) Header                           
     
117.      C                   write (e) Footer           
     
118.       * set the top of subfile A:
     
119.       *    Here you may choose to have subfile A positioned to either:
     
120.       *    1) The State chosen,                                       
     
121.       *            (use RelRcd >; 0)                                    
     
122.       *    2) or, the same way as SFLA was when the selection was made,
     
123.       *            (use TopRecIn >; 0)                                 
     
124.       *    3) or, always reposition to the beginning of SFLA.         
     
125.       *            (comment or delete this section)                                      
     
126.      C                   If        Relrcd >; 0        
     
127.      C                   eval      TopRec = RelRcd   
     
128.      C*                  If        TopRecIn >; 0      
     
129.      C*                  eval      TopRec = TopRecIn
     
130.      C                   else                       
     
131.      C                   eval      TopRec = 1      
     
132.      C                   endif                     
     
133.                                                    
     
134.      C                   if        FLD = *Blanks   
     
135.      C                   write (e) FMT02            
     
136.      C                   exfmt     FMT01            
     
137.      C                   Read  (e) FMT02            
     
138.      C                   Read  (e) Footer           
     
139.      C                   else                       
     
140.      C                   write (e) FMT01            
     
141.      C                   exfmt     FMT02            
     
142.      C                   Read  (e) FMT01            
     
143.      C                   Read  (e) Footer           
     
144.      C                   endif                     
     
145.                                                    
     
146.      C                   Select                     
     
147.       * Footer Push button Choices:                 
     
148.       * end the job                                 
     
149.      C                   When      *INKC   or      
     
150.      C                             *INKL                                   
     
151.      C                   Eval      *INLR = *ON                             
     
152.                                                                            
     
153.       * Fill cities subfile:                                               
     
154.      C                   When      FLD >; *Blanks                           
     
155.      C     RELRCD        chain (e) SFLA                                    
     
156.      C                   exsr      FillSubfileBSR                          
     
157.                                                                            
     
158.      C                   EndSL                                             
     
159.      C                   END                                               
     
160.       *  _________________________________________________________________         
     
161.      C     FillSubfileAsrBegSR                                             
     
162.       * fill SFLA                                                         
     
163.      C                   eval      RRN  = 0                                
     
164.       * Clear subfile & screen, prepare to re-fill or fill:               
     
165.      C                   Eval      *IN90=*off                              
     
166.      C                   Clear                   SFLA                     
     
167.      C                   Write     FMT01                                   
     
168.      C                   eval      *IN90 = *on                             
     
169.                                                                            
     
170.      C     *LoVal        Setll     Test01P                                 
     
171.      C                   Read      Test01P                                 
     
172.      C                   DoW       Not %EOF(Test01P)                       
     
173.      C                   Eval      RRN = RRN + 1                           
     
174.      C                   Write     SFLA                                    
     
175.      C                   Read      Test01p                                 
     
176.      C                   End                                               
     
177.                                                                            
     
178.      C                   Eval      NBRREC = RRN                           
     
179.      C     RRN           IFLT      5                                       
     
180.      C                   eval      *IN91 = *on                             
     
181.      C                   END                                               
     
182.                                                                            
     
183.      C                   ENDSR                                             
     
184.       *  _________________________________________________________________
     
185.      C     FillSubfileBsrBegSR                                             
     
186.       * fill SFLB                                                         
     
187.      C                   eval      RRNB = 0                                
     
188.                                                                            
     
189.      C                   Eval      *IN80=*off                              
     
190.      C                   Clear                   SFLB                     
     
191.      C                   eval      Title = '  Cities  '                    
     
192.      C                   Write     FMT02                                   
     
193.      C                   eval      *IN80 = *on                             
     
194.                                                                            
     
195.      C                   if        RELRCD = *zeros                        
     
196.      C                   Eval      CITIES = *Blanks                        
     
197.      C                   Eval      RRNB = RRNB + 1                        
     
198.      C                   Write     SFLB                        
     
199.      C                   else                                 
     
200.      C     RELRCD        Chain (e) SFLA                        
     
201.      C                   eval      SavedStates = States        
     
202.      C                   Eval      Title  = ' ' + STATES + ' '
     
203.      C     STATES        Setll     Test02P                     
     
204.      C                   Read (e)  Test02P                     
     
205.      C                   If        States <>; SavedStates or   
     
206.      C                             %EOF(Test02P)               
     
207.      C                   eval      cities = 'No cities listed'
     
208.      C                   Eval      RRNB = RRNB + 1            
     
209.      C                   Write     SFLB                        
     
210.      C                   else                                 
     
211.      C                   DoW       Not %EOF(Test02P) and      
     
212.      C                             States = SavedStates        
     
213.      C                   Eval      RRNB = RRNB + 1            
     
214.      C                   Write     SFLB                        
     
215.      C                   Read      Test02P                     
     
216.      C                   Enddo                                 
     
217.      C                   endif                                 
     
218.      C                   endif                                 
     
219.                                                                
     
220.      C                   Eval      NBRRECB = RRNB              
     
221.      C     RRNB          IFLT      5                           
     
222.      C                   eval      *IN81 = *on                  
     
223.      C                   END                                    
     
224.                                                                
     
225.      C                   EndSR                                 
     
226.       *  _____________________________________________________  
     
227. 
     
228. 
     
229. 
     
230. 
     
231. --------------------------------------------------------------------------------
     
232. 
     
233. 
     
234. 
     
235. 
     
236. The DDS for the two files used in this application
     
237. Name of states file: TEST01P
     
238.      A          R TEST01REC         
     
239.      A            STATES        10                                                   
     
240.      A          K STATES            
     
241. 
     
242. Name of cities file: TEST02P
     
243.      A          R TEST02REC         
     
244.      A            STATES        10  
     
245.      A            CITIES        20  
     
246.      A          K STATES            
     
247.      A          K CITIES         

复制代码

xuguopeng

忘了是不是这个代码了，可以搜索一下MICHAEL9406的精华帖

这些代码只是说明要做2个SFL和2个SFLCTL

winner_530

to xuguopeng ： 这个程序源代码好像只能显示其中一个SFLCTL吧，那能不能同时将两个都显示不来呢？

我想要的结果是和SEU里用F15后显示出来的一个样（屏幕中有上下两个子文件而且都可以使用PAGEUP/PAGEDOWN）。

xuguopeng

我只试过同时显示2个SUBFILE，但是同时只能激活一个SUBFILE

明天我再问问我们的开发人员吧

winner_530

先谢了！

magket

关注。

jamesten

一个SUBCTL只能控制一个SUBFILE吧?