awk1line 实现 sed1line

yinyuemi

sed1line代码来自http://sed.sourceforge.net/sed1line.txt，用awk1line实现，请大家指正，欢迎拍砖！

1. FILE SPACING:
   
2. 
   
3. # double space a file
   
4. 
   
5. -> sed G
   
6. 
   
7. -> awk '$0=$0 ORS'  or awk '1{print ""}' or: awk -vORS="\n\n" '1'
   
8. 
   
9. 
   
10. # double space a file which already has blank lines in it. Output file
    
11. 
    
12. # should contain no more than one blank line between lines of text.
    
13. 
    
14. -> sed '/^$/d;G'
    
15. 
    
16. -> awk NF ORS='\n\n'
    
17. 
    
18. 
    
19. # triple space a file
    
20. 
    
21. -> sed 'G;G'
    
22. 
    
23. -> awk '$0=$0 ORS ORS'
    
24. 
    
25. 
    
26. # undo double-spacing (assumes even-numbered lines are always blank)
    
27. 
    
28. -> sed 'n;d'
    
29. 
    
30. -> awk 'i=!i'
    
31. （有很多可以实现这个的awk方法，这里只给出黑哥的码）
    
32. 
    
33. # insert a blank line above every line which matches "regex"
    
34. 
    
35. -> sed '/regex/{x;p;x;}'
    
36. 
    
37. -> awk '/regex/{$0=ORS $0}1'
    
38. 
    
39. 
    
40. # insert a blank line below every line which matches "regex"
    
41. 
    
42. -> sed '/regex/G'
    
43. 
    
44. -> awk '/regex/{$0=$0 ORS}1' or: awk '{ORS=(/regex/)?"\n\n":"\n"}1'
    
45. 
    
46. 
    
47. # insert a blank line above and below every line which matches "regex"
    
48. 
    
49. -> sed '/regex/{x;p;x;G;}'
    
50. 
    
51. -> awk '/regex/{$0=ORS $0 ORS}1'
    
52. 
    
53. 
    
54. NUMBERING:
    
55. 
    
56. # number each line of a file (simple left alignment). Using a tab (see
    
57. 
    
58. # note on '\t' at end of file) instead of space will preserve margins.
    
59. 
    
60. -> sed = filename | sed 'N;s/\n/\t/'
    
61. 
    
62. -> awk '{print NR"\t"$0}' filename
    
63. 
    
64. 
    
65. # number each line of a file (number on left, right-aligned)
    
66. 
    
67. -> sed = filename | sed 'N; s/^/     /; s/ *\(.\{6,\}\)\n/\1  /'
    
68. 
    
69. -> awk '{printf "%6s  %s\n", NR,$0}' filename
    
70. 
    
71. 
    
72. # number each line of file, but only print numbers if line is not blank
    
73. 
    
74. -> sed '/./=' filename | sed '/./N; s/\n/ /'
    
75. 
    
76. -> awk '{print NF?NR" "$0:$0}' filename
    
77. 
    
78. 
    
79. # count lines (emulates "wc -l")
    
80. 
    
81. -> sed -n '$='
    
82. 
    
83. -> awk 'END{print NR}'
    
84. 
    
85. 
    
86. TEXT CONVERSION AND SUBSTITUTION:
    
87. 
    
88. # IN UNIX ENVIRONMENT: convert DOS newlines (CR/LF) to Unix format.
    
89. 
    
90. -> sed 's/.$//'               # assumes that all lines end with CR/LF
    
91. 
    
92. -> awk '{sub(/.$/,"",$0);print}'
    
93. 
    
94. -> sed 's/^M$//'              # in bash/tcsh, press Ctrl-V then Ctrl-M
    
95. 
    
96. -> awk '{sub(/^M$/,"",$0);print}'
    
97. 
    
98. -> sed 's/\x0D$//'            # works on ssed, gsed 3.02.80 or higher
    
99. -> gawk '{sub(/\x0D$/,"",$0);print}'
    
100. 
     
101. # IN UNIX ENVIRONMENT: convert Unix newlines (LF) to DOS format.
     
102. 
     
