sed如何实现两行的位置交换

cjaizss

是的，我改一下

pooronce

看这代码，似乎是肯定两种特征串都会出现
如果仅出现其中一串的话，好像会把后面的全部吃掉啊
n到末尾没得n的时候，hold space里的东西不会自动打印出的吧？

cjaizss

原帖由 pooronce 于 2008-9-19 09:29 发表
看这代码，似乎是肯定两种特征串都会出现
如果仅出现其中一串的话，好像会把后面的全部吃掉啊
n到末尾没得n的时候，hold space里的东西不会自动打印出的吧？

当然了，如果只有一个则不在考虑之中了

ubuntuer

原帖由 springwind426 于 2008-9-18 18:54 发表

sed '/music/{:a;N;/reallist/!ba;s/\([^\n]*\)\n\(.*\)\n\(.*\)/\3\n\2\n\1/}' 数据文件


解释：
/music/{....}  遇到含有music的行，开始做{}中的命令序列
:a;N;/reallist/!ba  循环读信息，直到读取 ...

springwind兄没有考虑music,和reallist两行是连续的情况
sed '/music/{:a;N;/reallist/!ba;/[^\n]*music[^\n]*\n[^\n]*reallist[^\n]*$/{s/\([^\n]*music[^\n]*\)\n\(.*\)/\2\n\1/}};s/\([^\n]*\)\n\(.*\)\n\(.*\)/\3\n\2\n\1/' test1

当然在先知道是连续的情况下,sed '/Nick/{h;d};/Dale/{G}' test1也是可以的
zj@zj:~/Script/cushell/08.09.19$ cat test1
29/05   b/p      5:35   Nick
29/05   L/c   1:00:00   Dale
01/06   L/c     30:50   Jick
zj@zj:~/Script/cushell/08.09.19$ sed '/Nick/{:a;N;/Jick/!ba;/[^\n]*Nick[^\n]*\n[^\n]*Jick[^\n]*$/{s/\([^\n]*Nick[^\n]*\)\n\(.*\)/\2\n\1/}};s/\([^\n]*\)\n\(.*\)\n\(.*\)/\3\n\2\n\1/' test1
01/06   L/c     30:50   Jick
29/05   L/c   1:00:00   Dale
29/05   b/p      5:35   Nick
zj@zj:~/Script/cushell/08.09.19$ sed '/Nick/{:a;N;/Dale/!ba;/[^\n]*Nick[^\n]*\n[^\n]*Dale[^\n]*$/{s/\([^\n]*Nick[^\n]*\)\n\(.*\)/\2\n\1/}};s/\([^\n]*\)\n\(.*\)\n\(.*\)/\3\n\2\n\1/' test1
29/05   L/c   1:00:00   Dale
29/05   b/p      5:35   Nick
01/06   L/c     30:50   Jick
zj@zj:~/Script/cushell/08.09.19$ sed '/Nick/{h;d};/Dale/{G}' test1
29/05   L/c   1:00:00   Dale
29/05   b/p      5:35   Nick
01/06   L/c     30:50   Jick

sabin541

这样的，由于我的问题比较简单，即两行必同时出现在一个文件中，而且两行不挨着
所以大家的代码基本上都可以实现我的要求。
但如果能产生一段代码
无论两行同时出现与否还是两行挨着与否等等情况都能达到这个效果当然更好了（即越完备越好）。我需要的功能已经完成了，剩下的时间就在大家的讨论中多学点东西了。

cjaizss

我的代码可以满足你开头的要求，但如果具体的要求必须定出来了才好解决。
比如只有music怎么办？
比如music和realist出现在同一行怎么办？
比如有几个music,realist又怎么办？

springwind426

原帖由 ubuntuer 于 2008-9-19 10:57 发表



springwind兄没有考虑music,和reallist两行是连续的情况
sed '/music/{:a;N;/reallist/!ba;/[^\n]*music[^\n]*\n[^\n]*reallist[^\n]*$/{s/\([^\n]*music[^\n]*\)\n\(.*\)/\2\n\1/}};s/\([^\n]*\)\n\(. ...

1. 
   
2. sed '/music/{:a;N;/reallist/!ba;s/\([^\n]*\)\(.*\)\n\(.*\)/\3\2\n\1/}'  数据文件
   

复制代码

试试这个

如果要考虑第一个出现的music可能与reallist是同一行，那么把 /reallist/换成/\n.*reallist/  就强制只匹配与music不在同一行的reallist

[ 本帖最后由 springwind426 于 2008-9-19 14:21 编辑 ]

sabin541

楼上考虑两个关键字出现在同一行的情况了，越扩越宽啊

原帖由 cjaizss 于 2008-9-19 13:09 发表
我的代码可以满足你开头的要求，但如果具体的要求必须定出来了才好解决。
比如只有music怎么办？
比如music和realist出现在同一行怎么办？
比如有几个music,realist又怎么办？

你的代码够我消化一段时间的了，剩下的情况我作为练习思索一下，谢谢大家了。

[ 本帖最后由 sabin541 于 2008-9-19 14:44 编辑 ]

lihao102

我也看不太懂~~~~~~~~~`

bigqueues

sed搞好复杂。
为什么不直接替换呢