如何合并满足条件的行

seemvivi

如文本：
100 109
110 119
120 129
130 139
160 169
170 179
如何处理后变为：
100 139
160 179

haooooaaa

1. awk 'a!=$2-10{if(a)print b,a;b=$1}{a=$2}END{print b,a}' file

复制代码

sync_1521

awk '$1!=b+1{if(NR==1){a=$1}else{print a,b;a=$1}}{b=$2}END{print a,b}' file

seemvivi

回复 2# haooooaaa
代码不太理解，可以说明一下吗   谢谢

   

songyc_2015

awk '!f{s=$1;f=1}length(y)&&($1-c!=10){print s,y;s=$1}{y=$2;c=$1}END{print s,y}' file

seemvivi

回复 3# sync_1521
可以说明一下代码吗  谢谢

   

sync_1521

读入第一行 100 109
   模式 $1!=b+1  动作{if(NR==1){a=$1}else{print a,b;a=$1}}
        $1为100  b未定义故为空   100!=(空)+1 成立  于是去执行动作 因为NR==1成立 即赋值a=100
   模式 空       动作{b=$2}
        因为模式为空 故每一行都会执行动作 b=$2 即赋值b=109
        
读入第二行 110 119
   模式 $1!=b+1  动作{if(NR==1){a=$1}else{print a,b;a=$1}}
        $1为110  b为109   110!=109+1 不成立  于是不去执行动作
   模式 空       动作{b=$2}
        因为模式为空 故每一行都会执行动作 b=$2 即赋值b=119
         
读入第三行 120 129
   模式 $1!=b+1  动作{if(NR==1){a=$1}else{print a,b;a=$1}}
        $1为120  b为119   120!=119+1 不成立  于是不去执行动作
   模式 空       动作{b=$2}
        因为模式为空 故每一行都会执行动作 b=$2 即赋值b=129
        
读入第四行 130 139
   模式 $1!=b+1  动作{if(NR==1){a=$1}else{print a,b;a=$1}}
        $1为130  b为129   130!=129+1 不成立  于是不去执行动作
   模式 空       动作{b=$2}
        因为模式为空 故每一行都会执行动作 b=$2 即赋值b=139           
      
读入第五行 160 169
   模式 $1!=b+1  动作{if(NR==1){a=$1}else{print a,b;a=$1}}
        $1为160  b为139   160!=139+1 成立  于是去执行动作 此时NR==5故NR==1不成立，于是执行{print a,b;a=$1} 即输出100 139 同时赋值a=160
   模式 空       动作{b=$2}
        因为模式为空 故每一行都会执行动作 b=$2 即赋值b=169
        
读入第六行 170 179
   模式 $1!=b+1  动作{if(NR==1){a=$1}else{print a,b;a=$1}}
        $1为170  b为169   170!=169+1 不成立  于是不去执行动作
   模式 空       动作{b=$2}
        因为模式为空 故每一行都会执行后面的动作 b=$2 即赋值b=179
        
最后执行END{print a,b}
   此时a=160 b=179 故输出 160 179  

seanking1987

回复 7# sync_1521


学习了~~~这真的是授人以渔啊

jason680

$ awk '{if(S1==""||$1!=S2+1)printf S2$1;S1=$1;S2=" "$2"\n"}END{printf S2}' FILE
100 139
160 179