103. -> sed "s/$/`echo -e \\\r`/"            # command line under ksh
     
104. -> sed 's/"/`echo \\\r`/"             # command line under bash
     
105. -> sed "s/$/`echo \\\r`/"               # command line under zsh
     
106. -> sed 's/$/\r/'                        # gsed 3.02.80 or higher
     
107. -> gawk '{sub(/$/,"\r",$0);print}'
     
108. 
     
109. # delete leading whitespace (spaces, tabs) from front of each line
     
110. 
     
111. # aligns all text flush left
     
112. 
     
113. -> sed 's/^[ \t]*//'                    # see note on '\t' at end of file
     
114. 
     
115. -> awk '{sub(/^[ \t]*/,"",$0);print}'
     
116. 
     
117. 
     
118. # delete trailing whitespace (spaces, tabs) from end of each line
     
119. 
     
120. -> sed 's/[ \t]*$//'                    # see note on '\t' at end of file
     
121. 
     
122. -> awk '{sub(/[ \t]*$/,"",$0);print}'
     
123. 
     
124. 
     
125. # delete BOTH leading and trailing whitespace from each line
     
126. 
     
127. -> sed 's/^[ \t]*//;s/[ \t]*$//'
     
128. 
     
129. -> awk '{sub(/^[ \t]*/,"",$0);sub(/[ \t]*$/,"",$0);print}'
     
130. 
     
131. 
     
132. # insert 5 blank spaces at beginning of each line (make page offset)
     
133. 
     
134. -> sed 's/^/     /'
     
135. 
     
136. -> awk '{sub(/^/,"     ",$0);print}'
     
137. 
     
138. 
     
139. # align all text flush right on a 79-column width
     
140. 
     
141. -> sed -e :a -e 's/^.\{1,78\}$/ &/;ta'  # set at 78 plus 1 space
     
142. 
     
143. -> awk '{printf "%79s\n",$0}'
     
144. 
     
145. 
     
146. # center all text in the middle of 79-column width. In method 1,
     
147. 
     
148. # spaces at the beginning of the line are significant, and trailing
     
149. 
     
150. # spaces are appended at the end of the line. In method 2, spaces at
     
151. 
     
152. # the beginning of the line are discarded in centering the line, and
     
153. 
     
154. # no trailing spaces appear at the end of lines.
     
155. 
     
156. -> sed  -e :a -e 's/^.\{1,77\}$/ & /;ta'                     # method 1
     
157. -> sed  -e :a -e 's/^.\{1,77\}$/ &/;ta' -e 's/\( *\)\1/\1/'  # method 2
     
158. 
     
159. -> awk '{t=(79-length)/2+length;printf "%"t"s%"79-t"s\n",$0," "}' #length=length($0)
     
160. 
     
161. 
     
162. # substitute (find and replace) "foo" with "bar" on each line
     
163. 
     
164. -> sed 's/foo/bar/'             # replaces only 1st instance in a line
     
165. 
     
166. -> awk '{sub(/foo/,"bar");print}'
     
167. 
     
168. -> sed 's/foo/bar/4'            # replaces only 4th instance in a line
     
169. 
     
170. -> gawk '{$0=gensub(/foo/,"bar",4,$0);print}'
     
171. 
     
172. -> sed 's/foo/bar/g'            # replaces ALL instances in a line
     
173. 
     
174. -> awk '{gsub(/foo/,"bar");print}'
     
175. 
     
176. -> sed 's/\(.*\)foo\(.*foo\)/\1bar\2/' # replace the next-to-last case
     
177. 
     
178. -> gawk '{$0=gensub(/(.*)foo(.*foo)/,"\\1bar\\2","g",$0);print}'
     
179. 
     
180. -> sed 's/\(.*\)foo/\1bar/'            # replace only the last case
     
181. 
     
182. -> gawk '{$0=gensub(/(.*)foo/,"\\1bar","g",$0);print}'
     
183. 
     
184. # substitute "foo" with "bar" ONLY for lines which contain "baz"
     
185. 
     
186. -> sed '/baz/s/foo/bar/g'
     
187. 
     
