shell awk 获得重复次数 像表格一样输出

idjy

a内容
1 a
2 b
3 c
4 a
1 b
1 c
2 b
2 d
1 a
3 a


如何通过shell,AWK等操作得到这样的结果
id a b c d
1  2 1 1 -
2  - 2 - 1
3  1 - 1 -
4  1 - - -


补充：abcd 未知 由第二列获得的所有唯一项组成

bianlimit

1. awk '{a[$1][$2]++;b[$2]}END{print "id a b c d";for(i in a){printf i" ";for(j in b){if(a[i][j]){printf a[i][j]" "}else{printf "- "}}print ""}}' FILE
   
2. id a b c d
   
3. 1 2 1 1 -
   
4. 2 - 2 - 1
   
5. 3 1 - 1 -
   
6. 4 1 - - -

复制代码

idjy

回复 2# bianlimit

多谢, 执行似乎出错。不过,思路大概了解了。

reyleon

回复 3# idjy


    2楼的命令, 需要 gawk 4.0+ 才行的

zsszss0000

1. {
   
2.         a[$1,$2]++
   
3. }
   
4. END{
   
5. 
   
6.         for(i in a)
   
7.         {
   
8.                 split(i,idx,SUBSEP);
   
9.                 b[idx[1]]++;
   
10.                 c[idx[2]]++;
    
11.         }
    
12.         printf "序号\t";
    
13. 
    
14.         for(i in c)
    
15.         {
    
16.                 printf i"\t";
    
17.         }
    
18.         printf "\n"
    
19. 
    
20.         for(i in b)
    
21.         {
    
22.                 printf i"\t"
    
23.                 for(j in c)
    
24.                 {
    
25.                         if((i,j) in a)
    
26.                         {
    
27.                                 printf a[i,j]"\t"
    
28.                         }
    
29.                         else
    
30.                         {
    
31.                                 printf "-\t"
    
32.                         }
    
33.                 }
    
34.                 printf "\n"
    
35.         }
    
36. }
    

复制代码

1. 序号    a       b       c       d
   
2. 4       1       -       -       -
   
3. 1       2       1       1       -
   
4. 2       -       2       -       1
   
5. 3       1       -       1       -

复制代码

awk -f yourawk.awk FILE

bianlimit

1. awk '{b[$2]=$2;a[$1,$2]++;m[$1]}END{c=asort(b,n);o="id";for(i=1;i<=c;i++){o=o" "n[i]};print o;for(i=1;i<=length(m);i++){for(j in n){h=h" "(a[i,n[j]]?a[i,n[j]]:"-")}print i" "h;h=x}}' FILE
   
2. id a b c d
   
3. 1  2 1 1 -
   
4. 2  - 2 - 2
   
5. 3  1 - 1 -
   
6. 4  1 - - -
   

复制代码

zxy877298415

1. awk '{a[$1" "$2]++;b[$1];c[$2]}END{printf "id ";for(i in c) {printf i"  "}print "";for(i in b){printf i"  ";for(j in c) {if(a[i" "j]) {printf a[i" "j]"  "} else printf "-  "}print ""}}' file
   
2. id a  b  c  d  
   
3. 1  2  1  1  -  
   
4. 2  -  2  -  1  
   
5. 3  1  -  1  -  
   
6. 4  1  -  -  -  

复制代码

回复 1# idjy


   

聆雨淋夜

1. awk 'function g(x){return e[x]?e[x]:"-"}{e[$1""$2]+=1}
   
2. END{print "id a b c d";for(i=1;i<=4;i++){print i,g(i"a"),g(i"b"),g(i"c"),g(i"d")}}' file
   
3. id a b c d
   
4. 1 2 1 1 -
   
5. 2 - 2 - 1
   
6. 3 - - 1 -
   
7. 4 1 - - -
   

复制代码

jason680

回复 1# idjy

awk '
{
  if(!a[$1, $2]++){
    if(!id[$1]++){
      ida[++idc] = $1;
    }
    if(!it[$2]++){
      ita[++itc] = $2;
      it_str = it_str " " $2
    }
  }
}
END{
  print "id" it_str;
  for(n=1; n<=idc; n++){
    str = N = ida[n];
    for(m=1; m<=itc; m++){
      str = str " " (a[N,ita[m]] ? a[N,ita[m]] : "-");
    }
    print str;
  }
}
' FILE | column -t
id  a  b  c  d
1   2  1  1  -
2   -  2  -  1
3   1  -  1  -
4   1  -  -  -

   

searchcu

回复 1# idjy


awk '{ar[$2,$1]++;br[$2]}
END {
  if(!k){t="id";for(i in br){t=t" "i}print t;k=1}
  while(++a<=4)
  {       
    s=a;for(i in br){s=s" "(ar[i,a]+0)} print s;       
  }
}' <<EE | tr '0' '-' |column -t
1 a
2 b
3 c
4 a
1 b
1 c
2 b
2 d
1 a
3 a
EE


id  a  b  c  d
1   2  1  1  -
2   -  2  -  1
3   1  -  1  -
4   1  -  -  -