用.cue文件切割.wav文件

skrypto

先发布源代码，再说明干什么用，免得烂在我的硬盘里。

1. #!/usr/bin/env perl
   
2. # This program splits a wav file that contains multiple tracks into multiple wav
   
3. # files, each of which contains one track based on indices provided by a cue file.
   
4. # Written by Shufeng Tan <shufengtan@gmail.com> January, 2007
   
5. # It is assumed that the cue file is in the same directory with the wav file.
   
6. # The cue file with the same basename with the wav file will be picked.
   
7. # Failing that, the program will pick the first cue file listed by DirHandle.
   
8. 
   
9. use strict;
   
10. use Audio::Wav;
    
11. use Data::Dumper;
    
12. use DirHandle;
    
13. use FileHandle;
    
14. use File::Basename;
    
15. 
    
16. my $wavfile = shift;
    
17. die "Usage: $0 file.wav\n" unless $wavfile;
    
18. die "File $wavfile not found.\n" unless -f $wavfile;
    
19. 
    
20. my $cuefile = find_cue_file($wavfile);
    
21. warn "CUE file not found for $wavfile\n" unless $cuefile;
    
22. 
    
23. my $WAV = new Audio::Wav;
    
24. my $read = $WAV->read($wavfile);
    
25. my $details = $read->details;
    
26. my $Track_Details = {
    
27.         bits_sample => $details->{bits_sample},
    
28.         sample_rate => $details->{sample_rate},
    
29.         channels => $details->{channels},
    
30. };
    
31. 
    
32. exit unless $cuefile;
    
33. my @tracks = parse_cue_file($cuefile, $read);
    
34. 
    
35. print "$#tracks tracks from $cuefile\n";
    
36. 
    
37. my $Max_Buf_Len = 1048576;
    
38. 
    
39. foreach my $i (0 .. ($#tracks-1)) {
    
40.         my $track_info = $tracks[$i];
    
41.         my $track = $track_info->{TRACK};
    
42.         my $name = $track_info->{TITLE};
    
43.         my $artist = $track_info->{PERFORMER};
    
44.         my $track_file = "${track}_$name.wav";
    
45.         $track_file =~ tr|/:|  |;
    
46.         my @pos = @{$track_info->{POS}};
    
47.         my $track_len = $tracks[$i+1]->{POS}->[0] - $pos[0];
    
48.         print "TRACK $track '$name' by '$artist' $track_len bytes POS=[@pos]\n";
    
49. 
    
50.         my $write = $WAV->write($track_file, $Track_Details);
    
51.         $write->set_info('software' => 'Audio::Wav', 'artist' => $artist, 'name' => $name);
    
52. 
    
53.         $read->move_to($pos[0]);
    
54.         my $read_len = 0;
    
55.         while($read_len < $track_len) {
    
56.                 my $remain = $track_len - $read_len;
    
57.                 my $buf_len = $remain >= $Max_Buf_Len ? $Max_Buf_Len : $remain;
    
58.                 my $buf = $read->read_raw($buf_len);
    
59.                 my $buf_len2 = length($buf);
    
60.                 $read_len += $buf_len2;
    
61.                 $write->write_raw($buf, $buf_len2);
    
62.                 if ($buf_len != $buf_len2) {
    
63.                         print "Last track: $read_len out of $track_len bytes\n";
    
64.                         last;
    
65.                 }
    
66.         }
    
67.         $write->finish();
    
68. }
    
69. 
    
70. exit;
    
71. 
    
72. sub find_cue_file {
    
73.         my ($file) = @_;
    
74.         if ($file =~ s/\.\w+$/.cue/) {
    
75.                 return $file if -f $file;
    
76.                 $file =~ s/\.cue$/.CUE/;
    
77.                 return $file if -f $file;
    
78.         }
    
79.         my $dir = dirname($file);
    
80.         my $dh = new DirHandle $dir;
    
81.         if (defined $dh) {
    
82.                 while(my $f = $dh->read) {
    
83.                         return "$dir/$f" if $f =~ /\.cue$/i;
    
84.                 }
    
85.         }
    
86. }
    
87. 
    
88. sub parse_cue_file {
    
89.         my ($cuefile, $wav_in) = @_;
    
90.         my $cueh = new FileHandle $cuefile;
    
91.         return unless defined $cueh;
    
92.         my $wav_data = $wav_in->{data};
    
93.         print Data::Dumper->Dump([$wav_data]);
    
94.         return unless defined $wav_data;
    
95.         my $wav_sec = $wav_data->{length};
    
96.         my $wav_offset = $wav_data->{data_start};
    
97.         my $wav_bps = $wav_data->{bytes_sec};
    
98.         my (@tracks, $href);
    
99.         while(<$cueh>) {
    
100.                 chomp;
     
101.                 s/\r$//;
     
102.                 if (/^\s*TRACK\s+(\d+)/i) {
     
103.                         push(@tracks, $href) if defined $href;
     
104.                         $href = { TRACK => $1 };
     
105.                 } elsif (/^\s*INDEX\s+\d+\s+0?(\d+):0?(\d+):0?(\d+)/i) {
     
106.                         my $pos = $wav_offset + ($1*60 + $2) * $wav_bps + $3*$wav_bps/75;
     
107.                         $href->{POS} = exists($href->{POS}) ? [@{$href->{POS}}, $pos] : [$pos];
     
108.                 } elsif (/^\s*(\w+)\s*(\S.*)/) {
     
109.                         my ($key, $val) = ($1, $2);
     
110.                         $val =~ s/^"//;
     
111.                         $val =~ s/"$//;
     
112.                         $href->{$key} = $val if defined $href;
     
113.                 }
     
114.         }
     
115.         if (defined $href) {
     
116.                 push @tracks, $href;
     
117.                 push @tracks, { POS => [$wav_data->{total_length}] };
     
118.         }
     
119.         return @tracks;
     
120. }
     

复制代码

兰花仙子

Good Topic!再写个说明文档吧.

skrypto

话要从bittorrent说起，很多下载的文件都把整盘CD十几首歌放在一个APE文件里，另外配一个CUE文件说明每一首歌的开始和结束时间。
一般来说文件名都叫CDImage.ape和CDImage.cue。

skrypto

APE是一种无损压缩格式，我只知道一个叫Monkey's Audio的软件可以把APE格式解压成WAV格式。
CDImage.ape => CDImage.wav

skrypto

把CDImage.wav和CDImage.cue放在同一个目录里就可以用上面的程序把一个大WAV文件分成几个小文件。

$ ls
CDImage.ape    CDImage.cue    CDImage.wav
$ /usr/local/bin/wavcut.pl CDImage.wav

skrypto

最后别忘了存.wav文件的目录里最好只能有一个.cue文件，如果有好几个.cue文件的话，主文件名（除掉后坠.cue）必须和.wav的相同。要不然回乱套了。

mslk

很不错啊