以 [小写字符] 标示出杂质

damcool

rdcwayx 发表于 2013-10-28 11:29
还是没看到在一条awk内搞定的。

一条是可以搞定的，但是没必要创建那么多数组，两维数组不是awk的长项。

damcool

满足一下斑竹要求。

1. #!/bin/awk
   
2. {
   
3.         ord["A"]=1;
   
4.         ord["B"]=2;
   
5.         ord["C"]=3;
   
6.         ord["D"]=4;
   
7.         l="";x=0;
   
8.         n=split($0,a,"");
   
9.         for (i=1;i<=n;i++)
   
10.         {
    
11.                 if (toupper(a[i])=="X")
    
12.                 {
    
13.                         x=ord[a[i+1]];
    
14.                         b[i]=5;
    
15.                         l=l"x";
    
16.                 }
    
17.                 else
    
18.                 {
    
19.                         if (b[i]==5) b[i]=ord[toupper(a[i])];
    
20.                         a1=a[i]a[i+1]
    
21.                         a2=a[i]a[i+1]a[i+2]
    
22.                         a3=a[i]a[i+1]a[i+2]a[i+3]
    
23.                         a4=a[i]a[i+1]a[i+2]a[i+3]a[i+4]
    
24.                         if (x>0 || b[i]>0 || match(a1,/[A-D]X/) || match(a2,/[A-D][B-D]X/) || match(a3,/[A-D][A-D][C-D]X/) || match(a4,/[A-D][A-D][A-D]DX/))
    
25.                         {
    
26.                                 l=l""tolower(a[i]);
    
27.                                 x=(x>0)?--x:0;
    
28.                                 b[i]=(b[i]>0)?b[i]-1:0;
    
29.                         }
    
30.                         else l=l""a[i];
    
31.                 }
    
32.         }
    
33.         m[++k]=l;
    
34. }
    
35. END{
    
36.         for (i=k;i>0;i--)
    
37.         {
    
38.                 n=split(m[i],a,"");
    
39.                 l="";x=0;
    
40.                 for (j=1;j<=n;j++)
    
41.                 {
    
42.                         if (toupper(a[j])=="X")
    
43.                         {
    
44.                                 c[j]=5;
    
45.                                 l=l"x";
    
46.                         }       
    
47.                         else
    
48.                         {
    
49.                                 if (c[j]==5) c[j]=ord[toupper(a[j])];
    
50.                                 if (c[j]>0)
    
51.                                 {
    
52.                                         l=l""tolower(a[j]);
    
53.                                         c[j]=c[j]-1;
    
54.                                 }
    
55.                                 else l=l""a[j];
    
56.                         }
    
57.                 }
    
58.                 m[i]=l;
    
59.         }
    
60.         for (i=1;i<=k;i++) print m[i];
    
61. }
    
62. 
    

复制代码

运行结果

1. cat /tmp/chars |awk -f scripts/contaminate.awk
   
2. aBDCDCDCaaxcxcdcCABABDCDcDcAabxbaBDCDCDCAABbCdCcaxdbbxaBDCDCDcAAbbcdxcca
   
3. bBCDCCABbBabxcdcDCAAbbcdxccaBBbbBABDCDCDCAAbBcDcCaxbbbABCDAAaxbcDADCaxxx
   
4. xaBCDCDCaaxbbCCDCCABAbdCdCdCAabxbaBdABACCCaxcdcdCAaBBcDcCABbbxaBDCDCDcaa
   
5. aACDCCAAdCabdCDCDCAabxcdxcxaBCDdBABdCDCDCAAbbxbxcaaBBBAbCDAAaxbcDADCAbbB
   
6. aDCAAAAaxaBcdCCCCCDCabxbbCcDCCAbABDcDCDCAabxbaBdABdCCCaxcdcDCaAAAABBCdcC
   
7. xcccAABDcAaxxaADCCCCCcaAcCaAAAAaAAaxbbdccxacDACdAaxcbbBbBBBAAaBCADDCAaxc
   
8. xaBCDCDCaaxbbCCDCCABABDCDCdCAabxbaBdABACCcaxcdcdCAaBBCDcCABbbxaBDCDCDCaA
   

复制代码

rdcwayx

1. $ cat gr33n.awk
   
2. 
   
3. BEGIN{FS="";v["X"]=0;v["A"]=1;v["B"]=2;v["C"]=3;v["D"]=4}
   
