文本行横竖转换

waker

改的好读一点儿吧

1. 
   
2. H            #保存所有行
   
3. ${          #最后一行处理，与AWK的END相似
   
4. :a
   
5. g            #取得保留空间内容
   
6. s/\n[^\n]/\n/g       #把第一个不是换行符删除
   
7. :b                                      #与下面一句形成循环
   
8. /[^\n]/s/\n\n/\n \n/g;tb    #其实是补位用的
   
9. x                                       #交换保留/模式空间内容，这时保留空间已经没有每"行"的第一个字符了
   
10. s/\n\+\([^\n]\)[^\n]*/\1/gp;ta   #打印出模式空间的所有"行"的第一个字符，再去:a处处理保留空间的内容
    
11. }
    

复制代码

faintblue

原帖由 waker 于 2006-1-12 09:12 发表
... 当然部分不支持\n的用户不能通过 ...

Yes, many sed versions don't support \n as a replacement.

r2007

空行没有考虑吧？
1234567

drmfslx

r2007

原帖由 faintblue 于 2006-1-12 11:12 发表


Yes, many sed versions don't support \n as a replacement.

这样是否移植性更好？

1. sed -n 'H;${:a;
   
2. g;
   
3. s/\(\n\)[^\n]/\1/g;
   
4. :b;
   
5. /[^\n]/s/\(\n\)\1/\1 \1/g;tb;
   
6. x;
   
7. s/\n\+\([^\n]\)[^\n]*/\1/gp;ta}'
   

复制代码

r2007

加了一行就出问题了

1. cat file
   
2. 123456
   
3. abc
   
4. ABCDE
   
5. hijk
   
6. lmnopqrstuvw
   
7. ^_^

复制代码

结果

1. 1aAhl^
   
2. 2bBim_
   
3. 3cCjn^
   
4. 4 Dko
   
5. 
   
6. 5 E p
   
7. 
   
8. 6   q
   
9. 
   
10.     r
    
11. 
    
12.     s
    
13. 
    
14.     t
    
15. 
    
16.     u
    
17. 
    
18.     v
    
19. 
    
20.     w
    

复制代码

waker

空行好解决
最前面加
/^$/s// /

多换行的问题还得考虑

faintblue

原帖由 r2007 于 2006-1-12 12:02 发表

这样是否移植性更好？

s/\n\+\([^\n]\)[^\n]*/\1/gp;ta}'

+ is bad for 移植性.

waker

再修订一次吧，虽然不能满足所有sed版本
不过感觉还有修改空间

1. sed -n '/^$/s// /
   
2. H
   
3. ${
   
4. :a
   
5. g
   
6. s/\(\n\)[^\n]/\1/g
   
7. :b
   
8. /[^\n]/s/\(\n\)\1/\1 \1/g
   
9. tb
   
10. x;
    
11. s/\n\n*\([^\n]\)[^\n]*/\1/g
    
12. s/\n//g
    
13. /[^\n]/{p;ba}
    
14. }' file
    

复制代码

dbcat

感谢蚂蚁,烈火,FAINTBLUE , WAKER ,R2007 的无私帮助!
问题圆满解决!
向你们致敬!

[ 本帖最后由 dbcat 于 2006-1-12 17:13 编辑 ]

大蚂蚁

呵呵，我是来学习的，建议美女把帖子改个名字，以后方便查阅