188. -> awk '/baz/{gsub(/foo/,"bar")}1'
     
189. 
     
190. 
     
191. # substitute "foo" with "bar" EXCEPT for lines which contain "baz"
     
192. 
     
193. -> sed '/baz/!s/foo/bar/g'
     
194. 
     
195. -> awk '!/baz/{gsub(/foo/,"bar")}1'
     
196. 
     
197. 
     
198. # change "scarlet" or "ruby" or "puce" to "red"
     
199. 
     
200. -> sed 's/scarlet/red/g;s/ruby/red/g;s/puce/red/g'   # most seds
     
201. 
     
202. -> gsed 's/scarlet\|ruby\|puce/red/g'                # GNU sed only
     
203. 
     
204. -> gawk '{gsub(/scarlet|ruby|puce/,"red");print}'
     
205. 
     
206. # reverse order of lines (emulates "tac")
     
207. 
     
208. # bug/feature in HHsed v1.5 causes blank lines to be deleted
     
209. 
     
210. -> sed '1!G;h;$!d'               # method 1
     
211. -> sed -n '1!G;h;$p'             # method 2
     
212. 
     
213. -> awk '{a[NR]=$0}END{i=NR;while(i>=1) print a[i--]}'
     
214. 
     
215. 
     
216. # reverse each character on the line (emulates "rev")
     
217. 
     
218. -> sed '/\n/!G;s/\(.\)\(.*\n\)/&\2\1/;//D;s/.//'
     
219. 
     
220. -> awk -vFS= '{i=NF;while(i>=1) printf $(i--);print ""}'
     
221. 
     
222. 
     
223. # join pairs of lines side-by-side (like "paste")
     
224. 
     
225. -> sed '$!N;s/\n/ /'
     
226. 
     
227. -> awk 'ORS=NR%2?FS:RS' or: awk '{getline line;print $0 FS line}'
     
228. 
     
229. 
     
230. # if a line ends with a backslash, append the next line to it
     
231. 
     
232. -> sed -e :a -e '/\\$/N; s/\\\n//; ta'
     
233. 
     
234. -> awk '/\\$/{sub(/\\$/,"");printf $0;next}1'
     
235. 
     
236. 
     
237. # if a line begins with an equal sign, append it to the previous line
     
238. 
     
239. # and replace the "=" with a single space
     
240. 
     
241. -> sed -e :a -e '$!N;s/\n=/ /;ta' -e 'P;D'
     
242. 
     
243. -> awk -vRS='\n=' -vORS=' ' '{print}'
     
244. 
     
245. 
     
246. # add commas to numeric strings, changing "1234567" to "1,234,567"
     
247. 
     
248. -> gsed ':a;s/\B[0-9]\{3\}\>/,&/;ta'                     # GNU sed
     
249. -> sed -e :a -e 's/\(.*[0-9]\)\([0-9]\{3\}\)/\1,\2/;ta'  # other seds
     
250. 
     
251. -> awk -v FS=OFS= '{for(i=2;i<=NF;i++) $i=(NF-i+1)%3?$i:","$i}1'
     
252. 
     
253.   
     
254. # add commas to numbers with decimal points and minus signs (GNU sed)
     
255. 
     
256. -> gsed -r ':a;s/(^|[^0-9.])([0-9]+)([0-9]{3})/\1\2,\3/g;ta'
     
257. 
     
258. -> awk -v FS=OFS= '{for(i=$1=="-"?3:2;i<=NF;i++) if($i==".") break; else {$i=(NF-i+1)%3?$i:","$i}}1'
     
259. 
     
260. 
     
261. # add a blank line every 5 lines (after lines 5, 10, 15, 20, etc.)
     
262. 
     
263. -> gsed '0~5G'                  # GNU sed only
     
264. -> sed 'n;n;n;n;G;'             # other seds
     
265. 
     
266. -> awk '{$0=NR%5?$0:$0 ORS}1'
     
267. 
     
268. 
     
269. SELECTIVE PRINTING OF CERTAIN LINES:
     
270. 
     
271. # print first 10 lines of file (emulates behavior of "head")
     
