perl map求解惑

饼干lr

在测试map的用法，虽然报错信息很清楚说参数不够，但我还是不明白是为什么。。。

#!/usr/bin/perl -w
use strict;

my @stri=(1,2,3,4);
my @abc=  map {'x',$_+1} @stri;
print "$_\n" for @abc;

[root@xx perl]# perl test.pl
Not enough arguments for map at test.pl line 5, near "} @stri"
syntax error at test.pl line 5, near "} @stri"
Execution of test.pl aborted due to compilation errors.

----------------------------------------------------------------------
#!/usr/bin/perl -w
use strict;

my @stri=(1,2,3,4);
my @abc=  map {$_+1,'x'} @stri;
print "$_\n" for @abc;

[root@xx perl]# perl test.pl
2
x
3
x
4
x
5
x

zhlong8

perl 的 parser 能力有限，map 遇到 { 开头的可能是 hashref 也可能是block，但是不能向后查看到闭括号 } 后面有没有逗号，所以实际编译时是按经验猜测的，猜错了新版本的会提示是语法错误（所以请升级你的解释器）。 perldoc -f map

{ starts both hash references and blocks, so map { ... could be either the start of map BLOCK LIST or map EXPR, LIST. Because Perl doesn't look ahead for the closing } it has to take a guess at which it's dealing with based on what it finds just after the {. Usually it gets it right, but if it doesn't it won't realize something is wrong until it gets to the } and encounters the missing (or unexpected) comma. The syntax error will be reported close to the }, but you'll need to change something near the { such as using a unary + or semicolon to give Perl some help:

        %hash = map {  "\L$_" => 1  } @array # perl guesses EXPR. wrong
        %hash = map { +"\L$_" => 1  } @array # perl guesses BLOCK. right
        %hash = map {; "\L$_" => 1  } @array # this also works
        %hash = map { ("\L$_" => 1) } @array # as does this
        %hash = map {  lc($_) => 1  } @array # and this.
        %hash = map +( lc($_) => 1 ), @array # this is EXPR and works!
        %hash = map  ( lc($_), 1 ),   @array # evaluates to (1, @array)

or to force an anon hash constructor use +{:

        @hashes = map +{ lc($_) => 1 }, @array # EXPR, so needs
                                               # comma at end

to get a list of anonymous hashes each with only one entry apiece.

饼干lr

回复 2# zhlong8


多谢！已经成功了！