再问关于内存屏障的问题

zylthinking

读写屏障的语义：
读屏障保证屏障之前的读操作在屏障之后的读操作之前完成
写屏障保证屏障之前的写操作在屏障之后的写操作之前完成

现在的问题是：
屏障之前/之后 又是如何定义的， 只程序的指令流的前后还是二进制文件的指令物理排列前后呢， 如果是指令物理排列前后， 似乎很难解决CPU各种突发的跳转问题， 应该是程序流前后，
但如果是程序流前后， 如下代码：

LOCKED   EQU 1
      UNLOCKED EQU 0
lock_mutex
      ; 互斥量是否锁定?
      LDREX r1, [r0]         ; 检查是否锁定
      CMP r1, #LOCKED      ; 和"locked"比较
      WFEEQ                ; 互斥量已经锁定，进入休眠
      BEQ lock_mutex         ; 被唤醒，重新检查互斥量是否锁定                        
      ; 尝试锁定互斥量
      MOV r1, #LOCKED
      STREX r2, r1, [r0]        ; 尝试锁定
      CMP r2, #0x0            ; 检查STR指令是否完成
      BNE lock_mutex         ; 如果失败，重试
      DMB                   ; 进入被保护的资源前需要隔离，保证互斥量已经被更新
      BX lr
unlock_mutex
      DMB                    ; 保证资源的访问已经结束
      MOV r1, #UNLOCKED      ; 向锁定域写"unlocked"
      STR r1, [r0]

      DSB                    ; 保证在CPU唤醒前完成互斥量状态更新
      SEV                    ; 像其他CPU发送事件，唤醒任何等待事件的CPU

      BX lr

其中，  DMB, SDB 语义如下：
DMB
数据内存屏障可作为内存屏障使用。 它可确保会先检测到程序中位于 DMB 指令前的所有显式内存访问指令，然后再检测到程序中位于 DMB 指令后的显式内存访问指令。它不影响其他指令在处理器上的执行顺序。

DSB
数据同步屏障是一种特殊类型的内存屏障。 只有当此指令执行完毕后，才会执行程序中位于此指令后的指令。 当满足以下条件时，此指令才会完成：
位于此指令前的所有显式内存访问均完成。
位于此指令前的所有缓存、跳转预测和 TLB 维护操作全部完成。

疑问是：标红的 DSB 为什么不是 DMB, 我的理解是 SEV 并不是内存访问指令。 但是， 如果 SEV 导致其他核心从 WFE 唤醒， 那么， WFE 之后的 STREX r2, r1, [r0] 岂不是同样是内存访问指令， 应该被保证发生于  STR r1, [r0] 之后的， 那不就是说， DSB 可以被 DMB 代替？

zylthinking

已经明白了： 用 DSB 的目的在于防止 SEV 在 STR r1, [r0] 之前执行

liuiang

楼主对屏障的研究已经进入另外一个境界了，向你学习。

我没专门深挖这个鸟鸟，我的理解是：

DMB只负责顺序正确，不保证DMB之前的访问一定执行完成；
DSB则保证指令执行DSB之后，所有之前的访问执行完成；

从本质来说，DMB只保证访问在writebuffer中是顺序提交（这里先忽略读），而DSB则保证writebuffer已经完全排空，所有写请求已经全部由cache一致性模型处理了。

DSB之后其他处理器可以肯定能看到更改，而不是更改其他处理器的writebuffer中排队。

panqihe

         STREX r2, r1, [r0]        ; 尝试锁定
      CMP r2, #0x0            ; 检查STR指令是否完成
      BNE lock_mutex         ; 如果失败，重试
      DMB                   ; 进入被保护的资源前需要隔离，保证互斥量已经被更新
疑问求解：如果在strex 和 dmb 之间另一个cpu, 假定为Py刚好也在执行lock_mutex，想要获取同样的锁。会不会造成两个CPU都获得了锁,因为DMB还没执行?