4. { for(i=1;i<=NF;i++)
   
5.      {  str=i OFS NR;
   
6.         a[str]=$i;
   
7.         if($i=="X") {b[++j]=str;e[str]++}
   
8.      }
   
9. }
   
10. END{for (i in b)
    
11.         { split(b[i],c,OFS);
    
12.           for (j=1;j<=v[a[c[1]+1 OFS c[2]]];j++) { if (a[c[1]+j OFS c[2]]!="X") {d[c[1]+j OFS c[2]]++} else {break}}
    
13.           for (j=1;j<=v[a[c[1] OFS c[2]+1]];j++) { if (a[c[1] OFS c[2]+j]!="X") {d[c[1] OFS c[2]+j]++} else {break}}
    
14.           for (j=1;j<=v[a[c[1]-1 OFS c[2]]];j++) { if (a[c[1]-j OFS c[2]]!="X") {d[c[1]-j OFS c[2]]++} else {break}}
    
15.           for (j=1;j<=v[a[c[1] OFS c[2]-1]];j++) { if (a[c[1] OFS c[2]-j]!="X") {d[c[1] OFS c[2]-j]++} else {break}}
    
16.         }
    
17.     for (j=1;j<=NR;j++)
    
18.        { for (i=1;i<=NF;i++)
    
19.            { if (e[i OFS j]||d[i OFS j])
    
20.                      { printf tolower(a[i OFS j]) }
    
21.              else {printf a[i OFS j] }
    
22.            }
    
23.          printf ORS
    
24.        }
    
25. }

复制代码

1. awk -f gr33n.awk i
   
2. 
   
3. aBDCDCDCaaxcxcdcCABABDCDcDcAabxbaBDCDCDCAABbCdCcaxdbbxaBDCDCDcAAbbcdxcca
   
4. bBCDCCABbBabxcdcDCAAbbcdxccaBBbbBABDCDCDCAAbBcDcCaxbbbABCDAAaxbcDADCaxxx
   
5. xaBCDCDCaaxbbCCDCCABAbdCdCdCAabxbaBdABACCCaxcdcdCAaBBcDcCABbbxaBDCDCDcaa
   
6. aACDCCAAdCabdCDCDCAabxcdxcxaBCDdBABdCDCDCAAbbxbxcaaBBBAbCDAAaxbcDADCAbbB
   
7. aDCAAAAaxaBcdCCCCCDCabxbbCcDCCAbABDcDCDCAabxbaBdABdCCCaxcdcDCaAAAABBCdcC
   
8. xcccAABDcAaxxaADCCCCCcaAcCaAAAAaAAaxbbdccxacDACdAaxcbbBbBBBAAaBCADDCAaxc
   
9. xaBCDCDCaaxbbCCDCCABABDCDCdCAabxbaBdABACCcaxcdcdCAaBBCDcCABbbxaBDCDCDCaA

复制代码

rdcwayx

思路：

1. 将所有字符导入一个两维数组 , 比如 a[ 3 OFS 4] 就是 C
2. 标记 X 的坐标到数组b，例子里会找到40个 X 的坐标, 同时标记该位置的X 在最后输出的时候要小写 （数组e）
3. 对上面40个X 的坐标的东南西北四个方向进行判断，如果符合条件，就标记为非0 （用数组d）
4. 输出结果，判断的依据是，只要数组 e 或者数组d 对应坐标的值大于0， 就要小写，否则大写。

yestreenstars

又写了一个~借助二维数组~单脚本完成任务~

1. [root@localhost ~]# cat i
   
2. ABDCDCDCAAXCXCDCCABABDCDCDCAABXBABDCDCDCAABBCDCCAXDBBXABDCDCDCAABBCDXCCA
   
3. BBCDCCABBBABXCDCDCAABBCDXCCABBBBBABDCDCDCAABBCDCCAXBBBABCDAAAXBCDADCAXXX
   
4. XABCDCDCAAXBBCCDCCABABDCDCDCAABXBABDABACCCAXCDCDCAABBCDCCABBBXABDCDCDCAA
   
5. AACDCCAADCABDCDCDCAABXCDXCXABCDDBABDCDCDCAABBXBXCAABBBABCDAAAXBCDADCABBB
   
6. ADCAAAAAXABCDCCCCCDCABXBBCCDCCABABDCDCDCAABXBABDABDCCCAXCDCDCAAAAABBCDCC
   
7. XCCCAABDCAAXXAADCCCCCCAACCAAAAAAAAAXBBDCCXACDACDAAXCBBBBBBBAAABCADDCAAXC
   
