perl 如何处理这样的文本输入文件？

weichanghe2000

大家好，请教大家一个perl处理文本文件的问题。
想了蛮久，没有想到怎么处理。
来这里求助下，先谢了哈。

读入1个txt文件，然后把该文件的每一题按照题号(1. 或者 3. 或者 4. 或 10. 或 12.)、字母序号(A. 或 B. 或 C.  或 D.  或 E. 或 F. 或 G.)存入hash中，作为hash的2个key，后面的作为value。

例如：
       $hash{1.}{A.} = 'chmop'
       $hash{1.}{D.} = 'unlink'

       $hash{10.}{B.} = 'remove'
       $hash{10.}{D.} = 'delete'

       $hash{19.}{B.} = '@nums=sort {$b <=> $a} @numbers'
       $hash{19.}{D.} = '@nums=sort {$b cmp $a} @numbers'

注意，下面的只是一个小例子，实际上，
题目序号1., 2., 1000., 或更多，
字母序号，可能更多，如有A. B. C. D. E. F. G.；
字母序号A.  B.  C.  D. 可能都在一行；也可能在4行；也可能在3行(A. B. 在1行，C. 在1行，D. 在1行)
怎样才能完全的，更健壮的？

1. 
   
2. 1. which command is used to cut trailing newline?                     ( B )
   
3. A. chmop           B. chomp
   
4. C. chop            D. unlink
   
5. 
   
6. 3. It is better to add a semicolon at the end of line in block        ( A )
   
7. in order to build a good program style.                       
   
8. A. True            B. Flase
   
9. 
   
10. 4. which command will jump current loop and enter into another loop?  ( C )
    
11. A. continue        B. break
    
12. C. next            D. last      E. redo      F. done     G. do   
    
13. 
    
14. 10.The ____ function removes the given key                            ( D )
    
15. (and its corresponding value) from the hash.            
    
16. A. del             B. remove        C. cut             D. delete
    
17. 
    
18. 12.The ____ function yields a list of all the keys in a hash,         ( A )
    
19. and the values function gives the corresponding values.      
    
20. A. keys            B. Keys      C. values          D. value
    
21. 
    
22. 19.How to sort an array by ascending  numeric order, such as @numbers              ( A )
    
23. A. @nums=sort {$a <=> $b} @numbers      B. @nums=sort {$b <=> $a} @numbers      
    
24. C. @nums=sort {$a cmp $b} @numbers      D. @nums=sort {$b cmp $a} @numbers      
    

复制代码

MMMIX

回复 1# weichanghe2000


    如果给出的例子有代表性的话，下述代码应该可以：

sub load_questions {
  local @ARGV = @_;

  my (%questions, $number);

  while (<>) {                        # Begin of question
    if (/^\s* (\d+) \s* \. .* \(\s* ([A-Z]) \s*\) \s*$/x) {
      $number = $1;
      $questions{$number}{__ANSWER__} = $2;
      $questions{$number}{__QUESTION__} = $_;
    }
    elsif (not /^\s*[A-Z]\s*\./) { # Continuing of question
      $questions{$number}{__QUESTION__} .= $_;
    }
    else {                        # Answers
      my @fields = split /\s*([A-Z])\s*\.\s*/;
      shift @fields;
      my %fields = map { s/^\s*//; s/\s*$//; $_ } @fields;
      while (my ($key, $val) = each %fields) {
        $questions{$number}{$key} = $val;
      }
    }
  }

  wantarray ? %questions : \%questions;
}

还缺些错误检查，自己加上吧。

weichanghe2000

回复 2# MMMIX

非常感谢。
但是我把你的代码贴进去，然后调用时，会报一个错。
不知道哪里出错了呢？



找到原因了，需要先去掉空行。
   

jason680

回复 1# weichanghe2000

$ perl exam.pl exam.txt
1. which command is used to cut trailing newline?
     Ans ( B ) : chomp
3. It is better to add a semicolon at the end of line in block in order to build a good program style.
     Ans ( A ) : True            
4. which command will jump current loop and enter into another loop?
     Ans ( C ) : next            
10. The ____ function removes the given key (and its corresponding value) from the hash.
     Ans ( D ) : delete
12. The ____ function yields a list of all the keys in a hash, and the values function gives the corresponding values.
     Ans ( A ) : keys            
19. How to sort an array by ascending  numeric order, such as @numbers
     Ans ( A ) : @nums=sort {$a <=> $b} @numbers      


$ cat exam.pl
use strict;
use warnings;

my %hExam;
my($sNum, $sAns,$sQu);
while(<>){
    chomp;
    if(s/^(\d+)[.]//){
        $sNum = $1;
        if(! s/\( \s* (\S+) \s* \) \s*$//x){
            die "exam $sNum: can't not get Answer field\n";
        }
        $sAns = $1;
        s/^\s+|\s+$//g;
        $sQu  = $_;
        next;
    }
    if(m/^[ABCDEFG][.] /){
        my(undef, %hAns) = split(/([A-G])[.] /);
        foreach(keys %hAns){
          $hExam{$sNum}{$_} = $hAns{$_};
        }
        $hExam{$sNum}{"QU"}  = $sQu;
        $hExam{$sNum}{"ANS"} = $sAns;
        next;
    }
    next if(m/^\s*$/);
    s/^\s+|\s+$//g;
    $sQu .= " $_";
}
for(sort {$a <=> $b} keys %hExam){
  print "$_. $hExam{$_}{QU}\n";
  $sAns = $hExam{$_}{ANS};
  print "     Ans ( $sAns ) : $hExam{$_}{$sAns}\n";
}

weichanghe2000

回复 2# MMMIX
     
      my @fields = split /\s*([A-Z])\s*\.\s*/;
      shift @fields;

这2句看了很久，没有看懂。
能够帮忙解释下吗？

我平时只用到 split /\s+/, $_， 用空格作为分隔。
我把你的加上了打印信息，但看得更加糊涂了。
1:A,   A还在，但是后面 那个. 怎么没有了呢？


   

MMMIX

回复 5# weichanghe2000


    split 的 pattern 中若有 capture group，在返回的 list 中也会包括这些 capture group 匹配到的内容，详细看 perldoc -f split 的末尾。

weichanghe2000

回复 6# MMMIX

非常感谢哈。
可能英语理解比较差，那几句话看了半天，理解起来还是相当费力气。
呵呵，perl基础和功底太弱了。
   

weichanghe2000

回复 4# jason680

非常感谢大神哈。
由于自己基础很一般，需要慢慢咀嚼和消化。
慢慢体会大神的思想。