为什么我从管道读数据了原来的数组值就变了啊？

frilland

use strict;
use warnings;
use Getopt::Long;         
my @node = ();
my $nodegroup = "";
my $dir = "/opt/OV/bin/OpC/utils/opcnode";
my $list_Nodes =$dir." "."-list_nodes";
my $list_AssNodes = $dir." "."-list_ass_nodes"." group_name=".$nodegroup;
my %list_AssTempls =();
my %nettype = ();       

GetOptions("n|node=s"=>\@node,"ng|nodegroup=s"=>\$nodegroup);

######################################################################
#Get all nodes' nettype  and the  command that is used to get a node's assigned templates
######################################################################
open(P1,"$list_Nodes|") or die "Can't run the command: $!";
foreach (@node)
{
        my $flag = 0;
        my $node = $_;                                       
        while(<P1>)
        {       
                $flag = 1 if(/$node/i);
                if($flag && /Network\sType\s+=\s(\w+)/)
                {
                        $nettype{$node}=$1;
                        last;       
                }
        }
        $list_AssTempls{$node}=$dir." "."-list_ass_templs"." nodename=".$node." nettype=".$nettype{$node};
}
close P1;


比如命令为perl 1.pl -n aaa -ng group
问题就在while(<P1>)这里，在while上一句，print "@node"；时，@node都还是aaa，但是进入while循环后@node就变成管道读入的数据了，并且，当我在$nettype{$node}=$1;上一句打印@node的值的时候，@node居然变成了Network Type = NETWORK了，我觉得很奇怪额，@node不是等于参数aaa吗，怎么后面就变了呢

MMMIX

原帖由 frilland 于 2009-7-20 15:30 发表
foreach (@node)
{
        my $flag = 0;
        my $node = $_;                                       
        while(<P1>)
        {      

用 foreach my $node (@node) { ... 这种写法吧

frilland

呵呵，真的就可以了呢~谢谢你哈~！！！！

bianjiang007

我学习perl不长时间，能否说明一下你的这个程序实现的功能是什么？我看不太懂～～谢谢了～～

Perl_Er

为啥了?

MMMIX

原帖由 Perl_Er 于 2009-7-21 08:14 发表
为啥了?

自己在 perlsyn 中查查。

Perl_Er

细微差别，大家注意啦!
while (<FILE>) { … }

    tramples on $_ while foreach does not (foreach localises $_ first). Surely this is the most important behavioural difference!

MMMIX

原帖由 Perl_Er 于 2009-7-21 11:06 发表
细微差别，大家注意啦!
while () { … }

    tramples on $_ while foreach does not (foreach localises $_ first). Surely this is the most important behavioural difference!

这个虽然没错，但和楼主的问题没有太大关系。

楼主的问题是，在 foreach (@node) BLOCK 这种写法中，@node 的值在 BLOCK 中被修改，这显然是由于这种写法导致在 BLOCK 中，$_ 是 @node 成员的别名，修改 $_ 就会修改 @node 对应的元素。foreach my $node (@node) BLOCK 这种写法，刚好可以用来解决这个问题。

BTW, 你这种给了正确答案却偏偏能再找个错误答案的能力实在让我无语

Perl_Er

在解决问题的同时，能引申出一些值得注意的地方,你的回答让人知其然，而不知其所以然. 明白while(<FH>，对这个问题很重要.这也是为什么我那样回复的原因。
foreach (@node) BLOCK 这种写法中会使用到$_变量，并且会localises $_ first. 而while(<FH>没有localises $_变量，而直接更改了上面foreach的$_,所以@node变了.如果把他的while改为foreach的话也是可行的. 并不是完全那个foreach写法有问题。
不要只是为了解决问题而解决问题！

[ 本帖最后由 Perl_Er 于 2009-7-21 16:47 编辑 ]