$num = ${$averages{$entry[0]}}[1] 这个代表什么意思啊？

palladiosh

求教各位大神，在这段代码中，这二句代表什么意思啊？

$temp = ${$averages{$entry[0]}}[0];
$num = ${$averages{$entry[0]}}[1];

假设： entry[0]= 姓名   entry[1] = 学号  entry[2] = 成绩

我对$temp的理解是：如果姓名已经在hash中存在，就将该姓名赋值给$temp
但是$num是什么情况啊？



#!/usr/bin/perl
# This program reads a text file passed as argument
# and computes a mark average for each student
# The format of each line of the input file is:
# name surname,subject_number,mark
# The program uses a hash of arrays with 2 elements each
# The formula used for the recurring average is:
# new_average = (old_average * N + current_value) / (N + 1)


open (INFILE, $ARGV[0]) or die "An input file is required as argument\n";

%averages = ();
while(<INFILE>)
{
  chomp($_);
  @entry = split(/,/, $_);
  #print "1: $entry[0]; 2: $entry[1]; 3: $entry[2]\n"; # test correct reading

  if (exists $averages{$entry[0]})
  {
    # this student is already in the hash:
    $temp = ${$averages{$entry[0]}}[0];
    $num = ${$averages{$entry[0]}}[1];
    $temp = ($temp * $num + $entry[2]) / ($num + 1);
    $num++;
    ${$averages{$entry[0]}}[0] = $temp;
    ${$averages{$entry[0]}}[1] = $num;
  }
  else
  {
    # this is a new student:
    ${$averages{$entry[0]}}[0] = $entry[2];
    ${$averages{$entry[0]}}[1] = 1;
  }
}

substr函数

回复 1# palladiosh

# new_average = (old_average * N + current_value) / (N + 1)

可见，$num就是N啊

MMMIX

回复 1# palladiosh


    array reference 的 dereference。

$temp = ${$averages{$entry[0]}}[0];

写成

$temp = $averages{$entry[0]}->[0]; 可能会更清晰些。

jason680

回复 1# palladiosh

How about this way ...

$ perl avg.pl
Name:John, Average:84
Name:Mary, Average:85

$ cat avg.pl
use strict;
use warnings;

my %hScore = ();
while(<DATA>){
  chomp;
  my($sName, $sNo, $sScore) = split /,/;
  
  if (exists $hScore{$sName}){
    # this student is already in the hash:
    my $rhName = $hScore{$sName};
    $rhName->{'total'} += $sScore;
    $rhName->{'subject'}++;
    $rhName->{'average'} = $rhName->{'total'} / $rhName->{'subject'};
  }
  else{
    # this is a new student:
    $hScore{$sName}->{'total'} = $sScore;
    $hScore{$sName}->{'subject'} = 1;
    $hScore{$sName}->{'average'} = $sScore;
  }
}
foreach my $sName (keys %hScore){
  print "Name:", $sName, ", Average:", $hScore{$sName}->{'average'}, "\n";

}
__DATA__
Mary,math,82
Mary,eng,88
John,math,84