8. XABCDCDCAAXBBCCDCCABABDCDCDCAABXBABDABACCCAXCDCDCAABBCDCCABBBXABDCDCDCAA
   
9. [root@localhost ~]# cat a
   
10. #!/bin/awk
    
11. BEGIN{
    
12.         FS="";
    
13.         IGNORECASE=1;
    
14.         a["a"]=a["A"]=1;
    
15.         a["b"]=a["B"]=2;
    
16.         a["c"]=a["C"]=3;
    
17.         a["d"]=a["D"]=4
    
18. }
    
19. {
    
20.         for(i=1;i<=NF;i++)b[NR,i]=$i
    
21. }
    
22. END{
    
23.         for(i=1;i<=NR;i++){
    
24.                 for(j=1;j<=NF;j++){
    
25.                         if(b[i,j]=="X"){
    
26.                                 for(k=j-1;k>=j-a[b[i,j-1]]&&k>=1;k--){
    
27.                                         if(b[i,k]=="X")break;
    
28.                                         b[i,k]=tolower(b[i,k])
    
29.                                 }
    
30.                                 for(k=j+1;k<=j+a[b[i,j+1]]&&k<=NF;k++){
    
31.                                         if(b[i,k]=="X")break;
    
32.                                         b[i,k]=tolower(b[i,k])
    
33.                                 }
    
34.                                 b[i,j]=tolower(b[i,j])
    
35.                         }
    
36.                 }
    
37.         }
    
38.         for(i=1;i<=NF;i++){
    
39.                 for(j=1;j<=NR;j++){
    
40.                         if(b[j,i]=="X"){
    
41.                                 for(k=j-1;k>=j-a[b[j-1,i]]&&k>=1;k--){
    
42.                                         if(b[k,i]=="X")break;
    
43.                                         b[k,i]=tolower(b[k,i])
    
44.                                 }
    
45.                                 for(k=j+1;k<=j+a[b[j+1,i]]&&k<=NR;k++){
    
46.                                         if(b[k,i]=="X")break;
    
47.                                         b[k,i]=tolower(b[k,i])
    
48.                                 }
    
49.                                 b[j,i]=tolower(b[j,i])
    
50.                         }
    
51.                 }
    
52.         }
    
53.         for(i=1;i<=NR;i++){
    
54.                 for(j=1;j<NF;j++)printf b[i,j];
    
55.                 print b[i,NF]
    
56.         }
    
57. }
    
58. [root@localhost ~]# awk -f a i
    
59. aBDCDCDCaaxcxcdcCABABDCDcDcAabxbaBDCDCDCAABbCdCcaxdbbxaBDCDCDcAAbbcdxcca
    
60. bBCDCCABbBabxcdcDCAAbbcdxccaBBbbBABDCDCDCAAbBcDcCaxbbbABCDAAaxbcDADCaxxx
    
61. xaBCDCDCaaxbbCCDCCABAbdCdCdCAabxbaBdABACCCaxcdcdCAaBBcDcCABbbxaBDCDCDcaa
    
62. aACDCCAAdCabdCDCDCAabxcdxcxaBCDdBABdCDCDCAAbbxbxcaaBBBAbCDAAaxbcDADCAbbB
    
63. aDCAAAAaxaBcdCCCCCDCabxbbCcDCCAbABDcDCDCAabxbaBdABdCCCaxcdcDCaAAAABBCdcC
    
64. xcccAABDcAaxxaADCCCCCcaAcCaAAAAaAAaxbbdccxacDACdAaxcbbBbBBBAAaBCADDCAaxc
    
65. xaBCDCDCaaxbbCCDCCABABDCDCdCAabxbaBdABACCcaxcdcdCAaBBCDcCABbbxaBDCDCDCaA
    
66. [root@localhost ~]#

复制代码

damcool

楼上两位的方法第一遍扫瞄数据没有作任何处理可惜了。

yinyuemi

也可以试试gawk4.0's new feature: array of array

yinyuemi

sed理论上也行

yestreenstars

回复 16# damcool
没什么可不可惜的，不同人的处理方法不同，就算你在第一次遍历时就处理数据也不代表你的脚本运行起来就比别人快~

   

damcool

yestreenstars 发表于 2013-10-28 15:57
回复 16# damcool
没什么可不可惜的，不同人的处理方法不同，就算你在第一次遍历时就处理数据也不代表你的 ...

我不太懂O(N)分析法，不过两个三重循环+几双个单重循环+几个单重循环，应该比一个双重循环+两个单重循环慢很多吧。