提取文本固定内容,并按要求输出

eatmyshort

文本内容是：
[Map 1]
MapName=4139
AutoRun=1
InIP=
InPort=4139
OutIP=132.228.166.14
OutPort=4139
MaxUser=0
MaxIPUser=0
Proxy=0
BlackList=
[Map 2]
MapName=4138
AutoRun=1
InIP=
InPort=4138
OutIP=132.228.166.14
OutPort=4138
MaxUser=0
MaxIPUser=0
Proxy=0
BlackList=
[Map 3]
MapName=8289
AutoRun=0
InIP=
InPort=8289
OutIP=132.228.166.14
OutPort=8289
MaxUser=0
MaxIPUser=0
Proxy=0
BlackList=
[Map 4]
MapName=22555
AutoRun=1
InIP=
InPort=22555
OutIP=132.232.5.55
OutPort=22022
MaxUser=0
MaxIPUser=0
Proxy=0
BlackList=
=================================================================分割线
要求：提取每个Map内的InPort,OutIP,OutPort


最后输出格式如下
OutIP=132.232.5.55,InPort=22555,OutPort=22022
OutIP=132.229.165.202,InPort=6662,OutPort=8080
。。。。。。。
。。。。。。。
。。。。。。。

Buring__

1. awk -vRS='\\[Map' 'NF{print $5","$6","$7}'

复制代码

tuyajie

1. awk 'BEGIN{RS="\n\\["}{for(i=1;i<=NF;i++){if($i~/OutPort/||$i~/InPort/||$i~/OutIP/)printf $i" "};printf"\n"}' test.txt | awk '{OFS=","; print $2,$1,$3}'

复制代码

改下

李满满

1. #!/usr/bin/env python
   
2. # -*- coding: utf-8 -*-
   
3. import re
   
4. flag = ('InPort', 'OutIP', 'OutPort')
   
5. fd = open('yhsafe.txt', 'rub')
   
6. fl = fd.readlines()
   
7. sectiondict = {}
   
8. for line in fl:
   
9. 
   
10.     match = re.search(r'^\[(.*)\]\s*', line)
    
11.     if match:
    
12.         match_gp = match.group(1)
    
13.         sectiondict.setdefault(match_gp, [])
    
14.     else:
    
15.         sectiondict[match_gp].append(line)
    
16. for key, val in sectiondict.iteritems():
    
17.     print ','.join([s.strip() for s in val if s.split('=')[0] in flag ])
    

复制代码

Press ENTER or type command to continue
InPort=22555,OutIP=132.232.5.55,OutPort=22022
InPort=8289,OutIP=132.228.166.14,OutPort=8289
InPort=4138,OutIP=132.228.166.14,OutPort=4138
InPort=4139,OutIP=132.228.166.14,OutPort=4139

jason680

回复 1# eatmyshort

$ awk '
BEGIN{
  FS= "=";
  OFS=",";
}
function v(k){
  return(k"="a[k]);
}
function p(){
  if(P)
    print v("OutIP"),v("InPort"),v("OutPort");
  delete a
}
match($0,/\[([^]]+)\]/,m){
  p();
  P=(m[1]~/^Map/)?1:0;
}
{
  a[$1]=$2;
}
END{
  p()
}' FILE
OutIP=132.228.166.14,InPort=4139,OutPort=4139
OutIP=132.228.166.14,InPort=4138,OutPort=4138
OutIP=132.228.166.14,InPort=8289,OutPort=8289
OutIP=132.232.5.55,InPort=22555,OutPort=22022

   

MMMIX

回复 1# eatmyshort


    记录，然后打印：

1. 
   
2. BEGIN {
   
3.     OFS = ","
   
4. }
   
5. {
   
6.     if (/Map\y/ && NR > 1) {
   
7.         print a[0], a[1], a[2]
   
8.         next
   
9.     }
   
10. 
    
11.     if (/OutIP/) {
    
12.         a[0] = $0; next
    
13.     }
    
14.     if (/InPort/) {
    
15.         a[1] = $0; next
    
16.     }
    
17.     if (/OutPort/) {
    
18.         a[2] = $0; next
    
19.     }
    
20. }
    
21. 
    
22. END {
    
23.     print a[0], a[1], a[2]
    
24. }
    

复制代码

eatmyshort

赞赞赞，

李满满 发表于 2015-08-06 18:15
Press ENTER or type command to continue
InPort=22555,OutIP=132.232.5.55,OutPort=22022
InPort=828 ...

yinyuemi

回复 1# eatmyshort

1. awk -vRS='(OutIP|OutPort|InPort)=[^\n]+' 'RT{printf RT (RT~/OutPort/?ORS:",")}'
   

复制代码

聆雨淋夜

1. awk -vRS='\\[Map [0-9]+\\]' 'NR>1{for(i=1;i<NF;i++)if($i~/InPort/)a=$i;else if($i~/OutIP/)b=$i;else if($i~/OutPort/)c=$i;print b",",a",",c}' file
   
2. 
   
3. OutIP=132.228.166.14, InPort=4139, OutPort=4139
   
4. OutIP=132.228.166.14, InPort=4138, OutPort=4138
   
5. OutIP=132.228.166.14, InPort=8289, OutPort=8289
   
6. OutIP=132.232.5.55, InPort=22555, OutPort=22022

复制代码

awk没有swith语句或者case语句啊

yinyuemi

回复 9# 聆雨淋夜


    4.0+有