请教一段代码，关于subfile

jinaolei

这是一个小例子，刚刚调通，有几个地方不太明白，代码如下：
-------PF-----
                     
     A          R CUSTR                     TEXT('CUSTOMER')           
     A            CUSTNO         6S 0       TEXT('CUST #')            
     A            CUSTNM        30A         TEXT('NAME')               
     A          K CUSTNO                                      

------DSPF-----

     A                                      DSPSIZ(24 80 *DS3)
     A                                      REF(JINLEFENG/CUST01)
     A                                      CA03(03)
     A          R SFL002S1                  SFL
     A            CUSTNO    R        O  5 10
     A            CUSTNM    R        O  5 27
     A          R SFL002C1                  SFLCTL(SFL002S1)
     A                                      OVERLAY
     A N90                                  ROLLUP(50)
     A  90                                  SFLEND(*MORE)
     A  20                                  SFLDSP
     A                                      SFLDSPCTL
     A                                      SFLSIZ(0016)
     A                                      SFLPAG(0010)
     A            DSPRECORD      4S 0H      SFLRCDNBR
     A                                  1 26'SIMPLE LOAD FORWARD'
     A                                      DSPATR(HI)
     A  20                              3  7'CUSTOMER NUMBER'
     A  20                              3 27'CUSTOMER NAME'
     A  20                              4  7'==============='
     A  20                              4 27'===================='
     A N20                              4 24'NO CUSTOMER RECORD FOUND'
     A          R CMDKEY
     A                                 23  3'F3-EXIT'
     A                                      DSPATR(HI)

------RPG-----

     FCUST01    IF   E             DISK
     FSFL002DF  CF   E             WORKSTN
     F                                     SFile(SFL002S1Rec#)
     D @Rec#           S              4S 0
     C                   Exsr      LOADSF
     C                   Dou       *in03=*On
     C                   Write     Cmdkey
     C                   Exfmt     SFL002C1
     C                   Eval      DSPRECORD=1
     C*Press rollup disply next page
     C                   If        *in50=*On
     C                   Exsr      Loadsf
     C                   Endif
     C                   Enddo
     C                   Eval      *Inlr=*On
     C                   Return
     C*
     C*Process Customer file and load records into sufile
     C     LOADSF        Begsr
     C*15Record per page
     C                   Do        10
     C                   Read      Custr                                  90
     C                   If        *in90=*On
     C                   Leave
     C                   Else
     C                   Eval      @Rec#=@Rec#+1
     C                   Write     SFL002S1
     C                   Endif
     C                   Enddo
     C*Set the subfile records to be displayed equal to the last record
     C                   Eval      DspRecord = @Rec#
     C                   If        @Rec#>0
     C                   Eval      *in20=*on
     C                   Endif
     C                   Endsr
  
PF中有18条数据，执行程序第一页显示前10条数据，然后按page-down显示后8条数据
现在有疑问，第一次执行LOADSF中的DO循环为什么就执行了10次，有18条数据呢它怎么不多执行两次，是因为 SFLPAG(0010)设的是10吗？
还有第二个疑问，当我把DO循环里的10修改为11，编译执行程序，发现第一页只显示一条数据，即表中的第11条数据，按下page-down显示第11至18条数据

对SFLRCDNBR还有分页显示不太理解，请明白的大虾指点一二

RAIITSMXH

    1、  第一次执行LOADSF中的DO循环为什么就执行了10次，有18条数据呢它怎么不多执行两次，是因为 SFLPAG(0010)设的是10吗？
===> DO循环的次数为10，所以只会读写10次，跟SFLPAG没有什么系啊
   2‘、当我把DO循环里的10修改为11，编译执行程序，发现第一页只显示一条数据，即表中的第11条数据，
===>当把10改成11后，执行完LOADSF这个subroutine后，DspRecord=11，所以EXFMT时显示的是第11条记录所在的页（即第二页）

SFLPAG的值只是表示一页放多少条记录
SFLRCDNBR是SFL的记录号，文件显示时会显示SFLRCDNBR对应的记录所在的页
即：你第一次执行时，SFLRCDNBR=10，（第10条记录在第一页），所以显示第一页的10条记录
      第二次执行时，SFLRCDNBR=11，（第11条记录在第二页），所以显示第二页的1条记录，翻页后SFLRCDNBR=18，所以显示第二页11~18条记 录

jinaolei

汗，惭愧，之前这个DO循环还真的没搞清楚。谢谢楼上兄台的讲解，我再试几次