272. 
     
273. -> sed 10q
     
274. 
     
275. -> awk 'NR==10{print;exit}1' or:awk '1;NR==10{exit}' (多谢Tim兄)
     
276. 
     
277. 
     
278. # print first line of file (emulates "head -1")
     
279. 
     
280. -> sed q
     
281. 
     
282. -> awk 'NR==1{print;exit}' or: awk '{print;exit}' (多谢Tim兄)
     
283. 
     
284. 
     
285. # print the last 10 lines of a file (emulates "tail")
     
286. 
     
287. -> sed -e :a -e '$q;N;11,$D;ba'
     
288. 
     
289. -> awk '{a[NR]=$0;delete a[NR-10]}END{for(i=NR-9;i<=NR;i++) print a[i]}'
     
290. 
     
291. 
     
292. # print the last 2 lines of a file (emulates "tail -2")
     
293. 
     
294. -> sed '$!N;$!D'
     
295. 
     
296. -> awk '{a=b;b=$0}END{print a ORS b}'
     
297. 
     
298. 
     
299. # print the last line of a file (emulates "tail -1")
     
300. 
     
301. -> sed '$!d'                    # method 1
     
302. -> sed -n '$p'                  # method 2
     
303. 
     
304. -> awk 'END{print $0}'
     
305. 
     
306. 
     
307. # print the next-to-the-last line of a file
     
308. 
     
309. -> sed -e '$!{h;d;}' -e x              # for 1-line files, print blank line
     
310. 
     
311. -> awk '{a=b;b=$0}END{print a}'
     
312. 
     
313. -> sed -e '1{$q;}' -e '$!{h;d;}' -e x  # for 1-line files, print the line
     
314. 
     
315. -> awk '{a=b;b=$0}END{print a?a:b}'
     
316. 
     
317. -> sed -e '1{$d;}' -e '$!{h;d;}' -e x  # for 1-line files, print nothing
     
318. 
     
319. -> awk '{a=b;b=$0}END{printf a?a ORS:""}'
     
320. 
     
321. 
     
322. # print only lines which match regular expression (emulates "grep")
     
323. 
     
324. -> sed -n '/regexp/p'           # method 1
     
325. -> sed '/regexp/!d'             # method 2
     
326. 
     
327. -> awk '/regxp/'
     
328. 
     
329. 
     
330. # print only lines which do NOT match regexp (emulates "grep -v")
     
331. 
     
332. -> sed -n '/regexp/!p'          # method 1, corresponds to above
     
333. -> sed '/regexp/d'              # method 2, simpler syntax
     
334. 
     
335. -> awk '!/regxp/'
     
336. 
     
337. 
     
338. # print the line immediately before a regexp, but not the line
     
339. 
     
340. # containing the regexp
     
341. 
     
342. -> sed -n '/regexp/{g;1!p;};h'
     
343. 
     
344. -> awk '{a=b;b=$0}/regexp/{print a}'
     
345. 
     
346. 
     
347. # print the line immediately after a regexp, but not the line
     
348. 
     
349. # containing the regexp
     
350. 
     
351. -> sed -n '/regexp/{n;p;}'
     
352. 
     
353. -> awk '/regexp/{getline line;print line}'
     
354. 
     
355. 
     
356. # print 1 line of context before and after regexp, with line number
     
357. 
     
358. # indicating where the regexp occurred (similar to "grep -A1 -B1")
     
359. 
     
360. -> sed -n -e '/regexp/{=;x;1!p;g;$!N;p;D;}' -e h
     
361. 
     
362. -> awk '{a=b;b=c;c=$0}b~/6/{printf "%s\n%s\n%s\n%s\n",NR-1,a,b,c}'
     
363. 
     
364. 
     
365. -> awk '{a=b;b=$0}/6/{getline c;print NR-1"\n"a"\n"b"\n"c}'
     
366. 
     
367. 
     
368. # grep for AAA and BBB and CCC (in any order)
     
369. 
     
370. -> sed '/AAA/!d; /BBB/!d; /CCC/!d'
     
371. 
     
372. -> awk '/AAA/&&/BBB/&&/CCC/'
     
