【已解决】awk合并两个文件的问题，真心求帮助！真心求帮助！真心求帮助！谁来帮帮我

有点浪有点漫

文件1：TEST1
0001|01|0
0001|02|0
0001|03|0
0001|04|0
0001|05|0

文件2：TEST2
0001|ChinaUnix论坛真是不错

结果：
文件3：TEST3
0001,ChinaUnix论坛真是不错,01,0
0001,ChinaUnix论坛真是不错,02,0
0001,ChinaUnix论坛真是不错,03,0
0001,ChinaUnix论坛真是不错,04,0
0001,ChinaUnix论坛真是不错,05,0

由文件1与文件2生成文件3的方法如下：

1. awk -F \| 'NR==FNR{a[$1]=$2} \
   
2. NR>FNR{printf("%s,%s,%s\,%sn",$1,a[$1],$2,$3);}' \
   
3. TEST2  TEST1  >!  TEST3

复制代码

文件4：TEST4
0001,ChinaUnix论坛真是不错,01,0,02,0,03,0,04,0,05,0

由文件1与文件2生成文件4的方法该如何写呢？求教....（作为一名初学者，请多多指教，谢谢 ）

personball

1. personball@vostro:awk$awk -F, '{if(!a[$1","$2]){a[$1","$2]=$0}else{a[$1","$2]=a[$1","$2]","$3","$4}}END{for(i in a)print a[i] }' TEST3
   
2. 0001,ChinaUnix论坛真是不错,01,0,02,0,03,0,04,0,05,0
   
3. personball@vostro:awk$cat TEST3
   
4. 0001,ChinaUnix论坛真是不错,01,0
   
5. 0001,ChinaUnix论坛真是不错,02,0
   
6. 0001,ChinaUnix论坛真是不错,03,0
   
7. 0001,ChinaUnix论坛真是不错,04,0
   
8. 0001,ChinaUnix论坛真是不错,05,0
   
9. personball@vostro:awk$
   

复制代码

回复 1# 有点浪有点漫

1. personball@vostro:awk$awk -F, '{t=$1","$2; if(!a[t]){a[t]=$0}else{a[t]=a[t]","$3","$4}}END{for(i in a)print a[i] }' TEST3
   
2. 0001,ChinaUnix论坛真是不错,01,0,02,0,03,0,04,0,05,0
   
3. personball@vostro:awk$

复制代码

rdcwayx

TEST3 中要会用OFS.

1. awk -F \| 'NR==FNR{a[$1]=$2} NR>FNR{$1=$1 OFS a[$1]}1' OFS=, test2 test1 > test3

复制代码

TEST4的代码

1. awk -F \| 'NR==FNR{a[$1]=$2;next}
   
2.           {b[$1]=b[$1]==""?$2 OFS $3:b[$1] OFS $2 OFS $3}
   
3.           END{for (i in b) print i,a[i],b[i]}' OFS=, test2 test1

复制代码

有点浪有点漫

rdcwayx 发表于 2012-06-28 10:50
TEST3 中要会用OFS.TEST4的代码

谢谢斑竹的解答，TEST4的代码学习了。

有点浪有点漫

回复 3# rdcwayx


谢谢斑竹的解答，您辛苦了！
TEST4的代码我能理解，并学会了这样的用法。


TEST3的代码有点不明白，"{$1=$1 OFS a[$1]}1"，这块内容
我认为，{$1=$1 OFS a[$1]}是在匹配的情况下将【TEST1中的第一列】+【,】+【TEST2中的第二列】
后面的一个数字1我就不明白是表示什么了，请指教。

TEST3的代码结果是：
0001|ChinaUnix论坛真是不错
0001,ChinaUnix论坛真是不错,01,0
0001,ChinaUnix论坛真是不错,02,0
0001,ChinaUnix论坛真是不错,03,0
0001,ChinaUnix论坛真是不错,04,0
0001,ChinaUnix论坛真是不错,05,0

第一行为什么会出现呢？

有点浪有点漫

回复 2# personball


    谢谢您的解答，不知道为什么我这里会显示【a[t]){a[t]=$0】这块内容有问题！

rdcwayx

有点浪有点漫 发表于 2012-06-28 11:57
回复 3# rdcwayx

第一行为什么会出现呢？

这个不清楚，也没注意。感觉应该是1 对两个文件都生效了。
我通常这样用的，就可以避免这种情况。

1. awk -F \| 'NR==FNR{a[$1]=$2;next}{$1=$1 OFS a[$1]}1' OFS=, test2 test1

复制代码