sed如何打印字段号【已解决】

yestreenstars

回复 20# chengchow

语文学得不错，采用了夸张的修辞手法~
   

jason680

回复 20# chengchow

++++++++[>+>++>+++>++++>+++++>++++++>+++++++>++++++++>+++++++++>++++++++++>+++++++++++>++++++++++++>+++++++++++++>++++++++++++++>+++++++++++++++>++++++++++++++++<<<<<<<<<<<<<<<<-]>>>>>>>>>>>>>>>-.+<<<<<<<<<<<<<<<>>>>>>>>>>>>>---.+++<<<<<<<<<<<<<>>>>>>>>>>>>>>----.++++<<<<<<<<<<<<<<>>>>>>>>>>>>+++.---<<<<<<<<<<<<>>>>>>>>>>>>>>-.+<<<<<<<<<<<<<<>>>>>>>>>>>>>>---.+++<<<<<<<<<<<<<<>>>>>>>>>>>>>---.+++<<<<<<<<<<<<<>>>>>>--.++<<<<<<>>>>>>>>>>>>>.<<<<<<<<<<<<<>>>>>>>>>>>>>>>----.++++<<<<<<<<<<<<<<<>>>>>>>>>>>>>>---.+++<<<<<<<<<<<<<<>>>>>>>>>>>>>>----.++++<<<<<<<<<<<<<<.
   

关阴月飞

fuck brand 不明觉历呀！！！！！！！！

chengchow

回复 22# jason680
不明觉厉，古巴比伦文？


   

kooleon

我是来围观大神的。

cjaizss

chengchow 发表于 2014-08-28 11:04
回复 19# yestreenstars

再次鄙视下星辰大婶，占了沙发和N层楼，居然什么活都没干！

可是偶还是怀疑,你未必明白了我那个程序在干吗.......

chengchow

回复 26# cjaizss
确实没看懂，慢慢看了！单独看差多懂，还是没搞懂版主思路（这个很糟糕），麻烦解释了
是通过sed分支循环累加来实现的吗？(猜测)
#!/bin/sed -nrf
s/[^ \t]+/1/g      ##替换字段字符为1
#s/[ \t]+/ /g       ##规范格式
#s/^ | $//g         ## 规范格式
#/^$/ {p;d;}      ## 规范格式
s/1/1;/                ## 替换1为1；执行完因该是“1; 1; 1; 1;”
ta;                      ## 分支执行条件满足跳到:a
:a;                      ## ta标记
s/([0-9]+); 1( |$)/\1 \1;\2/    ##单独看，不明白这句效果，执行到这里似乎没有匹配上/([0-9]+); 1( |$)/的字符串
tc;                       ## 同ta
s/;//                    ## 删除；
p                         ## 打印
:c                        ##  tc标记
/0;/{s//1;/;ta;}    ##匹配0;任意字符为1；执行并跳转:a   
s/;/-;/                  ##替换;为-；
:b;                       ##tb表记
s/9-/-0/                ##替换9-为-0
tb                         ##同ta
s/0-/1/;ta;            ##替换0-为1，并跳转：a
s/1-/2/;ta;            ##以下同上
s/2-/3/;ta;
s/3-/4/;ta;
s/4-/5/;ta;
s/5-/6/;ta;
s/6-/7/;ta;
s/7-/8/;ta;
s/8-/9/;ta;
s/-/1/;ta;


   

cjaizss

chengchow 发表于 2014-08-28 14:06
回复 26# cjaizss
确实没看懂，慢慢看了！单独看差多懂，还是没搞懂版主思路（这个很糟糕），麻烦解释了
...

思路,先把各字段替换为1,开头无空格,结尾无空格,每两个1用单个空格隔开.
然后挨个字段+1依次替换过去.
替换完了,输出.
比如,有10个字段,先替换为
1 1 1 1 1 1 1 1 1 1
然后
1 2 1 1 1 1 1 1 1 1
1 2 3 1 1 1 1 1 1 1
1 2 3 4 1 1 1 1 1 1
1 2 3 4 5 1 1 1 1 1
1 2 3 4 5 6 1 1 1 1
1 2 3 4 5 6 7 1 1 1
1 2 3 4 5 6 7 8 1 1
1 2 3 4 5 6 7 8 9 1
1 2 3 4 5 6 7 8 9 10
输出.

1. 
   
2. #!/bin/sed -nrf
   
3. s/[^ \t]+/1/g
   
4. s/[ \t]+/ /g
   
5. s/^ | $//g
   
6. #以上三句先把各字段替换为1,开头无空格,结尾无空格,每两个1用单个空格隔开.
   
7. 
   
8. #如果本行没有字段,直接空行输出
   
9. /^$/ {p;d;}
   
10. 
    
11. #先把第一个1后面加个分号,以后每处理一个字段,往后移一下,以分号标记处理到第几个段
    
12. s/1/1;/
    
13. ta; #这里之所以要用t,在于清除掉之前s成功
    
14. 
    
15. :a;
    
16. #这里就是把分号往后移动一个字段,以标志处理下一个字段,并把之前处理过的值复制过去,再来做当前字段+1
    
17. #例:
    
18. #当前处理为
    
19. #1 2 3; 1 1 1
    
20. #移动之后,为
    
21. # 1 2 3 3; 1 1
    
22. s/([0-9]+); 1( |$)/\1 \1;\2/
    
23. tc;
    
24. #tc失败发生在处理完所有的字段,也就是说分号后面已经不存在1了,那么就把分号干掉,并输出
    
25. s/;//
    
26. p
    
27. #这里本来应该加个d,不过我就没加了,因为此时已经没有分号,后面统统都会不成立
    
28. 
    
29. 
    
30. #这里就是+1的技巧了,技巧其实不难,看末尾的数字,如果是0-8很简单
    
31. #但如果是9,那么就把最后的几个9都变0,前面再+1
    
32. #使用一个短横线作为处理的标志
    
33. :c
    
34. /0;/{s//1;/;ta;}
    
35. s/;/-;/
    
36. :b;
    
37. s/9-/-0/
    
38. tb
    
39. 
    
40. s/0-/1/;ta;
    
41. s/1-/2/;ta;
    
42. s/2-/3/;ta;
    
43. s/3-/4/;ta;
    
44. s/4-/5/;ta;
    
45. s/5-/6/;ta;
    
46. s/6-/7/;ta;
    
47. s/7-/8/;ta;
    
48. s/8-/9/;ta;
    
49. s/-/1/;ta;
    

复制代码

另外,调试sed可以用sedsed,看起来比较方便，不过我从来不用这玩意,调试都是裸调的

chengchow

回复 28# cjaizss
非常感谢，明白了！
s/1/1;/                ## 替换1为1；执行完因该是“1; 1; 1; 1;”
理解错了，没有全文替换，粗心了，后面对不上了
解释后现在再看，就清楚多了

   

jeffreyst

都是大牛~