373. 
     
374. 
     
375. # grep for AAA and BBB and CCC (in that order)
     
376. 
     
377. -> sed '/AAA.*BBB.*CCC/!d'
     
378. 
     
379. -> awk '/AAA.*BBB.*CCC/'
     
380. 
     
381. 
     
382. # grep for AAA or BBB or CCC (emulates "egrep")
     
383. 
     
384. -> sed -e '/AAA/b' -e '/BBB/b' -e '/CCC/b' -e d    # most seds
     
385. -> gsed '/AAA\|BBB\|CCC/!d'                        # GNU sed only
     
386. 
     
387. -> awk '/AAA|BBB|CCC/'
     
388. 
     
389. 
     
390. # print paragraph if it contains AAA (blank lines separate paragraphs)
     
391. 
     
392. # HHsed v1.5 must insert a 'G;' after 'x;' in the next 3 scripts below
     
393. 
     
394. -> sed -e '/./{H;$!d;}' -e 'x;/AAA/!d;'
     
395. 
     
396. -> awk -vRS='\n\n' '/AAA/'
     
397. 
     
398. 
     
399. # print paragraph if it contains AAA and BBB and CCC (in any order)
     
400. 
     
401. -> sed -e '/./{H;$!d;}' -e 'x;/AAA/!d;/BBB/!d;/CCC/!d'
     
402. 
     
403. -> awk -vRS='\n\n' '/AAA/&&/BBB/&&/CCC/'
     
404. 
     
405. 
     
406. # print paragraph if it contains AAA or BBB or CCC
     
407. 
     
408. -> sed -e '/./{H;$!d;}' -e 'x;/AAA/b' -e '/BBB/b' -e '/CCC/b' -e d
     
409. -> gsed '/./{H;$!d;};x;/AAA\|BBB\|CCC/b;d'         # GNU sed only
     
410. 
     
411. -> awk -vRS='\n\n' '/AAA|BBB|CCC/'
     
412. 
     
413. 
     
414. # print only lines of 65 characters or longer
     
415. 
     
416. -> sed -n '/^.\{65\}/p'
     
417. 
     
418. -> awk 'length>=65'
     
419. 
     
420. 
     
421. # print only lines of less than 65 characters
     
422. 
     
423. -> sed -n '/^.\{65\}/!p'        # method 1, corresponds to above
     
424. -> sed '/^.\{65\}/d'            # method 2, simpler syntax
     
425. 
     
426. -> awk 'length<65' or awk 'NF<65' FS=
     
427. 
     
428. 
     
429. # print section of file from regular expression to end of file
     
430. 
     
431. -> sed -n '/regexp/,$p'
     
432. 
     
433. -> awk '/regexp/,0' or awk '/regexp/,EOF'
     
434. 
     
435. 
     
436. # print section of file based on line numbers (lines 8-12, inclusive)
     
437. 
     
438. -> sed -n '8,12p'               # method 1
     
439. -> sed '8,12!d'                 # method 2
     
440. 
     
441. -> awk 'NR==8,NR==12' OR awk 'NR>=8&&NR<=12'
     
442. 
     
443. 
     
444. # print line number 52
     
445. 
     
446. -> sed -n '52p'                 # method 1
     
447. -> sed '52!d'                   # method 2
     
448. -> sed '52q;d'                  # method 3, efficient on large files
     
449. 
     
450. -> awk 'NR==52{print;exit}'
     
451. 
     
452. 
     
453. # beginning at line 3, print every 7th line
     
454. 
     
455. -> gsed -n '3~7p'               # GNU sed only
     
456. -> sed -n '3,${p;n;n;n;n;n;n;}' # other seds
     
457. 
     
458. -> awk 'NR>=3&&!((NR-3)%10)'
     
459. 
     
460. 
     
461. # print section of file between two regular expressions (inclusive)
     
462. 
     
463. -> sed -n '/Iowa/,/Montana/p'             # case sensitive
     
464. 
     
465. -> awk '/Iowa/,/Montana/'
     
466. 
     
467. 
     
468. SELECTIVE DELETION OF CERTAIN LINES:
     
