sed 如何清空hold space

guang329

有一个文本 由 [TIME]文本\n若干行文本\n[SQL_EXECUTE_TIME(ms)]文本\n   组成如下

[TIME]:2016-09-06 02:00:45
SELECT
balance_rule_id,
rule_type,
rule_desc
FROM  acct_test.BALANCE_TYPE_RULE_DESC
[SQL_EXECUTE_TIME(ms)]:28
[TIME]:2016-09-06 02:00:45
SELECT SYSDATE FROM DUAL
[SQL_EXECUTE_TIME(ms)]:1




现在想将 [TIME] 跟 [SQL_EXECUTE_TIME(ms)] 之间的文本都拼接为一行

我的语句如下 (换行替换为# 为了方便观察替换了多少个换行符)
思路是先将 pattern space（模式空间）都放到  hold space（保留空间）
直到匹配到 SQL_EXECUTE 然后将 复制 hold space 的内容到 pattern space 并将换行符替换，拼接成一行
清空 pattern space，hold space

sed -n 'H;/SQL_EXECUTE/{g;s/\n/#/gp;d;x;d
}
' file


执行结果如下
#[TIME]:2016-09-06 02:00:45#SELECT #balance_rule_id,#rule_type,#rule_desc ## FROM  acct_test.BALANCE_TYPE_RULE_DESC##[SQL_EXECUTE_TIME(ms)]:28
#[TIME]:2016-09-06 02:00:45#SELECT #balance_rule_id,#rule_type,#rule_desc ## FROM  acct_test.BALANCE_TYPE_RULE_DESC##[SQL_EXECUTE_TIME(ms)]:28##[TIME]:2016-09-06 02:00:45# SELECT SYSDATE FROM DUAL ##[SQL_EXECUTE_TIME(ms)]:1


看现象好像似乎没有清空掉 hold space的内存。
求高人指点。

haooooaaa

1. sed ':a;/\n\[TIME/{P;D};N;s/\n/ /;/SQL_EXECUTE_TIME/!ba;'

复制代码

guang329

2楼 你的语句我跑不了呢  我用的是 aix 系统
28gxbsn@hot5[/gxbsn/ZXBilling/lgb]$sed ':a;/\n\[TIME/{P;D
> }
> ;N;s/\n/ /;/SQL_EXECUTE_TIME/!ba;'  file
sed: 0602-417 The label :a;/\n\[TIME/{P;D is greater than eight characters.

moperyblue

1. sed -n 'H;/SQL_EXECUTE/{g;s/\n/#/gp;s/.*//;h}'
   
2. sed '/TIME]/{:a;N;s/\n/#/;/SQL_EXECUTE_TIME/!ba}'
   
3. sed '/TIME]/{h;d};H;/SQL_EXECUTE_TIME/{g;s/\n/#/gp};d'

复制代码

jason680

回复 1# guang329

$ awk '/\[TIME/{ORS=" "}/\[SQL_EXECUTE/{ORS="\n"}1' FILE
[TIME]:2016-09-06 02:00:45 SELECT balance_rule_id, rule_type, rule_desc FROM  acct_test.BALANCE_TYPE_RULE_DESC [SQL_EXECUTE_TIME(ms)]:28
[TIME]:2016-09-06 02:00:45 SELECT SYSDATE FROM DUAL [SQL_EXECUTE_TIME(ms)]:1

yinyuemi

回复 1# guang329

sed '/\[TIME\]/{:a;N;/\n\[TIME\]/{P;D};s/\n/##/;ta}'

guang329

回复 4# moperyblue请教一下4楼
你通过 s/.*//;h  这个方式清空hold space
我通过 d;x;d  怎么清空不了 hold space 呢   


回复 5# 本友会机友会摄友会
文本不大 只是想一个语句处理完 看起来简洁一点

回复 6# jason680
可行 awd也是不错的选择

回复 7# yinyuemi
貌似 aix 的sed 用了a参数都报
sed: 0602-417 The label /\[TIME\]/{:a;N;/\n\[TIME\]/{P;D};s/\n/##/;ta} is greater than eight characters. 这个错误


感谢大家帮忙 。
不过我还是有一点点疑惑
为什么通过 d;x;d  
删除 pattern space  
然后 x; 交换 pattern space  hold space
再次 删除 pattern space
不能把 hold space 清空掉呢。  
sed 是否有什么限制吗？

moperyblue

回复 8# guang329

执行d后就会读入下一行了

info sed =>

`d'
     Delete the pattern space; immediately start next cycle.

yinyuemi

回复 8# guang329

d 后面的代码都会被忽略