469. 
     
470. # print all of file EXCEPT section between 2 regular expressions
     
471. 
     
472. -> sed '/Iowa/,/Montana/d'
     
473. 
     
474. -> awk 'Iowa/,Montana/{next}1'
     
475. 
     
476. 
     
477. # delete duplicate, consecutive lines from a file (emulates "uniq").
     
478. 
     
479. # First line in a set of duplicate lines is kept, rest are deleted.
     
480. 
     
481. -> sed '$!N; /^\(.*\)\n\1$/!P; D'
     
482. 
     
483. -> awk '{printf $0==v?"":$0 ORS;v=$0}' or: awk 'a !~ $0; {a=$0}'
     
484. 
     
485. 
     
486. # delete duplicate, nonconsecutive lines from a file. Beware not to
     
487. 
     
488. # overflow the buffer size of the hold space, or else use GNU sed.
     
489. 
     
490. -> sed -n 'G; s/\n/&&/; /^\([ -~]*\n\).*\n\1/d; s/\n//; h; P'
     
491. 
     
492. -> awk '!a[$0]++'
     
493. 
     
494. 
     
495. # delete all lines except duplicate lines (emulates "uniq -d").
     
496. 
     
497. -> sed '$!N; s/^\(.*\)\n\1$/\1/; t; D'
     
498. 
     
499. -> awk '!(a[$0]++-1)'
     
500. 
     
501. 
     
502. # delete the first 10 lines of a file
     
503. 
     
504. -> sed '1,10d'
     
505. 
     
506. -> awk '++p>10'
     
507. 
     
508. 
     
509. # delete the last line of a file
     
510. 
     
511. -> sed '$d'
     
512. 
     
513. -> awk '{a=b;b=$0}NR>1{print a}' OR: awk '{a[NR+1]=$0;if(NR>1)print a[NR]}'
     
514. 
     
515. 
     
516. # delete the last 2 lines of a file
     
517. 
     
518. -> sed 'N;$!P;$!D;$d'
     
519. 
     
520. -> awk '{a[NR+2]=$0;if(NR>2)print a[NR]}' OR: awk '{a=b;b=c;c=$0}NR>2{print a}'
     
521. 
     
522. 
     
523. 
     
524. # delete the last 10 lines of a file
     
525. 
     
526. -> sed -e :a -e '$d;N;2,10ba' -e 'P;D'   # method 1
     
527. -> sed -n -e :a -e '1,10!{P;N;D;};N;ba'  # method 2
     
528. 
     
529. -> awk '{a[NR+10]=$0;if(NR>10)print a[NR]}'
     
530. 
     
531. （如果文件非常大，内存有限的话，加个delete，如下
     
532. 
     
533. -> awk '{a[NR+10]=$0;if(NR>10){print a[NR]
     
534. ；delete a[NR]}}'）
     
535. 
     
536. # delete every 8th line
     
537. 
     
538. -> gsed '0~8d'                           # GNU sed only
     
539. -> sed 'n;n;n;n;n;n;n;d;'                # other seds
     
540. 
     
541. -> awk 'NR%8'
     
542. 
     
543. 
     
544. # delete lines matching pattern
     
545. 
     
546. -> sed '/pattern/d'
     
547. 
     
548. -> awk '/pattern/{next}1'
     
549. 
     
550. 
     
551. 
     
552. # delete ALL blank lines from a file (same as "grep '.' ")
     
553. 
     
554. -> sed '/^$/d'                           # method 1
     
555. -> sed '/./!d'                           # method 2
     
556. 
     
557. -> awk NF
     
558. 
     
559. 
     
560. # delete all CONSECUTIVE blank lines from file except the first; also
     
561. 
     
562. # deletes all blank lines from top and end of file (emulates "cat -s")
     
563. 
     
564. -> sed '/./,/^$/!d'          # method 1, allows 0 blanks at top, 1 at EOF
     
565. 
     
566. -> awk '{/^$/?p--:p=1}!p>=0'
     
567. 
     
568. -> sed '/^$/N;/\n$/D'        # method 2, allows 1 blank at top, 0 at EOF
     
569. 
     
570. -> awk -v p=1 '{/^$/?p--:p=1}!p>=0'
     
571. 
     
572. 
     
573. # delete all CONSECUTIVE blank lines from file except the first 2:
     
574. 
     
575. -> sed '/^$/N;/\n$/N;//D'
     
576. 
     
577. -> awk -v p=2 '{/^$/?p--:p=2}!p>=0'
     
578. 
     
579. 
     
580. # delete all leading blank lines at top of file
     
581. 
     
582. -> sed '/./,$!d'
     
583. 
     
584. -> awk '!/^$/{p=1}p' OR: awk '!/^$/,0'
     
585. 
     
586. 
     
587. # delete all trailing blank lines at end of file
     
588. 
     
589. -> sed -e :a -e '/^\n*$/{$d;N;ba' -e '}'  # works on all seds
     
590. -> sed -e :a -e '/^\n*$/N;/\n$/ba'        # ditto, except for gsed 3.02.*
     
591. 
     
592. -> awk -vRS='[\n]* '1'
     
593. 
     
594. 
     
595. # delete the last line of each paragraph
     
596. 
     
597. -> sed -n '/^$/{p;h;};/./{x;/./p;}'
     
598. 
     
599. -> awk '{a=b;b=$0}NR>1{printf /^$/?"":a ORS}'
     
600. 
     
601. 
     

复制代码

总的来说，awk 和 sed是各有所长，灵活应用它们，基本上可以应付日常的文本处理。

补充：关于/foo1/,/foo2/匹配在sed和awk使用中的异同。（非常感谢Tim的指正和帮助！！）

相同的情况：

1. echo 'xxx
   
2. foo1
   
3. yyy
   
4. foo2
   
5. zzz' | sed -n '/foo1/,/foo2/p'
   
6. foo1
   
7. yyy
   
8. foo2
   
9. 
   
10. echo 'xxx
    
11. foo1
    
12. yyy
    
13. foo2
    
14. zzz' |awk '/foo1/,/foo2/'
    
15. foo1
    
16. yyy
    
17. foo2
    
18. 
    
19. 即上面正文中，/foo1/,/foo2/匹配的awk和sed代码等同，指的是这种情况
    
20. 
    

复制代码

不同的情况：

1. echo 'xxx
   
2. foo1 foo2
   
3. yyy
   
4. foo2
   
5. zzz' | sed -n '/foo1/,/foo2/p'
   
6. foo1 foo2
   
7. yyy
   
8. foo2
   
9. 
   
10. echo 'xxx
    
11. foo1 foo2
    
12. yyy
    
13. foo2
    
14. zzz' | awk '/foo1/,/foo2/'
    
15. foo1 foo2
    
16. 
    
17. #所以这样情况下，awk代码需要作一定的锚定
    
18. 
    
19. echo 'xxx
    
20. foo1 foo2
    
21. yyy
    
22. foo2
    
23. zzz' | awk '/^foo1/,/^foo2/'
    
24. foo1 foo2
    
25. yyy
    
26. foo2
    
27. 
    

复制代码

ywlscpl

支持

yinyuemi

回复 2# ywlscpl


    多谢老兄支持

Shell_HAT

楼主再来个sed1line实现awk1line吧

http://bbs.chinaunix.net/thread-1635180-1-1.html

yinyuemi

回复 4# Shell_HAT


   我也想过试试，awk1line：http://www.pement.org/awk/awk1line.txt， 不过看起来大部分都是重复的，awk数组和计数的部分似乎很难用one line的sed解决，所以放弃了

zooyo

强贴留名，好好研读。

shellyxz

很欣赏楼主的专注精神。请问，lz工作是和正则相关的吗？

xiaopan3322

很欣赏楼主的专注精神。请问，lz工作是和正则相关的吗？
shellyxz 发表于 2011-05-14 17:50

    我帮SS兄回答了……不是……而且毫无关系……所以人家才是大牛

shellyxz

回复 8# xiaopan3322


      牛！！！
   
     很专注

zzy7186

SS 兄厉害啊 收藏了